DESCRIPTION = "Qt/Embedded version ${PV}"
LICENSE = "GPL/QPL"
SRC_URI = "ftp://ftp.trolltech.com/pub/qt/source/qt-embedded-${PV}.tar.gz \
	 file://${FILESDIR}/qpe.patch;patch=1 \
	 file://${FILESDIR}/tslib.patch;patch=1 \
	 file://${FILESDIR}/devfs.patch;patch=1 \
	 file://${FILESDIR}/no-moc.patch;patch=1 "
DEPENDS = "virtual/libc base/zlib base/libpng base/jpeg uicmoc-native"
PROVIDES = "virtual/qte virtual/libqte2"
S = "${WORKDIR}/qt-${PV}"

# strip off leading and trailing whitespace, and made the vars single word
#CXX:="${@oe.data.getVar('CXX', d, 1).strip().split()[-1]}"
#CC:="${@oe.data.getVar('CC', d, 1).strip().split()[-1]}"
#BUILD_CXX:="${@oe.data.getVar('BUILD_CXX', d, 1).strip().split()[-1]}"
#BUILD_CC:="${@oe.data.getVar('BUILD_CC', d, 1).strip().split()[-1]}"
#CFLAGS:="${@oe.data.getVar('CFLAGS', d, 1).strip()}"
#CXXFLAGS:="${@oe.data.getVar('CXXFLAGS', d, 1).strip()}"
#LDFLAGS:="${@oe.data.getVar('LDFLAGS', d, 1).strip()}"

export QTDIR = "${S}"

def qte_arch(d):
	import oe, re
	arch = oe.data.getVar('TARGET_ARCH', d, 1)
	if re.match("^i.86$", arch):
		arch = "x86"
	elif arch == "x86_64":
		arch = "x86"
	return arch

QTE_ARCH := "${@qte_arch(d)}"

EXTRA_OECONF_CONFIG = "-qconfig qpe"
EXTRA_OECONF_ARCH = "-xplatform ${TARGET_OS}-${QTE_ARCH}-g++"
EXTRA_OECONF_ARCH_collie = "-xplatform ${TARGET_OS}-sharp-g++"
EXTRA_OECONF_ARCH_ramses = "-xplatform ${TARGET_OS}-ramses-g++"

EXTRA_OECONF = "-system-jpeg -system-libpng -system-zlib -no-qvfb -no-xft -no-vnc -gif ${EXTRA_OECONF_ARCH} ${EXTRA_OECONF_CONFIG}"

EXTRA_OEMAKE = "-e"

export SYSCONF_CC = "${CC}"
export SYSCONF_CXX = "${CXX}"
export SYSCONF_LINK = "${CCLD}"
export SYSCONF_SHLIB = "${CCLD}"
export SYSCONF_CFLAGS = "${CFLAGS}"
export SYSCONF_CXXFLAGS = "${CXXFLAGS} -pipe -DQWS -fno-exceptions -fno-rtti -DNO_DEBUG"
export SYSCONF_LFLAGS = "${LDFLAGS}"
export SYSCONF_MOC = "${STAGING_BINDIR}/moc"
export SYSCONF_UIC = "${STAGING_BINDIR}/uic"

do_configure() {
	oenote ./configure ${EXTRA_OECONF}
	echo yes | ./configure ${EXTRA_OECONF} || die "Configuring qt failed"
}

do_compile() {
	unset CC LD CCLD CXX RANLIB AR STRIP CFLAGS LDFLAGS CXXFLAGS CPPFLAGS
	oe_runmake
}

do_stage() {
	oe_soinstall lib/libqte.so.${PV} ${STAGING_LIBDIR}
	rm -f include/qxt.h
	cp -pfLR include/* ${STAGING_INCDIR}/
}

do_install() {
	install -d ${D}${palmtopdir}/lib/fonts
	oe_soinstall lib/libqte.so.${PV} ${D}${palmtopdir}/lib
	cp -a lib/fonts/* ${D}${palmtopdir}/lib/fonts/
}

PACKAGES = "libqte2 qte-font-fixed qte-font-helvetica qte-font-smoothtimes qte-font-smallsmooth"

FILES_${PN} = ""
FILES_libqte2 = "${palmtopdir}/lib/libqte.so*"
FILES_qte-font-fixed = "${palmtopdir}/lib/fonts/fixed*"
FILES_qte-font-helvetica = "${palmtopdir}/lib/fonts/helvetica*"
FILES_qte-font-smoothtimes = "${palmtopdir}/lib/fonts/smoothtimes*"
FILES_qte-font-smallsmooth = "${palmtopdir}/lib/fonts/smallsmooth*"