DESCRIPTION = "GNU C Library"
LICENSE = "LGPL"
SECTION = "libs"
PRIORITY = "required"
MAINTAINER = "Chris Larson <kergoth@handhelds.org>"
PR = "r2"
#
# For now, we will skip building of a gcc package if it is a uclibc one
# and our build is not a uclibc one, and we skip a glibc one if our build
# is a uclibc build.
#
# See the note in gcc/gcc_3.4.0.oe
#

python __anonymous () {
    import oe, re
    uc_os = (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None)
    if uc_os:
        raise oe.parse.SkipPackage("incompatible with target %s" %
                                   oe.data.getVar('TARGET_OS', d, 1))
}

PROVIDES = "virtual/libc virtual/${TARGET_PREFIX}libc-for-gcc"
PACKAGES = "glibc glibc-dev glibc-doc glibc-i18n glibc-locale"

DEPENDS = "patcher-native virtual/${TARGET_PREFIX}gcc-initial"
INHIBIT_DEFAULT_DEPS = "1"

FILES_glibc_append = " ${datadir}/zoneinfo"
FILES_glibc-dev_append = " ${libdir}/*.o"
FILES_glibc-gconv = "${libdir}/gconv"
FILES_glibc-i18n = "${datadir}/i18n"

HEADERS_VERSION = "2.6.5.1"
HEADERS_DIR = "${WORKDIR}/linux-libc-headers-${HEADERS_VERSION}"

