From 709c4d66e0b107ca606941b988bad717c0b45d9b Mon Sep 17 00:00:00 2001
From: Denys Dmytriyenko <denis@denix.org>
Date: Tue, 17 Mar 2009 14:32:59 -0400
Subject: rename packages/ to recipes/ per earlier agreement

See links below for more details:
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21326
http://thread.gmane.org/gmane.comp.handhelds.openembedded/21816

Signed-off-by: Denys Dmytriyenko <denis@denix.org>
Acked-by: Mike Westerhof <mwester@dls.net>
Acked-by: Philip Balister <philip@balister.org>
Acked-by: Khem Raj <raj.khem@gmail.com>
Acked-by: Marcin Juszkiewicz <hrw@openembedded.org>
Acked-by: Koen Kooi <koen@openembedded.org>
Acked-by: Frans Meulenbroeks <fransmeulenbroeks@gmail.com>
---
 recipes/irssi/irssi_0.8.10.bb | 66 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 recipes/irssi/irssi_0.8.10.bb

(limited to 'recipes/irssi/irssi_0.8.10.bb')

diff --git a/recipes/irssi/irssi_0.8.10.bb b/recipes/irssi/irssi_0.8.10.bb
new file mode 100644
index 0000000000..f67e8fe9c5
--- /dev/null
+++ b/recipes/irssi/irssi_0.8.10.bb
@@ -0,0 +1,66 @@
+DESCRIPTION = "Irssi is a modular IRC client with Perl scripting."
+HOMEPAGE = "http://irssi.org/"
+SECTION = "console/network"
+LICENSE = "GPL"
+DEPENDS += "ncurses glib-2.0"
+PR = "r2"
+
+PACKAGES += "${PN}-common"
+FILES_${PN} = "${bindir}/irssi"
+FILES_${PN}-common = "${datadir}/irssi ${sysconfdir}"
+RDEPENDS_${PN} += "${PN}-common"
+
+inherit autotools
+
+SRC_URI = "http://www.irssi.org/files/${P}.tar.bz2 \
+	   file://autofoo.patch;patch=1"
+
+EXTRA_OECONF = "--enable-ipv6 \
+		--disable-ssl \
+		--disable-glibtest \
+		--without-socks \
+		--with-textui \
+		--without-bot \
+		--without-proxy \
+		--without-glib1 \
+		--with-glib2 \
+		--with-perl=no \
+		--with-glib-prefix=${STAGING_LIBDIR}/.. \
+		--with-glib-exec-prefix=${STAGING_LIBDIR}/.. \
+		--with-ncurses=${STAGING_LIBDIR}/.."
+
+do_configure () {
+	# create help files
+	echo "Creating help files..."
+	perl syntax.pl
+
+	files=`echo docs/help/in/*.in|sed -e 's,docs/help/in/Makefile.in ,,' -e 's,docs/help/in/,!,g' -e 's/\.in /.in ?/g'`
+	cat docs/help/in/Makefile.am.gen|sed "s/@HELPFILES@/$files/g"|sed 's/?/\\?/g'|tr '!?' '\t\n' > docs/help/in/Makefile.am
+
+	files=`echo $files|sed 's/\.in//g'`
+	cat docs/help/Makefile.am.gen|sed "s/@HELPFILES@/$files/g"|sed 's/?/\\?/g'|tr '!?' '\t\n' > docs/help/Makefile.am
+
+	# .HTML -> .txt with lynx
+	# echo "Documentation: html -> txt..."
+	# lynx -dump -nolist docs/faq.html|perl -pe 's/^ *//; if ($_ eq "\n" && $state eq "Q") { $_ = ""; } elsif (/^([QA]):/) { $state = $1 } elsif ($_ ne "\n") { $_ = "   $_"; };' > docs/faq.txt
+	> docs/faq.txt
+
+	autotools_do_configure
+}
+
+do_stage () {
+	find . -name \*.h | for h in `cat`; do
+		install -d ${STAGING_LIBDIR}/../irssi/`dirname $h`
+		install -m 0644 $h ${STAGING_LIBDIR}/../irssi/$h
+	done
+	find . -name lib\*.a | for l in `cat`; do
+		install -d ${STAGING_LIBDIR}/../irssi/`dirname $l`
+		install -m 0644 $l ${STAGING_LIBDIR}/../irssi/$l
+	done
+	install -m 0644 irssi-config ${STAGING_LIBDIR}/../irssi/
+}
+
+do_install () {
+	autotools_do_install
+	rm -f ${D}${docdir}/irssi/faq.txt
+}
-- 
cgit v1.2.3