From 5712bead144acbf3d1c264ca2d373a048962f5d2 Mon Sep 17 00:00:00 2001
From: "nslu2-linux.adm@bkbits.net" <nslu2-linux.adm@bkbits.net>
Date: Mon, 27 Dec 2004 16:40:13 +0000
Subject: Merge bk://oe-devel.bkbits.net/openembedded into
bkbits.net:/repos/n/nslu2-linux/openembedded
2004/12/27 17:20:39+01:00 handhelds.org!CoreDump
Merge bk://oe-devel@oe-devel.bkbits.net/openembedded
into handhelds.org:/home/mhentges/OpenEmbedded/bitbake/openembedded
2004/12/27 17:18:36+01:00 handhelds.org!CoreDump
pcmcia-cs/etc/ide: Allow custom scripts to be executed.
This allows for a more intelligent CF auto-mounter.
A script for Zs will follow after some field-testing
BKrev: 41d03aedDspF93aBk745Fvb_9AoJYQ
---
packages/pcmcia-cs/pcmcia-cs-3.2.8/automount.patch | 0
packages/pcmcia-cs/pcmcia-cs_3.2.8.bb | 87 ++++++++++++++++++++++
2 files changed, 87 insertions(+)
create mode 100644 packages/pcmcia-cs/pcmcia-cs-3.2.8/automount.patch
diff --git a/packages/pcmcia-cs/pcmcia-cs-3.2.8/automount.patch b/packages/pcmcia-cs/pcmcia-cs-3.2.8/automount.patch
new file mode 100644
index 0000000000..e69de29bb2
diff --git a/packages/pcmcia-cs/pcmcia-cs_3.2.8.bb b/packages/pcmcia-cs/pcmcia-cs_3.2.8.bb
index e69de29bb2..4e51de56cb 100644
--- a/packages/pcmcia-cs/pcmcia-cs_3.2.8.bb
+++ b/packages/pcmcia-cs/pcmcia-cs_3.2.8.bb
@@ -0,0 +1,87 @@
+DESCRIPTION = "Utilities and system configuration files for the Linux PCMCIA card services"
+SECTION = "base"
+PRIORITY = "required"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel"
+PR = "r10"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/pcmcia-cs/pcmcia-cs-${PV}.tar.gz \
+ file://busybox.patch;patch=1 \
+ file://network.patch;patch=1 \
+ file://pcic-extra.patch;patch=1 \
+ file://automount.patch;patch=1 \
+ file://pcmcia \
+ file://ide.opts \
+ file://wireless.opts \
+ file://network.conf \
+ file://wnv.conf"
+S = "${WORKDIR}/pcmcia-cs-${PV}"
+
+INITSCRIPT_NAME = "pcmcia"
+INITSCRIPT_PARAMS = "defaults"
+
+inherit update-rc.d
+
+export KERNEL_SOURCE = ${@base_read_file('${STAGING_DIR}/${HOST_SYS}/kernel/kernel-source')}
+
+sbindir = "/sbin"
+
+do_configure() {
+ touch .prereq.ok
+ touch config.out
+ cat >config.mk <<EOF
+UCC=${CC}
+UFLAGS=${CFLAGS} -I${S}/include
+HAS_WORDEXP=y
+SYSV_INIT=y
+RC_DIR=/etc
+CONFIG_PNP_BIOS=n
+ARCH=${ARCH}
+CONFIG_CARDBUS=n
+CONFIG_PCMCIA=y
+CONFIG_INET=y
+CONFIG_SCSI=y
+DO_IDE=y
+EOF
+ cat >include/pcmcia/autoconf.h <<EOF
+#define HAS_WORDEXP 1
+EOF
+}
+
+do_compile() {
+ oe_runmake all HAS_XPM= FLIBS="" XMANDIR=""
+}
+
+INSTALL_ETC = "ftl ide ieee1394 memory network parport scsi serial wireless"
+INSTALL_ETC_DATA = "config config.opts ftl.opts ieee1394.opts memory.opts network.opts parport.opts scsi.opts serial.opts shared"
+
+do_install() {
+ install -d ${D}/${sbindir}
+ for f in cardmgr/cardctl cardmgr/cardmgr cardmgr/ide_info cardmgr/ifport cardmgr/ifuser cardmgr/pcinitrd flash/ftl_check flash/ftl_format
+ do
+ install -m 0755 $f ${D}/${sbindir}/
+ done
+ install -d ${D}/${sysconfdir}/init.d \
+ ${D}/${sysconfdir}/pcmcia \
+ ${D}/${sysconfdir}/pcmcia/cis
+
+ install -m 0644 ${WORKDIR}/network.conf ${D}/${sysconfdir}/pcmcia/
+ install -m 0644 ${WORKDIR}/wnv.conf ${D}/${sysconfdir}/pcmcia/
+
+ for i in ${INSTALL_ETC}; do
+ install etc/${i} ${D}/${sysconfdir}/pcmcia/
+ done
+ for i in ${INSTALL_ETC_DATA}; do
+ install -m 0644 etc/${i} ${D}/${sysconfdir}/pcmcia/
+ done
+ install -m 0644 ${WORKDIR}/ide.opts ${D}/${sysconfdir}/pcmcia/
+ install -m 0644 ${WORKDIR}/wireless.opts ${D}/${sysconfdir}/pcmcia/
+ for i in etc/cis/*; do
+ install -m 0644 $i ${D}/${sysconfdir}/pcmcia/cis/
+ done
+ install -m 0755 etc/rc.pcmcia ${D}/${sysconfdir}/init.d/pcmcia
+ install -d ${D}/${sysconfdir}/sysconfig
+ install -m 0755 ${WORKDIR}/pcmcia ${D}/${sysconfdir}/sysconfig/pcmcia
+}
+
+FILES_${PN} = "${sbindir} ${sysconfdir}"
--
cgit v1.2.3