From d452ba2aa0d7f404dcbc725bca91914a9db2d438 Mon Sep 17 00:00:00 2001
From: Richard Purdie <richard@openedhand.com>
Date: Tue, 7 Feb 2006 11:06:51 +0000
Subject: Add lsof

git-svn-id: https://svn.o-hand.com/repos/poky@252 311d38ba-8fff-0310-9ca6-ca027cbcb966
---
 openembedded/packages/lsof/lsof_4.75.bb | 38 +++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 openembedded/packages/lsof/lsof_4.75.bb

(limited to 'openembedded/packages/lsof')

diff --git a/openembedded/packages/lsof/lsof_4.75.bb b/openembedded/packages/lsof/lsof_4.75.bb
new file mode 100644
index 0000000000..7c1bba3b6c
--- /dev/null
+++ b/openembedded/packages/lsof/lsof_4.75.bb
@@ -0,0 +1,38 @@
+SECTION = "console/utils"
+DESCRIPTION = "Lsof is a Unix-specific diagnostic \
+tool. Its name stands for LiSt Open Files, and it \
+does just that."
+LICENSE = "BSD"
+
+SRC_URI = "ftp://lsof.itap.purdue.edu/pub/tools/unix/lsof/lsof_${PV}.tar.bz2"
+LOCALSRC = "file://${WORKDIR}/lsof_${PV}/lsof_${PV}_src.tar"
+S = "${WORKDIR}/lsof_${PV}_src"
+
+python do_unpack () {
+	bb.build.exec_func('base_do_unpack', d)
+	src_uri = bb.data.getVar('SRC_URI', d)
+	bb.data.setVar('SRC_URI', '${LOCALSRC}', d)
+	bb.build.exec_func('base_do_unpack', d)
+	bb.data.setVar('SRC_URI', src_uri, d)
+}
+
+LSOF_OS = "${TARGET_OS}"
+LSOF_OS_linux-uclibc = "linux"
+
+do_configure () {
+	./Configure ${LSOF_OS}
+}
+
+export I = "${STAGING_INCDIR}"
+export L = "${STAGING_INCDIR}"
+export EXTRA_OEMAKE = ""
+
+do_compile () {
+	oe_runmake 'CC=${CC}' 'CFGL=${LDFLAGS} -L./lib -llsof' 'DEBUG=' 'INCL=${CFLAGS}'
+}
+
+do_install () {
+	install -d ${D}${sbindir} ${D}${mandir}/man8
+	install -m 4755 lsof ${D}${sbindir}/lsof
+	install -m 0644 lsof.8 ${D}${mandir}/man8/lsof.8
+}
-- 
cgit v1.2.3