From 4a208a12d4b7ed168ba7ce81006010ea32d4e955 Mon Sep 17 00:00:00 2001
From: Philipp Zabel <philipp.zabel@gmail.com>
Date: Fri, 22 Sep 2006 09:55:25 +0000
Subject: linux-libc-headers: add 2.6.18, generated by make headers_install

---
 .../linux-libc-headers_2.6.18.bb                   | 70 ++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 packages/linux-libc-headers/linux-libc-headers_2.6.18.bb

diff --git a/packages/linux-libc-headers/linux-libc-headers_2.6.18.bb b/packages/linux-libc-headers/linux-libc-headers_2.6.18.bb
new file mode 100644
index 0000000000..7fbd7542f0
--- /dev/null
+++ b/packages/linux-libc-headers/linux-libc-headers_2.6.18.bb
@@ -0,0 +1,70 @@
+SECTION = "devel"
+DESCRIPTION = "Sanitized set of 2.6 kernel headers for the C library's use."
+LICENSE = "GPL"
+DEFAULT_PREFERENCE = "-1"
+INHIBIT_DEFAULT_DEPS = "1"
+PR = "r0"
+
+SRC_URI = "http://www.kernel.org/pub/linux/kernel/v2.6/linux-2.6.18.tar.bz2"
+
+S = "${WORKDIR}/linux-2.6.18"
+
+set_arch() {
+	case ${TARGET_ARCH} in
+		alpha*)   ARCH=alpha ;;
+		arm*)     ARCH=arm ;;
+		cris*)    ARCH=cris ;;
+		hppa*)    ARCH=parisc ;;
+		i*86*)    ARCH=i386 ;;
+		ia64*)    ARCH=ia64 ;;
+		mips*)    ARCH=mips ;;
+		m68k*)    ARCH=m68k ;;
+		powerpc*) ARCH=ppc ;;
+		s390*)    ARCH=s390 ;;
+		sh*)      ARCH=sh ;;
+		sparc64*) ARCH=sparc64 ;;
+		sparc*)   ARCH=sparc ;;
+		x86_64*)  ARCH=x86_64 ;;
+	esac
+}
+
+do_configure() {
+	set_arch
+	oe_runmake allnoconfig ARCH=${ARCH}
+}
+
+do_compile () {
+}
+
+do_install() {
+	set_arch
+	oe_runmake headers_install INSTALL_HDR_PATH=${D}/usr ARCH=${ARCH}
+}
+
+do_install_append_arm() {
+	cp include/asm-arm/procinfo.h ${D}${includedir}/asm
+}
+
+STAGE_TEMP="${WORKDIR}/temp-staging"
+
+do_stage () {
+	set_arch
+	rm -rf ${STAGE_TEMP}
+	mkdir -p ${STAGE_TEMP}
+	oe_runmake headers_install INSTALL_HDR_PATH=${STAGE_TEMP}/usr ARCH=${ARCH}
+	if [ "${ARCH}" == "arm" ]; then
+		cp include/asm-arm/procinfo.h ${STAGE_TEMP}${includedir}/asm
+	fi
+	install -d ${STAGING_INCDIR}
+	rm -rf ${STAGING_INCDIR}/linux ${STAGING_INCDIR}/asm ${STAGING_INCDIR}/asm-generic
+	cp -pfLR ${STAGE_TEMP}${includedir}/linux ${STAGING_INCDIR}/
+	cp -pfLR ${STAGE_TEMP}${includedir}/asm ${STAGING_INCDIR}/
+	cp -pfLR ${STAGE_TEMP}${includedir}/asm-generic ${STAGING_INCDIR}/
+	rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/linux
+	rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/asm
+	rm -rf ${CROSS_DIR}/${TARGET_SYS}/include/asm-generic
+	install -d ${CROSS_DIR}/${TARGET_SYS}/include
+	cp -pfLR ${STAGE_TEMP}${includedir}/linux ${CROSS_DIR}/${TARGET_SYS}/include/
+	cp -pfLR ${STAGE_TEMP}${includedir}/asm ${CROSS_DIR}/${TARGET_SYS}/include/
+	cp -pfLR ${STAGE_TEMP}${includedir}/asm-generic ${CROSS_DIR}/${TARGET_SYS}/include/
+}
-- 
cgit v1.2.3