Initial support for netbooks with a poky-image-netbook(-live) image target.

This needs much love from folk with UI and WM skills.


git-svn-id: https://svn.o-hand.com/repos/poky/trunk@5266 311d38ba-8fff-0310-9ca6-ca027cbcb966

6 files changed, 108 insertions, 0 deletions

diff --git a/meta/packages/images/poky-image-netbook-live.bb b/meta/packages/images/poky-image-netbook-live.bb
new file mode 100644
index 0000000000..4a03015b79
--- /dev/null
+++ b/meta/packages/images/poky-image-netbook-live.bb
@@ -0,0 +1,8 @@
+DESCRIPTION = "Netbook Bootable Live Image"
+
+require poky-image-live.inc
+
+ROOTFS = "${DEPLOY_DIR_IMAGE}/poky-image-netbook-${MACHINE}.ext3"
+TIMEOUT = "3"
+
+do_bootimg[depends] += "poky-image-netbook:do_rootfs"
diff --git a/meta/packages/images/poky-image-netbook.bb b/meta/packages/images/poky-image-netbook.bb
new file mode 100644
index 0000000000..8138e9d598
--- /dev/null
+++ b/meta/packages/images/poky-image-netbook.bb
@@ -0,0 +1,7 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+IMAGE_FEATURES += "apps-console-core ${NETBOOK_IMAGE_FEATURES}"
+
+inherit poky-image
diff --git a/meta/packages/images/poky-image-sato-live.bb b/meta/packages/images/poky-image-sato-live.bb
index d69c252ee0..e2cc2c209f 100644
--- a/meta/packages/images/poky-image-sato-live.bb
+++ b/meta/packages/images/poky-image-sato-live.bb
@@ -3,5 +3,6 @@ DESCRIPTION = "Sato Bootable Live Image"
 require poky-image-live.inc
 
 ROOTFS = "${DEPLOY_DIR_IMAGE}/poky-image-sato-${MACHINE}.ext3"
+TIMEOUT = "3"
 
 do_bootimg[depends] += "poky-image-sato:do_rootfs"
diff --git a/meta/packages/matchbox-netbook/matchbox-session-netbook/session b/meta/packages/matchbox-netbook/matchbox-session-netbook/session
new file mode 100644
index 0000000000..bd6bdba4ac
--- /dev/null
+++ b/meta/packages/matchbox-netbook/matchbox-session-netbook/session
@@ -0,0 +1,22 @@
+#!/bin/sh
+
+. /etc/formfactor/config
+
+if [ "$HAVE_TOUCHSCREEN" = "1" ]; then
+    SHOWCURSOR="no"
+else
+    SHOWCURSOR="yes"
+fi
+
+matchbox-desktop &
+
+# Lines containing feature-[foo] are removed at build time if the machine
+# doesn't have the feature "foo".
+
+START_APPLETS=showdesktop,windowselector
+END_APPLETS=clock,battery,systray,startup-notify,notify
+END_APPLETS=openmoko-panel-gsm,$END_APPLETS # feature-phone
+
+matchbox-panel --titlebar --start-applets $START_APPLETS --end-applets $END_APPLETS &
+
+exec metacity
diff --git a/meta/packages/matchbox-netbook/matchbox-session-netbook_0.1.bb b/meta/packages/matchbox-netbook/matchbox-session-netbook_0.1.bb
new file mode 100644
index 0000000000..19e77d8915
--- /dev/null
+++ b/meta/packages/matchbox-netbook/matchbox-session-netbook_0.1.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Custom MB session files for poky"
+LICENSE = "GPL"
+SECTION = "x11"
+RDEPENDS = "formfactor gtk-engines gtk-theme-darkilouche matchbox-panel-2 matchbox-desktop-sato initscripts matchbox-session"
+PR = "r1"
+
+# This package is architecture specific because the session script is modified
+# based on the machine architecture.
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+SRC_URI = "file://session"
+S = "${WORKDIR}"
+
+do_install() {
+	# This is the set of machine features that the script has markers for
+	FEATURES="phone"
+	SCRIPT="${S}/sedder"
+	rm -f $SCRIPT
+	touch $SCRIPT
+	for FEAT in $FEATURES; do
+		if echo ${MACHINE_FEATURES} | awk "/$FEAT/ {exit 1}"; then
+			echo "/feature-$FEAT/d" >> $SCRIPT
+		fi
+	done
+
+	install -d ${D}/${sysconfdir}/matchbox
+	sed -f "$SCRIPT" ${S}/session > ${D}/${sysconfdir}/matchbox/session
+        chmod +x ${D}/${sysconfdir}/matchbox/session
+}
+
+pkg_postinst_${PN} () {
+#!/bin/sh -e
+if [ "x$D" != "x" ]; then
+    exit 1
+fi
+
+. ${sysconfdir}/init.d/functions
+
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/theme Sato
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/icon_theme Sato
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type bool --set /desktop/poky/interface/touchscreen true
+
+gconftool-2 --config-source=xml::$D${sysconfdir}/gconf/gconf.xml.defaults --direct --type string --set /desktop/poky/interface/font_name "Sans 10"
\ No newline at end of file
diff --git a/meta/packages/tasks/task-poky-x11-netbook.bb b/meta/packages/tasks/task-poky-x11-netbook.bb
new file mode 100644
index 0000000000..5a6407a0ab
--- /dev/null
+++ b/meta/packages/tasks/task-poky-x11-netbook.bb
@@ -0,0 +1,27 @@
+#
+# Copyright (C) 2008 Intel.
+#
+
+DESCRIPTION = "Netbook Tasks for Poky"
+PR = "r0"
+
+PACKAGES = "\
+    task-poky-x11-netbook \
+    task-poky-x11-netbook-dbg \
+    task-poky-x11-netbook-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+ALLOW_EMPTY = "1"
+
+NETWORK_MANAGER ?= "networkmanager-applet"
+RDEPENDS_task-poky-x11-netbook = "\
+    metacity-clutter \
+    matchbox-desktop \
+    matchbox-session-netbook \
+    matchbox-config-gtk \
+    xcursor-transparent-theme \
+    sato-icon-theme \
+    settings-daemon \
+    ${NETWORK_MANAGER}"