Meta: Recipe Reogranization

This is the next stage of recipe reorganization, in this stage
many recipes where moved to a new meta-demoapps layer since this
is more appropriate for demo usage then the core. Additional some
recipes were moved to meta-extras to indicate they may be depercated
at a future time.

A number of recipes were modified since dependencies need to be
corrected.

Signed-off-by: Saul Wold <Saul.Wold@intel.com>

9 files changed, 348 insertions, 0 deletions

diff --git a/meta/recipes-core/meta/external-csl-toolchain/SUPPORTED b/meta/recipes-core/meta/external-csl-toolchain/SUPPORTED
new file mode 100644
index 0000000000..fe9406acd1
--- /dev/null
+++ b/meta/recipes-core/meta/external-csl-toolchain/SUPPORTED
@@ -0,0 +1,4 @@
+en_GB.UTF-8 UTF-8
+en_GB ISO-8859-1
+en_US.UTF-8 UTF-8
+en_US ISO-8859-1
diff --git a/meta/recipes-core/meta/external-csl-toolchain_2008q3-72.bb b/meta/recipes-core/meta/external-csl-toolchain_2008q3-72.bb
new file mode 100644
index 0000000000..0d58445de2
--- /dev/null
+++ b/meta/recipes-core/meta/external-csl-toolchain_2008q3-72.bb
@@ -0,0 +1,63 @@
+INHIBIT_DEFAULT_DEPS = "1"
+
+# License applies to this recipe code, not the toolchain itself
+LICENSE = "MIT"
+
+PROVIDES = "\
+	linux-libc-headers \
+	virtual/arm-none-linux-gnueabi-gcc \
+	virtual/arm-none-linux-gnueabi-g++ \
+	virtual/arm-none-linux-gnueabi-gcc-initial \
+	virtual/arm-none-linux-gnueabi-gcc-intermediate \
+	virtual/arm-none-linux-gnueabi-binutils \
+	virtual/arm-none-linux-gnueabi-libc-for-gcc \
+	virtual/libc \
+	virtual/libintl \
+	virtual/libiconv \
+	glibc-thread-db \
+	virtual/linux-libc-headers "
+RPROVIDES = "glibc-utils libsegfault glibc-thread-db"
+PACKAGES_DYNAMIC = "glibc-gconv-*"
+PR = "r1"
+
+#SRC_URI = "http://www.codesourcery.com/public/gnu_toolchain/arm-none-linux-gnueabi/arm-${PV}-arm-none-linux-gnueabi-i686-pc-linux-gnu.tar.bz2 \
+
+SRC_URI = "file://SUPPORTED"
+
+do_install() {
+	echo "EXTERNAL_TOOLCHAIN is ${EXTERNAL_TOOLCHAIN}"
+	install -d ${D}${sysconfdir} ${D}${bindir} ${D}${sbindir} ${D}${base_bindir} ${D}${libdir}
+	install -d ${D}${base_libdir} ${D}${base_sbindir} ${D}${datadir}
+
+	cp -a ${EXTERNAL_TOOLCHAIN}/arm-none-linux-gnueabi/libc/lib/*  ${D}${base_libdir}
+	cp -a ${EXTERNAL_TOOLCHAIN}/arm-none-linux-gnueabi/libc/etc/*  ${D}${sysconfdir}
+	cp -a ${EXTERNAL_TOOLCHAIN}/arm-none-linux-gnueabi/libc/sbin/* ${D}${base_sbindir}
+	cp -a ${EXTERNAL_TOOLCHAIN}/arm-none-linux-gnueabi/libc/usr/*  ${D}/usr
+
+	sed -i -e "s# /lib# ../../lib#g" -e "s# /usr/lib# .#g" ${D}${libdir}/libc.so
+	sed -i -e "s# /lib# ../../lib#g" -e "s# /usr/lib# .#g" ${D}${libdir}/libpthread.so
+}
+
+GLIBC_INTERNAL_USE_BINARY_LOCALE ?= "compile"
+
+inherit libc-package
+
+PACKAGES += "libgcc libgcc-dev libstdc++ libstdc++-dev linux-libc-headers"
+FILES_libgcc = "${base_libdir}/libgcc_s.so.1"
+FILES_libgcc-dev = "${base_libdir}/libgcc_s.so"
+FILES_libstdc++ = "${libdir}/libstdc++.so.*"
+FILES_libstdc++-dev = "${includedir}/c++/${PV} \
+	${libdir}/libstdc++.so \
+	${libdir}/libstdc++.la \
+	${libdir}/libstdc++.a \
+	${libdir}/libsupc++.la \
+	${libdir}/libsupc++.a"
+FILES_linux-libc-headers = "${includedir}/asm* \
+	${includedir}/linux \
+	${includedir}/mtd \
+	${includedir}/rdma \
+	${includedir}/scsi \
+	${includedir}/sound \
+	${includedir}/video \
+"
+
diff --git a/meta/recipes-core/meta/external-poky-toolchain.bb b/meta/recipes-core/meta/external-poky-toolchain.bb
new file mode 100644
index 0000000000..a387ab3e60
--- /dev/null
+++ b/meta/recipes-core/meta/external-poky-toolchain.bb
@@ -0,0 +1,42 @@
+PROVIDES = "\
+    linux-libc-headers \
+    virtual/${TARGET_PREFIX}gcc \
+    virtual/${TARGET_PREFIX}gcc-intermediate \
+    virtual/${TARGET_PREFIX}gcc-initial \
+    virtual/${TARGET_PREFIX}binutils \
+    virtual/${TARGET_PREFIX}libc-for-gcc \
+    virtual/libc \
+    virtual/libintl \
+    virtual/libiconv \
+    virtual/linux-libc-headers "
+RPROVIDES = "glibc-utils libsegfault glibc-thread-db libgcc-dev libstdc++-dev libstdc++"
+PACKAGES_DYNAMIC = "glibc-gconv-*"
+INHIBIT_DEFAULT_DEPS = "1"
+PR = "r1"
+
+PSTAGING_DISABLED = "1"
+
+# License applies to this recipe code, not the toolchain itself
+LICENSE = "MIT"
+
+do_install() {
+	if [ ! -e  ${prefix}/environment-setup ]; then
+		echo "The Poky toolchain could not be found in ${prefix}!"
+		exit 1
+	fi
+
+	install -d ${DEPLOY_DIR}/ipk/
+	install -d ${STAGING_DIR}/pkgdata/
+	install -d ${STAGING_DIR_TARGET}/shlibs/
+	install -d ${STAGING_DIR_TARGET}/${base_libdir}/
+	install -d ${STAGING_DIR_TARGET}/${libdir}/
+	install -d ${STAGING_DIR_TARGET}/${includedir}/
+
+	cp -ar ${prefix}/ipk/* ${DEPLOY_DIR}/ipk/
+	cp -ar ${prefix}/pkgdata/* ${STAGING_DIR}/pkgdata/
+	cp -ar ${prefix}/${TARGET_SYS}/shlibs/* ${STAGING_DIR_TARGET}/shlibs/
+	cp -ar ${prefix}/${TARGET_SYS}/lib/* ${STAGING_DIR_TARGET}/${base_libdir}/
+	cp -ar ${prefix}/${TARGET_SYS}/usr/include/* ${STAGING_DIR_TARGET}/${includedir}/
+	cp -ar ${prefix}/${TARGET_SYS}/usr/lib/* ${STAGING_DIR_TARGET}/${libdir}/
+}
+
diff --git a/meta/recipes-core/meta/external-python-tarball.bb b/meta/recipes-core/meta/external-python-tarball.bb
new file mode 100644
index 0000000000..1812ba5506
--- /dev/null
+++ b/meta/recipes-core/meta/external-python-tarball.bb
@@ -0,0 +1,87 @@
+DESCRIPTION = "Meta package for building a standalone python tarball"
+LICENSE = "MIT"
+DEPENDS = "opkg-native opkg-utils-native virtual/fakeroot-native sed-native"
+
+inherit meta
+
+SDK_DIR = "${WORKDIR}/sdk"
+SDK_OUTPUT = "${SDK_DIR}/image"
+SDK_DEPLOY = "${TMPDIR}/deploy/sdk"
+
+IPKG_HOST = "opkg-cl -f ${IPKGCONF_SDK} -o ${SDK_OUTPUT}"
+
+TOOLCHAIN_HOST_TASK ?= "\
+    python-nativesdk-core \
+    python-nativesdk-textutils \
+    python-nativesdk-sqlite3 \
+    python-nativesdk-pickle \
+    python-nativesdk-logging \
+    python-nativesdk-elementtree \
+    python-nativesdk-curses \
+    python-nativesdk-compile \
+    python-nativesdk-compiler \
+    python-nativesdk-fcntl \
+    python-nativesdk-shell \
+    python-nativesdk-misc \
+    python-nativesdk-subprocess \
+    python-nativesdk-xmlrpc \
+    python-nativesdk-netclient \
+    python-nativesdk-netserver \
+    python-nativesdk-distutils"
+
+TOOLCHAIN_OUTPUTNAME ?= "python-nativesdk-standalone-${SDKMACHINE}"
+
+RDEPENDS = "${TOOLCHAIN_HOST_TASK}"
+
+EXCLUDE_FROM_WORLD = "1"
+
+do_populate_sdk() {
+	rm -rf ${SDK_OUTPUT}
+	mkdir -p ${SDK_OUTPUT}
+	mkdir -p ${SDK_OUTPUT}${localstatedir}/lib/opkg/
+
+	rm -f ${IPKGCONF_TARGET}
+	touch ${IPKGCONF_TARGET}
+	rm -f ${IPKGCONF_SDK}
+	touch ${IPKGCONF_SDK}
+
+	package_update_index_ipk
+	package_generate_ipkg_conf
+
+	for arch in ${PACKAGE_ARCHS}; do
+		revipkgarchs="$arch $revipkgarchs"
+	done
+
+	${IPKG_HOST} update
+	${IPKG_HOST} install ${TOOLCHAIN_HOST_TASK}
+
+	install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg
+	mv ${SDK_OUTPUT}/var/lib/opkg/* ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg/
+	rm -Rf ${SDK_OUTPUT}/var
+
+	install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}
+	install -m 0644 ${IPKGCONF_SDK} ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}/
+
+	rm -f ${SDK_OUTPUT}/${SDKPATHNATIVE}${libdir_nativesdk}/*.la
+
+	# Link the ld.so.cache file into the hosts filesystem
+	ln -s /etc/ld.so.cache ${SDK_OUTPUT}/${SDKPATHNATIVE}/etc/ld.so.cache
+
+	# Add version information
+	versionfile=${SDK_OUTPUT}/${SDKPATH}/version-${MULTIMACH_TARGET_SYS}
+	touch $versionfile
+	echo 'Distro: ${DISTRO}' >> $versionfile
+	echo 'Distro Version: ${DISTRO_VERSION}' >> $versionfile
+	echo 'Metadata Revision: ${METADATA_REVISION}' >> $versionfile
+	echo 'Timestamp: ${DATETIME}' >> $versionfile
+
+	# Package it up
+	mkdir -p ${SDK_DEPLOY}
+	cd ${SDK_OUTPUT}
+	${FAKEROOT} tar cfj ${SDK_DEPLOY}/${TOOLCHAIN_OUTPUTNAME}.tar.bz2 .
+}
+
+do_populate_sdk[nostamp] = "1"
+do_populate_sdk[recrdeptask] = "do_package_write"
+addtask populate_sdk before do_build after do_install
+
diff --git a/meta/recipes-core/meta/meta-ide-support.bb b/meta/recipes-core/meta/meta-ide-support.bb
new file mode 100644
index 0000000000..8fe9a23036
--- /dev/null
+++ b/meta/recipes-core/meta/meta-ide-support.bb
@@ -0,0 +1,14 @@
+DESCRIPTION = "Meta package for ensuring the build directory contains all appropriate toolchain packages for using an IDE"
+LICENSE = "MIT"
+DEPENDS = "virtual/libc gdb-cross qemu-helper-native unfs-server-native"
+PR = "r1"
+
+inherit meta toolchain-scripts
+
+do_populate_ide_support () {
+  toolchain_create_tree_env_script
+}
+
+do_populate_ide_support[nostamp] = "1"
+do_populate_ide_support[recrdeptask] = "do_package_write"
+addtask populate_ide_support before do_build after do_install
diff --git a/meta/recipes-core/meta/meta-toolchain-sdk.bb b/meta/recipes-core/meta/meta-toolchain-sdk.bb
new file mode 100644
index 0000000000..8572f021d7
--- /dev/null
+++ b/meta/recipes-core/meta/meta-toolchain-sdk.bb
@@ -0,0 +1,4 @@
+TOOLCHAIN_TARGET_SDKTASK ?= "task-poky-standalone-gmae-sdk-target task-poky-standalone-gmae-sdk-target-dbg"
+TOOLCHAIN_TARGET_TASK = "${TOOLCHAIN_TARGET_SDKTASK}"
+TOOLCHAIN_OUTPUTNAME = "${SDK_NAME}-toolchain-sdk-${DISTRO_VERSION}"
+require meta-toolchain.bb
diff --git a/meta/recipes-core/meta/meta-toolchain.bb b/meta/recipes-core/meta/meta-toolchain.bb
new file mode 100644
index 0000000000..2fab8f94b2
--- /dev/null
+++ b/meta/recipes-core/meta/meta-toolchain.bb
@@ -0,0 +1,103 @@
+DESCRIPTION = "Meta package for building a installable toolchain"
+LICENSE = "MIT"
+DEPENDS = "opkg-native opkg-utils-native virtual/fakeroot-native sed-native"
+
+inherit meta toolchain-scripts
+
+SDK_DIR = "${WORKDIR}/sdk"
+SDK_OUTPUT = "${SDK_DIR}/image"
+SDK_DEPLOY = "${TMPDIR}/deploy/sdk"
+
+SDKTARGETSYSROOT = "${SDKPATH}/sysroots/${TARGET_SYS}"
+
+IPKG_HOST = "opkg-cl -f ${IPKGCONF_SDK} -o ${SDK_OUTPUT}"
+IPKG_TARGET = "opkg-cl -f ${IPKGCONF_TARGET} -o ${SDK_OUTPUT}/${SDKTARGETSYSROOT}"
+
+TOOLCHAIN_HOST_TASK ?= "task-sdk-host"
+TOOLCHAIN_TARGET_TASK ?= "task-poky-standalone-sdk-target task-poky-standalone-sdk-target-dbg"
+TOOLCHAIN_OUTPUTNAME ?= "${SDK_NAME}-toolchain-${DISTRO_VERSION}"
+
+RDEPENDS = "${TOOLCHAIN_TARGET_TASK} ${TOOLCHAIN_HOST_TASK}"
+
+EXCLUDE_FROM_WORLD = "1"
+
+do_populate_sdk() {
+	rm -rf ${SDK_OUTPUT}
+	mkdir -p ${SDK_OUTPUT}
+	mkdir -p ${SDK_OUTPUT}${localstatedir}/lib/opkg/
+	mkdir -p ${SDK_OUTPUT}/${SDKTARGETSYSROOT}${localstatedir}/lib/opkg/
+
+	rm -f ${IPKGCONF_TARGET}
+	touch ${IPKGCONF_TARGET}
+	rm -f ${IPKGCONF_SDK}
+	touch ${IPKGCONF_SDK}
+
+	package_update_index_ipk
+	package_generate_ipkg_conf
+
+	for arch in ${PACKAGE_ARCHS}; do
+		revipkgarchs="$arch $revipkgarchs"
+	done
+
+	${IPKG_HOST} update
+	${IPKG_HOST} install ${TOOLCHAIN_HOST_TASK}
+
+	${IPKG_TARGET} update
+	${IPKG_TARGET} install ${TOOLCHAIN_TARGET_TASK}
+
+	install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg
+	mv ${SDK_OUTPUT}/var/lib/opkg/* ${SDK_OUTPUT}/${SDKPATHNATIVE}${localstatedir_nativesdk}/lib/opkg/
+	rm -Rf ${SDK_OUTPUT}/var
+
+	# Don't ship any libGL in the SDK
+	rm -rf ${SDK_OUTPUT}/${SDKPATHNATIVE}${libdir_nativesdk}/libGL*
+
+	install -d ${SDK_OUTPUT}/${SDKTARGETSYSROOT}/${sysconfdir}
+	install -m 0644 ${IPKGCONF_TARGET} ${IPKGCONF_SDK} ${SDK_OUTPUT}/${SDKTARGETSYSROOT}/${sysconfdir}/
+
+	install -d ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}
+	install -m 0644 ${IPKGCONF_SDK} ${SDK_OUTPUT}/${SDKPATHNATIVE}/${sysconfdir}/
+
+	# Can copy pstage files here
+	# target_pkgs=`cat ${SDK_OUTPUT}/${SDKTARGETSYSROOT}/var/lib/opkg/status | grep Package: | cut -f 2 -d ' '`
+
+	# Fix or remove broken .la files
+	for i in `find ${SDK_OUTPUT}/${SDKTARGETSYSROOT} -name \*.la`; do
+		sed -i 	-e "/^dependency_libs=/s,\([[:space:]']\)${base_libdir},\1${SDKTARGETSYSROOT}${base_libdir},g" \
+			-e "/^dependency_libs=/s,\([[:space:]']\)${libdir},\1${SDKTARGETSYSROOT}${libdir},g" \
+			-e "/^dependency_libs=/s,\-\([LR]\)${base_libdir},-\1${SDKTARGETSYSROOT}${base_libdir},g" \
+			-e "/^dependency_libs=/s,\-\([LR]\)${libdir},-\1${SDKTARGETSYSROOT}${libdir},g" \
+			-e 's/^installed=yes$/installed=no/' $i
+	done
+	#rm -f ${SDK_OUTPUT}/${SDKPATHNATIVE}/lib/*.la
+	rm -f ${SDK_OUTPUT}/${SDKPATHNATIVE}${libdir_nativesdk}/*.la
+
+	# Link the ld.so.cache file into the hosts filesystem
+	ln -s /etc/ld.so.cache ${SDK_OUTPUT}/${SDKPATHNATIVE}/etc/ld.so.cache
+
+	# Setup site file for external use
+	siteconfig=${SDK_OUTPUT}/${SDKPATH}/site-config-${MULTIMACH_TARGET_SYS}
+	touch $siteconfig
+	for sitefile in ${CONFIG_SITE} ; do
+		cat $sitefile >> $siteconfig
+	done
+
+	toolchain_create_sdk_env_script
+
+	# Add version information
+	versionfile=${SDK_OUTPUT}/${SDKPATH}/version-${MULTIMACH_TARGET_SYS}
+	touch $versionfile
+	echo 'Distro: ${DISTRO}' >> $versionfile
+	echo 'Distro Version: ${DISTRO_VERSION}' >> $versionfile
+	echo 'Metadata Revision: ${METADATA_REVISION}' >> $versionfile
+	echo 'Timestamp: ${DATETIME}' >> $versionfile
+
+	# Package it up
+	mkdir -p ${SDK_DEPLOY}
+	cd ${SDK_OUTPUT}
+	${FAKEROOT} tar cfj ${SDK_DEPLOY}/${TOOLCHAIN_OUTPUTNAME}.tar.bz2 .
+}
+
+do_populate_sdk[nostamp] = "1"
+do_populate_sdk[recrdeptask] = "do_package_write"
+addtask populate_sdk before do_build after do_install
diff --git a/meta/recipes-core/meta/package-index.bb b/meta/recipes-core/meta/package-index.bb
new file mode 100644
index 0000000000..21822fe9da
--- /dev/null
+++ b/meta/recipes-core/meta/package-index.bb
@@ -0,0 +1,29 @@
+DESCRIPTION = "Rebuild the package index"
+LICENSE = "MIT"
+
+INHIBIT_DEFAULT_DEPS = "1"
+ALLOW_EMPTY = "1"
+PACKAGES = ""
+
+do_fetch() {
+}
+do_unpack() {
+}
+do_patch() {
+}
+do_configure() {
+}
+do_compile() {
+}
+do_install() {
+}
+
+do_build[nostamp] = "1"
+do_build[dirs] = "${DEPLOY_DIR_IPK}"
+do_build() {
+	set -ex
+	package_update_index_ipk
+	set +ex
+}
+
+EXCLUDE_FROM_WORLD = "1"
diff --git a/meta/recipes-core/tasks/task-poky-tools.bb b/meta/recipes-core/tasks/task-poky-tools.bb
index 0a2533c525..0bb07a2984 100644
--- a/meta/recipes-core/tasks/task-poky-tools.bb
+++ b/meta/recipes-core/tasks/task-poky-tools.bb
@@ -63,6 +63,7 @@ RDEPENDS_task-poky-tools-profile_append_atom-pc = " lttng-ust"
 
 RDEPENDS_task-poky-tools-testapps = "\
     blktool \
+    fstests \
     tslib-calibrate \
     tslib-tests \
     lrzsz \
@@ -72,6 +73,7 @@ RDEPENDS_task-poky-tools-testapps = "\
     owl-video \
     gst-meta-video \
     gst-meta-audio \
+    x11perf \
     xrestop \
     xwininfo \
     xprop \