Adds recipes to support building X servers based on the xfree86 DDX instead

of kdrive and building mesa. It's a big commit and it's still rather rough
around the edges, but there is a desire to get this in early so people can
review the work and help polish the changes.

Some of the notable bits:
• DRI support in mesa and the X server. (configured in machine conf via
  MACHINE_DRI_MODULES variable)
• XCB backend for xlib
• A fairly lite X server build with lots of legacy modules disabled.

I'm sure there is plenty of other fairly low hanging fruit if we want to
put more effort into reducing the size of the xserver build. Currently the
server build comes in @ ~2.3MB vs a kdrive fbdev server build @ ~1MB. E.g
xaa could be made conditional to save ~320K. Of course the kdrive server
doesn't include glx stuff, which is a pretty big chunk.

Also thanks to hrw, since I nabbed a some patches from him for this, and RP,
for various bits of Poky style advice.


git-svn-id: https://svn.o-hand.com/repos/poky/trunk@5205 311d38ba-8fff-0310-9ca6-ca027cbcb966

5 files changed, 97 insertions, 47 deletions

diff --git a/meta/packages/mesa/mesa-common.inc b/meta/packages/mesa/mesa-common.inc
index 18e9b4ebed..51b8f4644a 100644
--- a/meta/packages/mesa/mesa-common.inc
+++ b/meta/packages/mesa/mesa-common.inc
@@ -1,9 +1,21 @@
 SECTION = "x11"
 
-SRC_URI = "${SOURCEFORGE_MIRROR}/mesa3d/MesaLib-${PV}.tar.bz2 \
-	file://mklib-rpath-link.patch;patch=1"
+DESCRIPTION = "An open source implementation of the OpenGL spec"
+HOMEPAGE = "http://mesa3d.org"
+LICENSE = "MIT"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/mesa3d/MesaLib-${PV}.tar.bz2"
 S = "${WORKDIR}/Mesa-${PV}"
 
-LICENSE = "LGPL"
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glu \
+                --disable-glw \
+                --disable-glut \
+                --enable-glx-tls"
+
+do_stage() {
+        autotools_stage_all
+}
+
 
