blob: 9ba090b69a8276bb6bd72716d5149d045bc4a40b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
DESCRIPTION = "2.6 Linux Development Kernel for the Motorola GSM phones A780 and E680"
SECTION = "kernel"
MAINTAINER = "Michael 'Mickey' Lauer <mickey@vanille.de>"
LICENSE = "GPL"
PR = "ezx3-r2"
inherit kernel
##############################################################
# Source
SRC_URI = "http://www.kernel.org/pub/linux/kernel/v2.6/linux-2.6.16.tar.bz2 \
file://patch-2.6.16.13;patch=1 \
file://dpm-core-2.6.16.patch;patch=1 \
file://dpm-pxa27x-2.6.16.patch;patch=1 \
file://pxa7xx_udc.patch;patch=1 \
file://ezx_usb_gadged_serial_pxa27x.patch;patch=1 \
file://pxa27x_udc-more.patch;patch=1 \
file://ezx_defconfig.patch;patch=1 \
file://ezx_core.patch;patch=1 \
file://ezx_mtd.patch;patch=1 \
file://ezx_roflash.patch;patch=1 \
file://ezx_camera.patch;patch=1 \
file://sa1100_rtc.patch;patch=1 \
file://pxa_serial_bug_workaround.patch;patch=1 \
file://ezx_sound.patch;patch=1 \
file://pxa_serial_dpm.patch;patch=1 \
file://ezxfb-fix-screensave.patch;patch=1 \
file://keypad-module.patch;patch=1 \
file://exz-platformdevices.patch;patch=1 \
file://pxa_mtd_fix.patch;patch=1 \
file://ezx_pxa_ssp.patch;patch=1 \
file://pxamci_debug.patch;patch=1 \
file://ssp_pcap_nobitbang.patch;patch=1 \
file://pxamci-4bit.patch;patch=1 \
file://a780-transflash_power.patch;patch=1 \
file://ezx-kbd.patch;patch=1 \
file://ezx-mmc-ro.patch;patch=1 \
\
file://defconfig-a780 \
file://defconfig-e680"
S = "${WORKDIR}/linux-2.6.16"
##############################################################
# Compensate for sucky bootloader on all Sharp Zaurus models
#
FILES_kernel-image = ""
ALLOW_EMPTY = 1
COMPATIBLE_HOST = "arm.*-linux"
COMPATIBLE_MACHINE = '(a780|e680)'
CMDLINE_CON = "console=ttyS2,115200n8 console=tty1 noinitrd"
CMDLINE_ROOT = "root=/dev/mmcblk0p1 rootfstype=ext3 rootdelay=5"
# CMDLINE_OTHER = "dyntick=enable"
CMDLINE_DEBUG = '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug",d)}'
CMDLINE_IP = "ip=192.168.1.2:192.168.1.10:192.168.1.10:255.255.255.0:ezx:usb0:off"
CMDLINE = "${CMDLINE_CON} ${CMDLINE_ROOT} ${CMDLINE_IP} ${CMDLINE_ROTATE} ${CMDLINE_OTHER} ${CMDLINE_DEBUG}"
###############################################################
# module configs specific to this kernel
#
module_autoload_pxaficp_ir = "pxaficp_ir"
module_autoload_snd-pcm-oss = "snd-pcm-oss"
do_configure() {
rm -f ${S}/.config
if [ ! -e ${WORKDIR}/defconfig-${MACHINE} ]; then
die "No default configuration for ${MACHINE} available."
fi
echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
if [ "${TARGET_OS}" == "linux-gnueabi" ]; then
echo "CONFIG_AEABI=y" >> ${S}/.config
echo "CONFIG_OABI_COMPAT=y" >> ${S}/.config
else
echo "# CONFIG_AEABI is not set" >> ${S}/.config
echo "# CONFIG_OABI_COMPAT is not set" >> ${S}/.config
fi
sed -e '/CONFIG_AEABI/d' \
-e '/CONFIG_OABI_COMPAT=/d' \
-e '/CONFIG_CMDLINE=/d' \
-e '/CONFIG_MTD_MTDRAM_SA1100=/d' \
-e '/CONFIG_MTDRAM_TOTAL_SIZE=/d' \
-e '/CONFIG_MTDRAM_ERASE_SIZE=/d' \
-e '/CONFIG_MTDRAM_ABS_POS=/d' \
'${WORKDIR}/defconfig-${MACHINE}' >>'${S}/.config'
yes '' | oe_runmake oldconfig
}
# Check the kernel is below the 1264*1024 byte limit for the PXA Zaurii
do_compile_append() {
case ${MACHINE} in
c7x0 | akita | poodle | spitz | tosa )
size=`ls -l arch/${ARCH}/boot/${KERNEL_IMAGETYPE} | awk '{ print $5}'`
if [ $size -ge 1294336 ]; then
rm arch/${ARCH}/boot/${KERNEL_IMAGETYPE}
echo "Size is $size"
die "This kernel is too big for your PXA Zaurus and will destroy data if you flash it. Please reduce the size of the kernel by making more of it modular."
fi
;;
*)
;;
esac
}
do_deploy() {
install -d ${DEPLOY_DIR_IMAGE}
install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin
tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${MACHINE}.tgz -C ${D} lib
}
do_deploy[dirs] = "${S}"
addtask deploy before do_package after do_install
|
