DESCRIPTION = "Opie Launcher"
SECTION = "opie/base"
PRIORITY = "optional"
LICENSE = "GPL"
DEPENDS = "opie-libqrsync "
PV = "1.1.4-cvs-${CVSDATE}"
APPNAME = "qpe"
PR = "r6"

SRC_URI = "cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/core/apps/calibrate;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/noncore/settings/mediummount;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/core/launcher;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/pics;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/apps;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/root;date=${CVSDATE} \
           cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/etc;date=${CVSDATE} \
           file://server.pro \
           file://opie-reorgfiles \
           file://opie"

S = "${WORKDIR}/launcher"

inherit opie update-rc.d

INITSCRIPT_NAME = "opie"
INITSCRIPT_PARAMS = "defaults 99"

do_configure_prepend() {
	ln -s ${WORKDIR}/calibrate ${S}/calibrate
	ln -s ${WORKDIR}/mediummount ${S}/mediummount
	install -m 0644 ${WORKDIR}/server.pro ${S}/server.pro
}

do_stage() {
    install obexinterface.h ${STAGING_INCDIR}/

}

SECTIONS = "1Pim Applications Examples Games Opie-SH Python Settings"

do_install() {
	install -d ${D}/${palmtopdir}/bin
	for i in ${SECTIONS}
	do
		install -d ${D}/${palmtopdir}/apps/$i/
		install -m 0644 ${WORKDIR}/apps/$i/.directory ${D}/${palmtopdir}/apps/$i/
	done
	install -d ${D}/${palmtopdir}/pics/launcher
	install -d ${D}/${palmtopdir}/pics/logo
	install -d ${D}/etc/init.d
	install -d ${D}/${palmtopdir}/etc/colors

	install -m 0755 ${S}/qpe ${D}/${palmtopdir}/bin/qpe
	install -m 0755 ${WORKDIR}/opie-reorgfiles ${D}/${palmtopdir}/bin/
	install -m 0644 ${WORKDIR}/apps/Settings/calibrate.desktop ${D}/${palmtopdir}/apps/Settings/calibrate.desktop
	install -m 0644 ${WORKDIR}/pics/launcher/*.* ${D}/${palmtopdir}/pics/launcher/
	install -m 0644 ${WORKDIR}/pics/logo/*.* ${D}/${palmtopdir}/pics/logo/
	install -m 0644 ${WORKDIR}/etc/colors/*.scheme ${D}/${palmtopdir}/etc/colors/
	install -m 0644 ${WORKDIR}/etc/mime.types ${D}/etc/
	install -m 0755 ${WORKDIR}/opie ${D}/etc/init.d/opie
}

FILES_opie-taskbar_append = " /etc ${palmtopdir}/apps ${palmtopdir}/pics"