From 7b8667fa75578f7e6a4958a851296a02e27eb34e Mon Sep 17 00:00:00 2001
From: Michael Lauer <mickey@vanille-media.de>
Date: Wed, 15 Aug 2007 19:53:43 +0000
Subject: major python upgrade: add python[-native] 2.5.1, rename python-2.4
 package

---
 packages/python/python_2.5.1.bb | 84 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 84 insertions(+)
 create mode 100644 packages/python/python_2.5.1.bb

(limited to 'packages/python/python_2.5.1.bb')

diff --git a/packages/python/python_2.5.1.bb b/packages/python/python_2.5.1.bb
new file mode 100644
index 0000000000..a9d37a1ebb
--- /dev/null
+++ b/packages/python/python_2.5.1.bb
@@ -0,0 +1,84 @@
+DESCRIPTION = "Python Programming Language"
+HOMEPAGE = "http://www.python.org"
+LICENSE = "PSF"
+SECTION = "devel/python"
+PRIORITY = "optional"
+DEPENDS = "python-native readline zlib gdbm openssl sqlite3 tcl tk"
+DEPENDS_sharprom = "python-native readline zlib gdbm openssl"
+PR = "ml0"
+
+PYTHON_MAJMIN = "2.5"
+
+SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.bz2 \
+           file://bindir-libdir.patch;patch=1 \
+           file://crosscompile.patch;patch=1 \
+           file://fix-tkinter-detection.patch;patch=1 \
+           file://autohell.patch;patch=1 \
+           file://sitebranding.patch;patch=1"
+S = "${WORKDIR}/Python-${PV}"
+
+inherit autotools
+
+EXTRA_OECONF = "--with-threads --with-pymalloc --with-cyclic-gc \
+                --without-cxx --with-signal-module --with-wctype-functions \
+                --enable-shared"
+
+#
+# copy config.h and an appropriate Makefile for distutils.sysconfig
+# which laters uses the information out of these to compile extensions
+#
+do_compile_prepend() {
+	install -d ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
+	install -d ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
+	install -m 0644 pyconfig.h ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
+	install -m 0644 Makefile Makefile.orig
+	install -m 0644 Makefile Makefile.backup
+	sed -e 's,${includedir},${STAGING_INCDIR},' < Makefile.backup > Makefile
+	install -m 0644 Makefile Makefile.backup
+	sed -e 's,${libdir},${STAGING_LIBDIR},' < Makefile.backup > Makefile
+	install -m 0644 Makefile ${STAGING_LIBDIR}/python${PYTHON_MAJMIN}/config/
+}
+
+do_compile() {
+	oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
+		   HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
+		   STAGING_LIBDIR=${STAGING_LIBDIR} \
+		   STAGING_INCDIR=${STAGING_INCDIR} \
+		   BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
+		   OPT="${CFLAGS}"
+}
+
+do_stage() {
+	install -m 0644 Include/*.h ${STAGING_INCDIR}/python${PYTHON_MAJMIN}/
+	oe_libinstall -a -so libpython${PYTHON_MAJMIN} ${STAGING_LIBDIR}
+}
+
+do_install() {
+	install -m 0644 Makefile.orig Makefile
+        oe_runmake HOSTPGEN=${STAGING_BINDIR_NATIVE}/pgen \
+                   HOSTPYTHON=${STAGING_BINDIR_NATIVE}/python \
+                   STAGING_LIBDIR=${STAGING_LIBDIR} \
+                   STAGING_INCDIR=${STAGING_INCDIR} \
+		   BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
+		   DESTDIR=${D} install
+}
+
+require python-${PYTHON_MAJMIN}-manifest.inc
+
+RPROVIDES_python-core = "python"
+RPROVIDES_python-curses = "python"
+
+PACKAGES =+ "libpython2"
+FILES_libpython2 = "${libdir}/libpython*"
+
+# catch debug extensions
+FILES_python-dbg += "${libdir}/python${PYTHON_MAJMIN}/lib-dynload/.debug"
+
+# catch all the rest (unsorted)
+PACKAGES += "python-misc"
+FILES_python-misc = "${libdir}/python${PYTHON_MAJMIN}"
+
+# catch manpage
+PACKAGES += "python-man"
+FILES_python-man = "${datadir}/man"
+
-- 
cgit v1.2.3


From a71e0b7fd43bde934854cfd5ad3e8dad2df87948 Mon Sep 17 00:00:00 2001
From: Michael Lauer <mickey@vanille-media.de>
Date: Wed, 15 Aug 2007 20:06:49 +0000
Subject: python[-native] 2.5.1: add patch to compile everything in optimized
 bytecode. This also reduces the packaging size / flash consumption

---
 packages/python/python_2.5.1.bb | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

(limited to 'packages/python/python_2.5.1.bb')

diff --git a/packages/python/python_2.5.1.bb b/packages/python/python_2.5.1.bb
index a9d37a1ebb..6cf14735f1 100644
--- a/packages/python/python_2.5.1.bb
+++ b/packages/python/python_2.5.1.bb
@@ -14,7 +14,8 @@ SRC_URI = "http://www.python.org/ftp/python/${PV}/Python-${PV}.tar.bz2 \
            file://crosscompile.patch;patch=1 \
            file://fix-tkinter-detection.patch;patch=1 \
            file://autohell.patch;patch=1 \
-           file://sitebranding.patch;patch=1"
+           file://sitebranding.patch;patch=1 \
+           file://default-is-optimized.patch;patch=1"
 S = "${WORKDIR}/Python-${PV}"
 
 inherit autotools
-- 
cgit v1.2.3