blob: 4115d2f8478295ebe0e136e3c8eb6b547ac2a0f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# linux-yocto-custom.bb:
#
# An example kernel recipe that uses the linux-yocto and oe-core
# kernel classes to apply a subset of yocto kernel management to git
# managed kernel repositories.
#
# To use linux-yocto-custom in your layer, create a
# linux-yocto-custom.bbappend file containing at least the following
# lines:
#
# FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
# COMPATIBLE_MACHINE_yourmachine = "yourmachine"
#
# You must also provide a Linux kernel configuration. The most direct
# method is to copy your .config to files/defconfig in your layer,
# in the same directory as the bbappend and add file://defconfig to
# your SRC_URI.
#
# To use the yocto kernel tooling to generate a BSP configuration
# using modular configuration fragments, see the yocto-bsp and
# yocto-kernel tools documentation.
#
# Warning:
#
# Building this example without providing a defconfig or BSP
# configuration will result in build or boot errors. This is not a
# bug.
#
#
# Notes:
#
# patches: patches can be merged into to the source git tree itself,
# added via the SRC_URI, or controlled via a BSP
# configuration.
#
# example configuration addition:
# SRC_URI += "file://smp.cfg"
# example patch addition (for kernel v3.4 only):
# SRC_URI += "file://0001-linux-version-tweak.patch
# example feature addition (for kernel v3.4 only):
# SRC_URI += "file://feature.scc"
#
inherit kernel
require recipes-kernel/linux/linux-yocto.inc
# Override SRC_URI in a bbappend file to point at a different source
# tree if you do not want to build from Linus' tree.
SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git;protocol=git;nocheckout=1"
LINUX_VERSION ?= "3.4"
LINUX_VERSION_EXTENSION ?= "-custom"
# Override SRCREV to point to a different commit in a bbappend file to
# build a different release of the Linux kernel.
# tag: v3.4 76e10d158efb6d4516018846f60c2ab5501900bc
SRCREV="76e10d158efb6d4516018846f60c2ab5501900bc"
PR = "r1"
PV = "${LINUX_VERSION}+git${SRCPV}"
# Override COMPATIBLE_MACHINE to include your machine in a bbappend
# file. Leaving it empty here ensures an early explicit build failure.
COMPATIBLE_MACHINE = "(^$)"
|
