DESCRIPTION = "Evas is a hardware-accelerated canvas API that can draw \
anti-aliased text, smooth super and sub-images, alpha-blend, as well as drop \
down to using normal X11 primitives such as pixmaps, lines and rectangles if \
your CPU or graphics hardware are too slow."
HOMEPAGE = "http://www.enlightenment.org"
SECTION = "libs"
PRIORITY = "optional"
DEPENDS = "libpng jpeg freetype"

SRC_URI = "${SOURCEFORGE_MIRROR}/enlightenment/evas-1.0.0_pre5.tar.gz \
           file://configure.patch;patch=1 \
           file://pkg.m4"
S = "${WORKDIR}/evas-1.0.0_pre5"

inherit autotools pkgconfig

EXTRA_OECONF = "--enable-fb \
		--enable-image-loader-png \
		--enable-image-loader-jpeg \
		--enable-small-dither-mask \
		--enable-cpu-c \
		--enable-scale-smooth \
		--enable-scale-sample \
		--enable-convert-16-rgb-ipq \
		--enable-convert-16-rgb-rot-0 \
		--enable-convert-16-rgb-rot-270"
export FREETYPE_CONFIG = "${STAGING_BINDIR}/freetype-config"

do_configure () {
	install -m 0644 ${WORKDIR}/pkg.m4 acinclude.m4
	autotools_do_configure
}

headers = "Evas_Engine_Buffer.h \
           Evas_Engine_DirectFB.h \
           Evas_Engine_FB.h \
           Evas_Engine_GL_X11.h \
           Evas_Engine_Software_Qtopia.h \
           Evas_Engine_Software_Win32_GDI.h \
           Evas_Engine_Software_X11.h \
           Evas.h"

do_stage () {
	for i in ${headers}; do
		install -m 0644 ${S}/src/lib/$i ${STAGING_INCDIR}/
	done
	oe_libinstall -C src/lib libevas ${STAGING_LIBDIR}/
	cat evas-config | sed -e 's,/usr/include,${STAGING_INCDIR},g; \
				      s,/usr/lib,${STAGING_LIBDIR},g; \
				      s,/usr/bin,${STAGING_BINDIR},g; \
				      s,/usr,${STAGING_LIBDIR}/..,g;' > ${STAGING_BINDIR}/evas-config
	chmod u+x ${STAGING_BINDIR}/evas-config
}