From 3856d5e9f5296f19877689cb32db6fc4471bb7c2 Mon Sep 17 00:00:00 2001
From: Michael Lauer <mickey@vanille-media.de>
Date: Tue, 22 Jun 2004 12:11:34 +0000
Subject: fix rxvt unicode. patch courtesy Chris Lord.

BKrev: 40d821f6VpQpp_qS3N30UCq-j4Ot_A
---
 rxvt-unicode/rxvt-unicode_2.4.oe | 49 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

(limited to 'rxvt-unicode')

diff --git a/rxvt-unicode/rxvt-unicode_2.4.oe b/rxvt-unicode/rxvt-unicode_2.4.oe
index e69de29bb2..219eb50e7b 100644
--- a/rxvt-unicode/rxvt-unicode_2.4.oe
+++ b/rxvt-unicode/rxvt-unicode_2.4.oe
@@ -0,0 +1,49 @@
+DEPENDS = "x11 xt libxft"
+DESCRIPTION = "rxvt-unicode is a clone of the well known \
+terminal emulator rxvt, modified to store text in Unicode \
+(either UCS-2 or UCS-4) and to use locale-correct input and \
+output. It also supports mixing multiple fonts at the \
+same time, including Xft fonts."
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/rxvt-unicode/rxvt-unicode-${PV}.tar.bz2 \
+           file://gcc34.patch;patch=1"
+
+inherit autotools 
+
+PROVIDES = "virtual/x-terminal-emulator"
+ALTERNATIVE_NAME = "x-terminal-emulator"
+
+CFLAGS_append = " -fpermissive"
+
+EXTRA_OECONF = "--disable-menubar --disable-xim \
+		--enable-utmp --enable-wtmp --enable-lastlog \
+		--disable-strings --with-term=rxvt --enable-keepscrolling \
+		--enable-xft --with-name=rxvt --enable-frills \
+		--enable-swapscreen --enable-transparency \
+		--with-codesets=eu,jp \
+		--enable-cursor-blink --enable-pointer-blank \
+		--enable-text-blink --enable-plain-scroll \
+		--enable-combining --enable-shared \
+		--with-x=${STAGING_LIBDIR}/.."
+EXTRA_OEMAKE = "'XINC=-I${STAGING_INCDIR}' \
+		'XLIB=-L${STAGING_LIBDIR} -lX11'"
+
+do_configure () {
+	mv autoconf/configure.in . || true
+	rm autoconf/libtool.m4
+	libtoolize --force
+	autotools_do_configure
+	echo '#define RXVT_UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
+	echo '#define RXVT_WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
+	echo '#define RXVT_LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
+	echo '#define HAVE_XLOCALE 1' >> config.h
+}
+
+do_compile () {
+	if test -e ${S}/${HOST_SYS}-libtool; then
+		LIBTOOL=${S}/${HOST_SYS}-libtool
+	else
+		LIBTOOL=${S}/libtool
+	fi
+	oe_runmake "LIBTOOL=$LIBTOOL"
+}
-- 
cgit v1.2.3