SECTION = "base"
PRIORITY = "required"
MAINTAINER = "Greg Gilbert <greg@treke.net>"
DEPENDS = "libtool-cross"
DESCRIPTION = "Set of tools for managing notebook power consumption."

SRC_URI = "${DEBIAN_MIRROR}/main/a/apmd/apmd_${PV}.orig.tar.gz; \
           file://debian.patch;patch=1 \
           file://workaround.patch;patch=1 \
           file://apmwrapper \
           file://init \
           file://default \
           file://apmd_proxy \
           file://apmd_proxy.conf"

S = "${WORKDIR}/apmd-${PV}.orig"

inherit update-rc.d

INITSCRIPT_NAME = "apmd"
INITSCRIPT_PARAMS = "defaults"

do_compile() {
	oe_runmake "LIBTOOL=${STAGING_BINDIR}/${TARGET_PREFIX}libtool" apm apmd
}

do_stage() {
	oe_libinstall -so libapm ${STAGING_LIBDIR}
}

do_install() {

	install -d ${D}/${sysconfdir}
	install -d ${D}/${sysconfdir}/apm
	install -d ${D}/${sysconfdir}/apm/event.d
	install -d ${D}/${sysconfdir}/apm/other.d
	install -d ${D}/${sysconfdir}/apm/suspend.d
	install -d ${D}/${sysconfdir}/apm/resume.d
	install -d ${D}/${sysconfdir}/apm/scripts.d
	install -d ${D}/${sysconfdir}/default
	install -d ${D}/${sysconfdir}/init.d
	install -d ${D}/${sbindir}
	install -d ${D}/${bindir}
	install -d ${D}/${libdir}
	install -d ${D}/${datadir}/apmd
	install -m 4755 ${S}/.libs/apm ${D}/${bindir}/apm.orig
	install -m 0755 ${WORKDIR}/apmwrapper ${D}/${bindir}/apm
	install -m 0755 ${S}/.libs/apmd ${D}/${sbindir}/apmd
	install -m 0755 ${WORKDIR}/apmd_proxy ${D}/${sysconfdir}/apm/
	install -m 0644 ${WORKDIR}/apmd_proxy.conf ${D}/${datadir}/apmd/
	install -m 0644 ${WORKDIR}/default ${D}/${sysconfdir}/default/apmd
	oe_libinstall -so libapm ${D}/${libdir}

	cat ${WORKDIR}/init | sed -e 's,/usr/sbin,${sbindir},g; s,/etc,${sysconfdir},g;' > ${D}/${sysconfdir}/init.d/apmd
	chmod 755 ${D}/${sysconfdir}/init.d/apmd
}