-DEPENDS = "makedepend-native xf86vidmodeproto glproto virtual/libx11 libxext libxxf86vm libxi libxmu libice"
diff --git a/meta/packages/mesa/mesa-dri_7.1.bb b/meta/packages/mesa/mesa-dri_7.1.bb
new file mode 100644
index 0000000000..608bac0857
--- /dev/null
+++ b/meta/packages/mesa/mesa-dri_7.1.bb
@@ -0,0 +1,15 @@
+include mesa-common.inc
+
+PROTO_DEPS = "xf86driproto glproto"
+LIB_DEPS = "libdrm virtual/libx11 libxext libxxf86vm libxdamage libxfixes"
+
+DEPENDS = "${PROTO_DEPS}  ${LIB_DEPS}"
+
+PE = "1"
+PR = "r0"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dbg += "${libdir}/dri/.debug/*"
+
+EXTRA_OECONF += "--with-driver=dri --with-dri-drivers=${MACHINE_DRI_MODULES}"
+
diff --git a/meta/packages/mesa/mesa-dri_git.bb b/meta/packages/mesa/mesa-dri_git.bb
new file mode 100644
index 0000000000..137e1d4a33
--- /dev/null
+++ b/meta/packages/mesa/mesa-dri_git.bb
@@ -0,0 +1,20 @@
+include mesa-common.inc
+
+PROTO_DEPS = "xf86driproto glproto"
+LIB_DEPS = "libdrm virtual/libx11 libxext libxxf86vm libxdamage libxfixes"
+
+DEPENDS = "${PROTO_DEPS}  ${LIB_DEPS}"
+
+PV = "7.1+git${SRCREV}"
+PR = "r0"
+
+DEFAULT_PREFERENCE = "-1"
+
+SRC_URI = "git://anongit.freedesktop.org/git/mesa/mesa;protocol=git"
+S = "${WORKDIR}/git"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dbg += "${libdir}/dri/.debug/*"
+
+EXTRA_OECONF += "--with-driver=dri --with-dri-drivers=${MACHINE_DRI_MODULES}"
+
diff --git a/meta/packages/mesa/mesa-mesa.inc b/meta/packages/mesa/mesa-mesa.inc
deleted file mode 100644
index d794f0c097..0000000000
--- a/meta/packages/mesa/mesa-mesa.inc
+++ /dev/null
@@ -1,41 +0,0 @@
-include mesa-common.inc
-
-PACKAGES =+ "libglu libglu-dev libosmesa libosmesa-dev libgl libgl-dev"
-
-FILES_libgl = "${libdir}/libGL.so.*"
-FILES_libglu = "${libdir}/libGLU.so.*"
-FILES_libosmesa = "${libdir}/libOSMesa.so.*"
-
-FILES_libgl-dev = "${libdir}/libGL.* ${includedir}/GL"
-FILES_libglu-dev = "${libdir}/libGLU.* ${includedir}/GL/glu*.h"
-FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/osmesa.h"
-
-do_configure() {
-	cd configs
-
-	cp linux current
-	sed -e "s%CC *= *.*%CC = ${CC}%" -i current
-	sed -e "s%CXX *= *.*%CXX = ${CXX}%" -i current
-	sed -e "s%LD *= *.*%LD = ${LD}%" -i current
-	sed -e "s%OPT_FLAGS *= *.*%OPT_FLAGS = ${TARGET_CFLAGS}%" -i current
-	sed -e "s%X11_INCLUDES *= *.*%X11_INCLUDES = -I${STAGING_INCDIR}/X11%" -i current
-	sed -e "s%EXTRA_LIB_PATH *= *.*%EXTRA_LIB_PATH = ${LDFLAGS}%" -i current
-	sed -i s:\$\(CC\):gcc:g  ../src/mesa/x86/Makefile
-	echo "SRC_DIRS = mesa glu glut/glx" >> current
-}
-
-do_compile() {
-	oe_runmake default
-}
-
-do_install() {
-	install -d ${D}${libdir}
-	cp -pP lib/* ${D}${libdir}/
-	install -d ${D}${includedir}
-	cp -R include/GL ${D}${includedir}/
-}
-
-do_stage() {
-        cp -pP lib/* ${STAGING_LIBDIR}/
-        cp -R include/GL ${STAGING_INCDIR}/
-}
diff --git a/meta/packages/mesa/mesa_7.0.2.bb b/meta/packages/mesa/mesa_7.0.2.bb
index 3eb1fbef8b..a6cbef07d4 100644
--- a/meta/packages/mesa/mesa_7.0.2.bb
+++ b/meta/packages/mesa/mesa_7.0.2.bb
@@ -1,6 +1,50 @@
-include mesa-mesa.inc
+# Note: we don't require mesa-common.inc since going forward mesa will
+# be autotool based.
 
-SRC_URI_append = " file://fix-host-compile.patch;patch=1 "
+SRC_URI = "${SOURCEFORGE_MIRROR}/mesa3d/MesaLib-${PV}.tar.bz2 \
+	   file://mklib-rpath-link.patch;patch=1 \
+           file://fix-host-compile.patch;patch=1 "
+S = "${WORKDIR}/Mesa-${PV}"
 
+DEPENDS = "makedepend-native xf86vidmodeproto glproto virtual/libx11 libxext libxxf86vm libxi libxmu libice"
 
+PACKAGES =+ "libglu libglu-dev libosmesa libosmesa-dev libgl libgl-dev"
+
+FILES_libgl = "${libdir}/libGL.so.*"
+FILES_libglu = "${libdir}/libGLU.so.*"
+FILES_libosmesa = "${libdir}/libOSMesa.so.*"
+
+FILES_libgl-dev = "${libdir}/libGL.* ${includedir}/GL"
+FILES_libglu-dev = "${libdir}/libGLU.* ${includedir}/GL/glu*.h"
+FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/osmesa.h"
+
+do_configure() {
+	cd configs
+
+	cp linux current
+	sed -e "s%CC *= *.*%CC = ${CC}%" -i current
+	sed -e "s%CXX *= *.*%CXX = ${CXX}%" -i current
+	sed -e "s%LD *= *.*%LD = ${LD}%" -i current
+	sed -e "s%OPT_FLAGS *= *.*%OPT_FLAGS = ${TARGET_CFLAGS}%" -i current
+	sed -e "s%X11_INCLUDES *= *.*%X11_INCLUDES = -I${STAGING_INCDIR}/X11%" -i current
+	sed -e "s%EXTRA_LIB_PATH *= *.*%EXTRA_LIB_PATH = ${LDFLAGS}%" -i current
+	sed -i s:\$\(CC\):gcc:g  ../src/mesa/x86/Makefile
+	echo "SRC_DIRS = mesa glu glut/glx" >> current
+}
+
+do_compile() {
+	oe_runmake default
+}
+
+do_install() {
+	install -d ${D}${libdir}
+	cp -pP lib/* ${D}${libdir}/
+	install -d ${D}${includedir}
+	cp -R include/GL ${D}${includedir}/
+}
+
+do_stage() {
+        cp -pP lib/* ${STAGING_LIBDIR}/
+        cp -R include/GL ${STAGING_INCDIR}/
+}