Add Alsa support to poky

git-svn-id: https://svn.o-hand.com/repos/poky@198 311d38ba-8fff-0310-9ca6-ca027cbcb966

5 files changed, 131 insertions, 0 deletions

diff --git a/openembedded/packages/alsa/alsa-lib_1.0.10.bb b/openembedded/packages/alsa/alsa-lib_1.0.10.bb
new file mode 100644
index 0000000000..a5d5426316
--- /dev/null
+++ b/openembedded/packages/alsa/alsa-lib_1.0.10.bb
@@ -0,0 +1,31 @@
+DESCRIPTION = "Alsa sound library"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+
+# configure.in sets -D__arm__ on the command line for any arm system
+# (not just those with the ARM instruction set), this should be removed,
+# (or replaced by a permitted #define).
+#FIXME: remove the following
+ARM_INSTRUCTION_SET = "arm"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/alsa-lib-${PV}.tar.bz2"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-cards=pdaudiocf --with-oss=yes"
+
+do_stage () {
+	oe_libinstall -so -C src libasound ${STAGING_LIBDIR}/
+	install -d ${STAGING_INCDIR}/alsa/sound
+	install -m 0644 include/*.h ${STAGING_INCDIR}/alsa/
+	install -m 0644 include/sound/ainstr*.h ${STAGING_INCDIR}/alsa/sound/
+	install -d ${STAGING_DATADIR}/aclocal
+	install -m 0644 utils/alsa.m4 ${STAGING_DATADIR}/aclocal/
+}
+
+PACKAGES = "libasound alsa-server alsa-conf alsa-doc alsa-dev"
+FILES_libasound = "${libdir}/libasound.so*"
+FILES_alsa-server = "${bindir}"
+FILES_alsa-conf = "${datadir}"
+FILES_alsa-dev = "${libdir}/pkgconfig/ /usr/include/"
diff --git a/openembedded/packages/alsa/alsa-oss_1.0.10.bb b/openembedded/packages/alsa/alsa-oss_1.0.10.bb
new file mode 100644
index 0000000000..acf2ba7505
--- /dev/null
+++ b/openembedded/packages/alsa/alsa-oss_1.0.10.bb
@@ -0,0 +1,18 @@
+DESCRIPTION = "Alsa OSS Compatibility Package"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/oss-lib/alsa-oss-${PV}.tar.bz2"
+
+inherit autotools 
+
+do_configure_prepend () {
+	touch NEWS README AUTHORS ChangeLog
+}
+
+do_stage () {
+	oe_libinstall -C alsa -a -so libaoss ${STAGING_LIBDIR}
+	oe_libinstall -C alsa -a -so libalsatoss ${STAGING_LIBDIR}
+}
diff --git a/openembedded/packages/alsa/alsa-tools_1.0.10.bb b/openembedded/packages/alsa/alsa-tools_1.0.10.bb
new file mode 100644
index 0000000000..eed86e5dba
--- /dev/null
+++ b/openembedded/packages/alsa/alsa-tools_1.0.10.bb
@@ -0,0 +1,10 @@
+BROKEN = "1"
+
+DESCRIPTION = "Alsa Tools"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/tools/alsa-tools-${PV}.tar.bz2"
+
+inherit autotools
diff --git a/openembedded/packages/alsa/alsa-utils_1.0.10.bb b/openembedded/packages/alsa/alsa-utils_1.0.10.bb
new file mode 100644
index 0000000000..916afedd16
--- /dev/null
+++ b/openembedded/packages/alsa/alsa-utils_1.0.10.bb
@@ -0,0 +1,57 @@
+DESCRIPTION = "ALSA Utilities"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib ncurses"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2"
+
+inherit autotools
+
+# This are all packages that we need to make. Also, the now empty alsa-utils
+# ipk depend on them.
+
+PACKAGES += "alsa-utils-alsamixer"
+PACKAGES += "alsa-utils-midi"
+PACKAGES += "alsa-utils-aplay"
+PACKAGES += "alsa-utils-amixer"
+PACKAGES += "alsa-utils-aconnect"
+PACKAGES += "alsa-utils-iecset"
+PACKAGES += "alsa-utils-speakertest"
+PACKAGES += "alsa-utils-aseqnet"
+PACKAGES += "alsa-utils-alsactl"
+
+
+# We omit alsaconf, because
+# a) this is a bash script
+# b) it creates config files for RedHat, Debian, Mandrake etc, but not
+#    for Familiar, OpenZaurus etc
+
+
+FILES_${PN} = ""
+FILES_alsa-utils-aplay       = "${bindir}/aplay ${bindir}/arecord"
+FILES_alsa-utils-amixer      = "${bindir}/amixer"
+FILES_alsa-utils-alsamixer   = "${bindir}/alsamixer"
+FILES_alsa-utils-speakertest = "${bindir}/speaker-test"
+FILES_alsa-utils-midi        = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi"
+FILES_alsa-utils-aconnect    = "${bindir}/aconnect"
+FILES_alsa-utils-aseqnet     = "${bindir}/aseqnet"
+FILES_alsa-utils-iecset      = "${bindir}/iecset"
+FILES_alsa-utils-alsactl     = "${sbindir}/alsactl"
+
+DESCRIPTION_alsa-utils-aplay        = "play (and record) sound files via ALSA"
+DESCRIPTION_alsa-utils-amixer       = "command-line based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-alsamixer    = "ncurses based control for ALSA mixer and settings"
+#DESCRIPTION_alsa-utils-speaker-test= "??"
+DESCRIPTION_alsa-utils-midi         = "miscalleanous MIDI utilities for ALSA"
+DESCRIPTION_alsa-utils-aconnect     = "ALSA sequencer connection manager"
+DESCRIPTION_alsa-utils-aseqnet      = "network client/server on ALSA sequencer"
+DESCRIPTION_alsa-utils-alsactl      = "saves/restores ALSA-settings in /etc/asound.state"
+DESCRIPTION_alsa-utils-alsaconf     = "a bash script that creates ALSA configuration files"
+
+RDEPENDS_alsa-utils-aplay  += "alsa-conf"
+RDEPENDS_alsa-utils-amixer += "alsa-conf"
+
+# ALSA can be in kernel
+RRECOMMENDS_alsa-utils += "${ALSA_PACKAGES}"
+ALLOW_EMPTY_alsa-utils = "1"
diff --git a/openembedded/packages/alsa/files/alsa-utils-sys-siglist.patch b/openembedded/packages/alsa/files/alsa-utils-sys-siglist.patch
new file mode 100644
index 0000000000..8c499e8d63
--- /dev/null
+++ b/openembedded/packages/alsa/files/alsa-utils-sys-siglist.patch
@@ -0,0 +1,15 @@
+sys_siglist is not supported by default on uclibc and is, in general,
+a bad thing for the same reasons as sys_errlist is a bad thing.  GNU
+supports strsignal in the manner of strerror
+
+--- alsa-utils-1.0.8/alsamixer/alsamixer.c.orig	2005-09-06 12:44:41.415219126 -0700
++++ alsa-utils-1.0.8/alsamixer/alsamixer.c	2005-09-06 12:44:43.407344482 -0700
+@@ -2188,7 +2188,7 @@
+ mixer_signal_handler (int signal)
+ {
+   if (signal != SIGSEGV)
+-    mixer_abort (ERR_SIGNAL, sys_siglist[signal], 0);
++    mixer_abort (ERR_SIGNAL, strsignal(signal), 0);
+   else
+     {
+       fprintf (stderr, "\nSegmentation fault.\n");