#	 file://dyn-ldconfig.diff;patch=1;pnum=0
#	  file://glibcbug.patch;patch=1;pnum=0
#	  file://nptl-pthread-once.patch;patch=1;pnum=1
#	  file://50_glibc232-hppa-full-nptl-2003-10-22.patch;patch=1;pnum=1
#	  file://alpha-crti.patch;patch=1;pnum=1
#	  file://glibc-make-check-perms.patch;patch=1;pnum=0
# This patch is needed for builds against recent 2.5/2.6 kernel headers:
SRC_URI = "ftp://ftp.gnu.org/gnu/glibc/glibc-${PV}.tar.gz \
	   ftp://ftp.gnu.org/pub/gnu/glibc/glibc-linuxthreads-2.3.2.tar.gz \
	   http://ep09.pld-linux.org/~mmazur/linux-libc-headers/linux-libc-headers-${HEADERS_VERSION}.tar.bz2 \
	   file://noinfo.patch;patch=1 \
	   file://10_cvs.patch;patch=1 \
	   file://arm-ioperm.patch;patch=1;pnum=0 \
	   file://glibc-i686-timing.patch;patch=1;pnum=1 \
	   file://makeconfig.patch;patch=1;pnum=0 \
	   file://locale-es_AR.patch;patch=1;pnum=0 \
	   file://ldconfig.patch;patch=1;pnum=0 \
	   file://ldd.patch;patch=1;pnum=0 \
	   file://fhs-linux-paths.patch;patch=1;pnum=1 \
	   file://glibc22-nss-upgrade.patch;patch=1;pnum=1 \
	   file://glibc22-eo_EO.patch;patch=1;pnum=1 \
	   file://glibc22-m68k-compat.patch;patch=1;pnum=1 \
	   file://glibc22-m68k-fpic.patch;patch=1;pnum=1 \
	   file://glibc22-locales.patch;patch=1;pnum=0 \
	   file://sparc64-fixups.patch;patch=1;pnum=1 \
	   file://glibc22-ttyname-devfs.patch;patch=1;pnum=0 \
	   file://powerpc-sysconf.patch;patch=1;pnum=1 \
	   file://arm-no-hwcap.patch;patch=1;pnum=0 \
	   file://locales-stuff.patch;patch=1;pnum=1 \
	   file://librt-mips.patch;patch=1;pnum=0 \
	   file://glibc23-ctype-compat.patch;patch=1;pnum=1 \
	   file://glibc23-hppa-Rminkernel.patch;patch=1;pnum=0 \
	   file://glibc23-function-compat.patch;patch=1;pnum=1 \
	   file://glibc23-errno.patch;patch=1;pnum=1 \
	   file://glibc23-asserth-decls.patch;patch=1;pnum=0 \
	   file://alpha-pic.patch;patch=1;pnum=0 \
	   file://glibc23-cmov.patch;patch=1;pnum=1 \
	   file://libgcc-compat-all.patch;patch=1;pnum=0 \
	   file://locales-supported.patch;patch=1;pnum=0 \
	   file://libgcc-compat-other.patch;patch=1;pnum=1 \
	   file://s390-tls.patch;patch=1;pnum=0 \
	   file://hurd-enable-ldconfig.patch;patch=1;pnum=1 \
	   file://30_glibc232-base.patch;patch=1;pnum=0 \
	   file://sparcv8-target.patch;patch=1;pnum=0 \
	   file://50_glibc232-arm-dwarf2-buildfix.patch;patch=1;pnum=0 \
	   file://50_glibc232-m68k-dwarf2-buildfix.patch;patch=1;pnum=1 \
	   file://arm-output-format.patch;patch=1;pnum=0 \
	   file://pthread-cleanup.patch;patch=1;pnum=0 \
	   file://glibc-${PV}-ldconfig-tls.patch;patch=1;pnum=1 \
	   file://glibc23-mips-msq.patch;patch=1;pnum=0 \
	   file://glibc23-libio-compat.patch;patch=1;pnum=1 \
	   file://80_glibc232-locales-nb_NO-fix.patch;patch=1;pnum=0 \
	   file://ldso-disable-hwcap.patch;patch=1;pnum=1 \
	   file://11_shlib-lds.patch;patch=1;pnum=1 \
	   file://glibc23-version-sanity.patch;patch=1;pnum=1 \
	   file://glibc23-sse-oldkernel.patch;patch=1;pnum=1 \
	   file://glibc23-sparc-pread64.patch;patch=1;pnum=1 \
	   file://glibc23-powerpc-sigcontext.patch;patch=1;pnum=1 \
	   file://hppa-syscall.patch;patch=1;pnum=0 \
	   file://glibc23-errno-hack.patch;patch=1;pnum=1 \
	   file://90_glibc232-statvfs.patch;patch=1;pnum=0 \
	   file://90_glibc232-timezones.patch;patch=1;pnum=0 \
	   file://arm-memcpy.patch;patch=1;pnum=0 \
	   file://arm-longlong.patch;patch=1;pnum=0 \
	   file://arm-machine-gmon.patch;patch=1;pnum=0 \
	   file://glibc232-gcc34-i386-fixup-attribute.patch;patch=1;pnum=1 \
	   file://glibc232-gcc34-no-unit-at-a-time.patch;patch=1;pnum=1 \
	   \
	   file://etc/ld.so.conf \
	   file://generate-supported.mk"

S = "${WORKDIR}/glibc-${PV}"
B = "${WORKDIR}/build-${TARGET_SYS}"

inherit autotools

EXTRA_OECONF = "--without-tls --without-__thread --enable-kernel=${OLDEST_KERNEL} \
	        --without-cvs --disable-profile --disable-debug --without-gd \
		--enable-clocale=gnu \
	        --enable-add-ons=linuxthreads --with-headers=${HEADERS_DIR}/include"

EXTRA_OECONF += "${@get_glibc_fpu_setting(oe, d)}"

def get_glibc_fpu_setting(oe, d):
	if oe.data.getVar('TARGET_FPU', d, 1) in [ 'soft' ]:
		return "--without-fp"
	return ""

