SNAPDATE = "${@'%d%02d%02d' % ( time.localtime()[0], time.localtime()[1], time.localtime()[2]-1 )}" 
DESCRIPTION = "Qt/Embedded version ${PV}shot as of ${SNAPDATE}"
LICENSE = "GPL/QPL"
SECTION = "libs"
PRIORITY = "optional"
SRC_URI = "ftp://ftp.trolltech.com/pub/qt/snapshots/qt-embedded-${PV}shot-${SNAPDATE}.tar.gz \
    	   file://${FILESDIR}/qpe.patch;patch=1 \
    	   file://${FILESDIR}/tslib.patch;patch=1 \
    	   file://${FILESDIR}/devfs.patch;patch=1 \
    	   file://${FILESDIR}/no-moc.patch;patch=1"
DEPENDS = "virtual/libc base/zlib base/libpng base/jpeg uicmoc-native"
PROVIDES = "virtual/qte virtual/libqte2"
S = "${WORKDIR}/qt-${PV}shot-${SNAPDATE}"

export QTDIR = "${S}"

def qte_arch(d):
	import oe, re
	arch = oe.data.getVar('TARGET_ARCH', d, 1)
	if re.match("^i.86$", arch):
		arch = "x86"
	elif arch == "x86_64":
		arch = "x86"
	elif arch == "mipsel":
		arch = "mips"
	return arch

QTE_ARCH := "${@qte_arch(d)}"

EXTRA_OECONF_CONFIG = "-qconfig qpe"
EXTRA_OECONF_ARCH = "-xplatform ${TARGET_OS}-${QTE_ARCH}-g++"
EXTRA_OECONF_ARCH_collie = "-xplatform ${TARGET_OS}-sharp-g++"
EXTRA_OECONF_ARCH_ramses = "-xplatform ${TARGET_OS}-ramses-g++"

EXTRA_OECONF = "-system-jpeg -system-libpng -system-zlib -no-qvfb -no-xft -no-vnc -gif ${EXTRA_OECONF_ARCH} ${EXTRA_OECONF_CONFIG}"

EXTRA_OEMAKE = "-e"

export SYSCONF_CC = "${CC}"
export SYSCONF_CXX = "${CXX}"
export SYSCONF_LINK = "${CCLD}"
export SYSCONF_SHLIB = "${CCLD}"
export SYSCONF_CFLAGS = "${CFLAGS}"
export SYSCONF_CXXFLAGS = "${CXXFLAGS} -pipe -DQWS -fno-exceptions -fno-rtti -DNO_DEBUG"
export SYSCONF_LFLAGS = "${LDFLAGS}"
export SYSCONF_MOC = "${STAGING_BINDIR}/moc"
export SYSCONF_UIC = "${STAGING_BINDIR}/uic"

do_configure() {
    for f in ${S}/configs/linux-*-g++-shared; do
        sed -e 's,-linux-,-linux-uclibc-,g' < $f \
            > `echo $f | sed -e 's,linux-,linux-uclibc-,'`
    done
    oenote ./configure ${EXTRA_OECONF}
    echo yes | ./configure ${EXTRA_OECONF} || die "Configuring qt failed"
}

do_compile() {
    unset CC LD CCLD CXX RANLIB AR STRIP CFLAGS LDFLAGS CXXFLAGS CPPFLAGS
    oe_runmake || die "Compiling qte failed"
}

do_stage () {
    oe_libinstall -so -C lib libqte ${STAGING_LIBDIR}
    rm -f include/qxt.h
    cp -pfLR include/* ${STAGING_INCDIR}/
}

do_install () {
    oe_libinstall -so -C lib libqte ${D}/${palmtopdir}/lib
}