rpm/rpm-native: Add recipe for 4.4.2.3 (from Poky)

Squashed set of changes from Poky:

svn r5069 - rpm/rpm-native: Add recipe for 4.4.2.3
svn r5085 - rpm: Patch out some Makefile strangeness causing build failures
svn r5093 - rpm: Enable python extensions and improve cross compiling patches
svn r5103 - rpm: Tweak patches to remove popt problem
svn r5113 - rpm: Add recommends support from suse rpm patches
svn r5132 - rpm-native: Set varprefix to get the rpm database in a sane location
svn r5152 - rpm: Handle PYTHONVER differently in EXTRA_OECONF to stop gettext/uclibc failures during parsing
svn r5154 - rpm: Add missing patches
svn r5423 - rpm: Add python module packaging

OE changes:

rpm-native: add Python 2.6 support
rpm: use distutils-base to get Python version
rpm: use sed instead of ed - it is present in our metadata
rpm: set ARM_INSTRUCTION_SET as it fails to build for thumb

| /tmp/ccYO91se.s: Assembler messages:
| /tmp/ccYO91se.s:71: Error: selected processor does not support `swpb r2,r3,[r4]'
| /tmp/ccYO91se.s:72: Error: unshifted register required -- `eor r2,r2,#1'

1 files changed, 95 insertions, 0 deletions

diff --git a/recipes/rpm/rpm_4.4.2.3.bb b/recipes/rpm/rpm_4.4.2.3.bb
new file mode 100644
index 0000000000..6c2dc55e69
--- /dev/null
+++ b/recipes/rpm/rpm_4.4.2.3.bb
@@ -0,0 +1,95 @@
+DESCRIPTION = "The RPM Package Manager."
+HOMEPAGE = "http://rpm.org/"
+LICENSE = "LGPL GPL"
+DEPENDS = "zlib beecrypt file popt python sed-native"
+PR = "r13"
+
+SRC_URI = "http://www.rpm.org/releases/rpm-4.4.x/rpm-4.4.2.3.tar.gz \
+           file://external-tools.patch;patch=1 \
+	   file://cross_libpaths.patch;patch=1 \
+	   file://weakdeps.patch;patch=1;pnum=0 \
+	   file://tagsbackport.patch;patch=1;pnum=0 \
+	   file://missingok.patch;patch=1;pnum=0 \
+	   file://extcond.patch;patch=1;pnum=0"
+
+inherit autotools gettext distutils-base
+
+S = "${WORKDIR}/rpm-${PV}"
+
+ARM_INSTRUCTION_SET = "arm"
+
+acpaths = "-I ${S}/db/dist/aclocal -I ${S}/db/dist/aclocal_java"
+
+EXTRA_OECONF = "--with-python \
+		--with-python-incdir=${STAGING_INCDIR}/${PYTHON_DIR} \
+		--with-python-libdir=${libdir}/${PYTHON_DIR} \
+		--without-apidocs \
+		--without-selinux \
+		--without-lua \
+		--without-dmalloc \
+		--without-efence"
+
+PACKAGES += "python-rpm"
+FILES_python-rpm = "${libdir}/python*/site-recipes/rpm/_*"
+
+# Handle the db MUTEX settings here, the POSIX library is
+# the default - "POSIX/pthreads/library".
+# Don't ignore the nice SWP instruction on the ARM:
+# These enable the ARM assembler mutex code, this won't
+# work with thumb compilation...
+ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
+MUTEX = ""
+MUTEX_arm = "${ARM_MUTEX}"
+MUTEX_armeb = "${ARM_MUTEX}"
+EXTRA_OECONF += "${MUTEX}"
+
+export varprefix = "${localstatedir}"
+
+do_configure () {
+	rm ${S}/popt/ -Rf
+	rm ${S}/db/dist/configure.in -f
+	cd ${S}/db/dist/aclocal
+	rm libtool* -f
+	for i in `ls *.ac`; do
+	    j=`echo $i | sed 's/.ac/.m4/g'`
+	    mv $i $j
+	done
+	cd ${S}/db/dist/aclocal_java
+	for i in `ls *.ac`; do
+	    j=`echo $i | sed 's/.ac/.m4/g'`
+	    mv $i $j
+	done
+	cd ${S}
+	autotools_do_configure
+	cd ${S}/db/dist
+	. ./RELEASE
+	# Edit version information we couldn't pre-compute.
+	sed -i -e "s/__EDIT_DB_VERSION_MAJOR__/$DB_VERSION_MAJOR/g"  configure
+	sed -i -e "s/__EDIT_DB_VERSION_MINOR__/$DB_VERSION_MINOR/g"  configure
+	sed -i -e "s/__EDIT_DB_VERSION_PATCH__/$DB_VERSION_PATCH/g"  configure
+	sed -i -e "s/__EDIT_DB_VERSION_STRING__/$DB_VERSION_STRING/g"  configure
+	sed -i -e "s/__EDIT_DB_VERSION_UNIQUE_NAME__/$DB_VERSION_UNIQUE_NAME/g"  configure
+	sed -i -e "s/__EDIT_DB_VERSION__/$DB_VERSION/g"  configure
+	cd ${S}/db3
+	${S}/db3/configure \
+		    --build=${BUILD_SYS} \
+		    --host=${HOST_SYS} \
+		    --target=${TARGET_SYS} \
+		    --prefix=${prefix} \
+		    --exec_prefix=${exec_prefix} \
+		    --bindir=${bindir} \
+		    --sbindir=${sbindir} \
+		    --libexecdir=${libexecdir} \
+		    --datadir=${datadir} \
+		    --sysconfdir=${sysconfdir} \
+		    --sharedstatedir=${sharedstatedir} \
+		    --localstatedir=${localstatedir} \
+		    --libdir=${libdir} \
+		    --includedir=${includedir} \
+		    --oldincludedir=${oldincludedir} \
+		    --infodir=${infodir} \
+		    --mandir=${mandir} \
+		    ${EXTRA_OECONF} \
+		    --with-pic
+
+}