From ecb1a9ebc036bfb90e50b1e156d830c75dfe2436 Mon Sep 17 00:00:00 2001
From: "nslu2-linux.adm@bkbits.net" <nslu2-linux.adm@bkbits.net>
Date: Mon, 3 Jan 2005 21:40:08 +0000
Subject: Merge bk://oe-devel.bkbits.net/openembedded into
 bkbits.net:/repos/n/nslu2-linux/openembedded

2005/01/03 22:31:46+01:00 hrw.one.pl!hrw
timesleuth is not game so moved from qpe-games to own directory

2005/01/03 22:23:43+01:00 hrw.one.pl!hrw
added opie/security SECTION for opie-security plugins as they were packaged like normal applications before

BKrev: 41d9bbb8deZoVHyqhZXAuipJBrYREw
---
 classes/opie.bbclass | 95 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 95 insertions(+)

(limited to 'classes/opie.bbclass')

diff --git a/classes/opie.bbclass b/classes/opie.bbclass
index e69de29bb2..55b3a9cb6e 100644
--- a/classes/opie.bbclass
+++ b/classes/opie.bbclass
@@ -0,0 +1,95 @@
+#
+# This oeclass takes care about some of the itchy details of installing parts
+# of Opie applications. Depending on quicklaunch or not, plugin or not, the
+# TARGET is either a shared object, a shared object with a link to quicklauncher,
+# or a usual binary.
+# 
+# You have to provide two things: 1.) A proper SECTION field, and 2.) a proper APPNAME
+# Then opie.oeclass will:
+#    * create the directory for the binary and install the binary file(s)
+#    * for applications: create the directory for the .desktop and install the .desktop file
+#    * for quicklauncher applications: create the startup symlink to the quicklauncher
+# You can override the automatic detection of APPTYPE, valid values are 'quicklaunch', 'binary', 'plugin'
+# You can override the default location of APPDESKTOP (<workdir>/apps/<section>/)
+#
+
+inherit palmtop
+
+DEPENDS_prepend = "${@["libopie2 ", ""][(bb.data.getVar('PN', d, 1) == 'libopie2')]}"
+
+# to be consistent, put all targets into workdir
+EXTRA_QMAKEVARS_POST_append = " DESTDIR=${S}"
+
+# plan for later:
+# add common scopes for opie applications, see qmake-native/common.pro
+# qmake should care about all the details then. qmake can do that, i know it :)
+#
+
+python opie_do_opie_install() {
+	import os, shutil
+	section = bb.data.getVar( "SECTION", d ).split( '/' )[1] or "Applications"
+	section = section.title()
+	if section in ( "Base", "Libs" ):
+		bb.note( "Section = Base or Libs. Target won't be installed automatically." )
+		return
+
+	#               SECTION         : BINDIR			DESKTOPDIR
+	dirmap = { 	"Applets" 	: ( "/plugins/applets",		None 			),
+			"Applications" 	: ( "<BINDIR>",			"/apps/Applications" 	),
+			"Multimedia"	: ( "<BINDIR>",			"/apps/Applications"	),
+			"Games"		: ( "<BINDIR>",			"/apps/Games"		),
+			"Settings"	: ( "<BINDIR>",			"/apps/Settings"	),
+			"Pim"		: ( "<BINDIR>",			"/apps/1Pim"		),
+			"Examples"	: ( "<BINDIR>",			"/apps/Examples"	),
+			"Shell"		: ( "/bin",			"/apps/Opie-SH"		),
+			"Codecs"	: ( "/plugins/codecs",		None			),
+			"Decorations"	: ( "/plugins/decorations",	None			),
+			"Inputmethods"	: ( "/plugins/inputmethods",	None			),
+			"Fontfactories" : ( "/plugins/fontfactories",	None			),
+			"Security"	: ( "/plugins/security",	None			),
+			"Styles"	: ( "/plugins/styles",		None			),
+			"Today"		: ( "/plugins/today",		None			),
+		"Networksettings"	: ( "/plugins/networksettings", None			) }
+
+	if section not in dirmap:
+		raise ValueError, "Unknown section '%s'. Valid sections are: %s" % ( section, dirmap.keys() )
+	
+	bindir, desktopdir = dirmap[section]
+	APPNAME = bb.data.getVar( "APPNAME", d, True ) or bb.data.getVar( "PN", d, True )
+	APPTYPE = bb.data.getVar( "APPTYPE", d, True )
+	if not APPTYPE:
+		if bindir == "<BINDIR>":
+			APPTYPE = "quicklaunch"
+		else:
+			APPTYPE = "plugin"
+
+	appmap = { "binary":"/bin", "quicklaunch":"/plugins/application" }
+	if bindir == "<BINDIR>": bindir = appmap[APPTYPE]
+	
+	bb.note( "Section='%s', bindir='%s', desktopdir='%s', name='%s', type='%s'" %
+               ( section, bindir, desktopdir, APPNAME, APPTYPE ) )
+
+	S = bb.data.getVar( "S", d, 1 )
+	D = "%s/image" % bb.data.getVar( "WORKDIR", d, True )
+	WORKDIR = bb.data.getVar( "WORKDIR", d, True )
+	palmtopdir = bb.data.getVar( "palmtopdir", d )
+	APPDESKTOP = bb.data.getVar( "APPDESKTOP", d, True ) or "%s/%s" % ( WORKDIR, desktopdir )
+
+	if desktopdir is not None:
+		os.system( "install -d %s%s%s/" % ( D, palmtopdir, desktopdir ) )
+		os.system( "install -m 0644 %s/%s.desktop %s%s%s/" % ( APPDESKTOP, APPNAME, D, palmtopdir, desktopdir ) )
+
+	os.system( "install -d %s%s%s/" % ( D, palmtopdir, bindir ) )
+
+	if APPTYPE == "binary":
+		os.system( "install -m 0755 %s/%s %s%s%s/" % ( S, APPNAME, D, palmtopdir, bindir ) )
+	elif APPTYPE == "quicklaunch":
+		os.system( "install -m 0755 %s/lib%s.so %s%s%s/" % ( S, APPNAME, D, palmtopdir, bindir ) )
+		os.system( "install -d %s%s/bin/" % ( D, palmtopdir ) )
+		os.system( "ln -sf %s/bin/quicklauncher %s%s/bin/%s" % ( palmtopdir, D, palmtopdir, APPNAME ) )
+	elif APPTYPE == "plugin":
+		os.system( "install -m 0755 %s/lib%s.so %s%s%s/" % ( S, APPNAME, D, palmtopdir, bindir ) )
+}
+
+EXPORT_FUNCTIONS do_opie_install
+addtask opie_install after do_compile before do_populate_staging
-- 
cgit v1.2.3