DESCRIPTION = "Opie Launcher"
SECTION = "opie/base"
PRIORITY = "optional"
MAINTAINER = "Greg Gilbert <greg@treke.net>"
LICENSE = "GPL"
DEPENDS = "opie-libqrsync libopie2"
PV = "1.1.3-cvs-${CVSDATE}"
APPNAME = "qpe"

SRC_URI = "cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/core/apps/calibrate;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/noncore/settings/mediummount;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/core/launcher;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/pics;date=${CVSDATE}                     \
           cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/apps;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@192.58.209.91/cvs;module=opie/root;date=${CVSDATE}"

S = "${WORKDIR}/launcher"

inherit opie

do_configure_prepend() {
	ln -s ${WORKDIR}/calibrate ${S}/calibrate
	ln -s ${WORKDIR}/mediummount ${S}/mediummount
	install -m 0644 ${FILESDIR}/server.pro ${S}/server.pro
}

do_install() {
	install -d ${D}/${palmtopdir}/bin \
		   ${D}/${palmtopdir}/apps/Applications \
		   ${D}/${palmtopdir}/apps/Settings \
		   ${D}/${palmtopdir}/pics/launcher \
		   ${D}/etc/init.d
	install -m 0755 ${S}/qpe ${D}/${palmtopdir}/bin/qpe
	install -m 0644 ${WORKDIR}/apps/Settings/calibrate.desktop ${D}/${palmtopdir}/apps/Settings/calibrate.desktop
	install -m 0644 ${WORKDIR}/pics/launcher/*.* ${D}/${palmtopdir}/pics/launcher/
	install -m 0644 ${WORKDIR}/root/etc/init.d/opie ${D}/etc/init.d/opie
#FIXME use our own - machine dependent - start script
#FIXME why is this still called qpe? it should be called launcher, or taskbar, or opie, or whatever - just not QPE!
}

FILES_opie-taskbar_append = " /etc/init.d/opie"