DESCRIPTION = "Itsy Package Manager"
DESCRIPTION_libipkg = "Itsy Package Manager Library"
LICENSE = "GPL"
PROVIDES = "virtual/ipkg libipkg"
DEPENDS = "virtual/libc"
PR = "r1"

PACKAGES =+ "libipkg-dev libipkg "
FILES_libipkg-dev = "${libdir}/*.a ${libdir}/*.la ${libdir}/*.so"
FILES_libipkg = "${libdir}"

SRC_URI = "cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=familiar/dist/ipkg;tag=${@'V' + oe.data.getVar('PV',d,1).replace('.', '-')}"
S = "${WORKDIR}/ipkg/C"

inherit autotools libtool

pkg_postinst_ipkg () {
#!/bin/sh
if [ "x$D" != "x" ]; then
	install -d ${IMAGE_ROOTFS}/${sysconfdir}/rcS.d
	# this needs to happen after S35mountall so that /tmp is available
	echo -e "#!/bin/sh\nipkg-cl configure\nrm -f \$0" > ${IMAGE_ROOTFS}/${sysconfdir}/rcS.d/S36configure
	chmod 755 ${IMAGE_ROOTFS}/${sysconfdir}/rcS.d/S36configure
fi

update-alternatives --install /usr/bin/ipkg ipkg /usr/bin/ipkg-cl 100
}

pkg_postrm_ipkg () {
#!/bin/sh
update-alternatives --remove ipkg /usr/bin/ipkg-cl
}

do_stage() {
	oe_soinstall .libs/libipkg.so.0.0.0 ${STAGING_LIBDIR}/
	install -d ${STAGING_INCDIR}/replace/
	install -m 0644 replace/replace.h ${STAGING_INCDIR}/replace/
	install -d ${STAGING_INCDIR)/libipkg/
	for f in *.h
	do
		install -m 0644 $f ${STAGING_INCDIR}/libipkg/
	done
}