glibcbuild_do_unpack () {
	mv "${WORKDIR}/linuxthreads" "${WORKDIR}/linuxthreads_db" "${S}/"
# kernel headers
	case ${TARGET_ARCH} in
		alpha*)   TARGET_ARCH=alpha ;;
		arm*)     TARGET_ARCH=arm ;;
		cris*)    TARGET_ARCH=cris ;;
		hppa*)    TARGET_ARCH=parisc ;;
		i*86*)    TARGET_ARCH=i386 ;;
		ia64*)    TARGET_ARCH=ia64 ;;
		mips*)    TARGET_ARCH=mips ;;
		m68k*)    TARGET_ARCH=m68k ;;
		powerpc*) TARGET_ARCH=ppc ;;
		s390*)    TARGET_ARCH=s390 ;;
		sh*)      TARGET_ARCH=sh ;;
		sparc64*) TARGET_ARCH=sparc64 ;;
		sparc*)   TARGET_ARCH=sparc ;;
		x86_64*)  TARGET_ARCH=x86_64 ;;
	esac
	if test !  -e ${HEADERS_DIR}/include/asm-$TARGET_ARCH; then
		oefatal unable to create asm symlink in kernel headers
	fi
	ln -sf "asm-$TARGET_ARCH" "${HEADERS_DIR}/include/asm"
	if test "$TARGET_ARCH" = "arm"; then
		ln -sf proc-armv ${HEADERS_DIR}/include/asm/proc
		ln -sf arch-ebsa285 ${HEADERS_DIR}/include/asm/arch
	fi
}

python do_unpack () {
	oe.build.exec_func('base_do_unpack', d)
	oe.build.exec_func('glibcbuild_do_unpack', d)
}

do_configure () {
# override this function to avoid the autoconf/automake/aclocal/autoheader
# calls for now
# don't pass CPPFLAGS into configure, since it upsets the kernel-headers
# version check and doesn't really help with anything
	(cd ${S} && gnu-configize) || die "failure in running gnu-configize"
	CPPFLAGS="" oe_runconf
}

rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
	  yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
	  rusers.x spray.x nfs_prot.x rquota.x key_prot.x"

do_compile () {
	# this really is arm specific
	touch ${S}/sysdeps/arm/framestate.c
	# -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
	unset LDFLAGS
	base_do_compile
	(
		cd ${S}/sunrpc/rpcsvc
		for r in ${rpcsvc}; do
			h=`echo $r|sed -e's,\.x$,.h,'`
			rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
		done
	)
}

do_stage() {
	oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
		   'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
		   '${STAGING_LIBDIR}/libc-${PV}.so' '${STAGING_LIBDIR}/libc.so.6' \
		   install-headers install-lib

	install -d ${STAGING_INCDIR}/asm
	rm -f ${STAGING_INCDIR}/linux/wireless.h
	cp -a ${HEADERS_DIR}/include/linux ${STAGING_INCDIR}/
	ln -sf ${STAGING_KERNEL_DIR}/include/linux/wireless.h ${STAGING_INCDIR}/linux/wireless.h
	cp -a ${HEADERS_DIR}/include/asm/* ${STAGING_INCDIR}/asm/

	install -d ${STAGING_INCDIR}/gnu \
		   ${STAGING_INCDIR}/bits \
		   ${STAGING_INCDIR}/rpcsvc
	install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
	install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
	install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
	for r in ${rpcsvc}; do
		h=`echo $r|sed -e's,\.x$,.h,'`
		install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
	done
	for i in libc.a libc_pic.a libc_nonshared.a; do
		install ${B}/$i ${STAGING_LIBDIR}/
	done
	echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
	echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so

	oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
		   'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
		   '${CROSS_DIR}/${TARGET_SYS}/lib/libc-${PV}.so' \
		   '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
		   install-headers install-lib

	install -d ${CROSS_DIR}/${TARGET_SYS}/include/asm
	cp -a ${HEADERS_DIR}/include/linux ${CROSS_DIR}/${TARGET_SYS}/include/
	cp -R ${HEADERS_DIR}/include/asm/* ${CROSS_DIR}/${TARGET_SYS}/include/asm/

	install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
		   ${CROSS_DIR}/${TARGET_SYS}/include/bits \
		   ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
	install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
	install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
	install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
	for r in ${rpcsvc}; do
		h=`echo $r|sed -e's,\.x$,.h,'`
		install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
	done

	for i in libc.a libc_pic.a libc_nonshared.a; do
		install ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/
	done
	echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
	echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
}

include glibc-package.oe