linux-handhelds-2.6: magician defconfig: I2C_PXA=y

2 files changed, 81 insertions, 0 deletions

diff --git a/packages/module-init-tools/module-init-tools-cross_3.2.2+3.3-pre1.bb b/packages/module-init-tools/module-init-tools-cross_3.2.2+3.3-pre1.bb
new file mode 100644
index 0000000000..1100e52c46
--- /dev/null
+++ b/packages/module-init-tools/module-init-tools-cross_3.2.2+3.3-pre1.bb
@@ -0,0 +1,16 @@
+LICENSE = "GPL"
+require module-init-tools_${PV}.bb
+inherit cross
+DEFAULT_PREFERENCE = "1"
+PROVIDES += "virtual/${TARGET_PREFIX}depmod virtual/${TARGET_PREFIX}depmod-2.6"
+
+EXTRA_OECONF_append = " --program-prefix=${TARGET_PREFIX}"
+
+do_stage () {
+        oe_runmake install
+        mv ${bindir}/${TARGET_PREFIX}depmod ${bindir}/${TARGET_PREFIX}depmod-2.6
+}
+
+do_install () {
+        :
+}
diff --git a/packages/module-init-tools/module-init-tools_3.2.2+3.3-pre1.bb b/packages/module-init-tools/module-init-tools_3.2.2+3.3-pre1.bb
new file mode 100644
index 0000000000..b155b4a740
--- /dev/null
+++ b/packages/module-init-tools/module-init-tools_3.2.2+3.3-pre1.bb
@@ -0,0 +1,65 @@
+DESCRIPTION = "This package contains a set of programs for loading, inserting, and \
+removing kernel modules for Linux (versions 2.5.48 and above). It serves \
+the same function that the modutils package serves for Linux 2.4."
+LICENSE = "GPL"
+SECTION = "base"
+PR = "r1"
+
+DEFAULT_PREFERENCE = "-1"
+
+PACKAGES =+ "module-init-tools-insmod-static module-init-tools-depmod"
+RDEPENDS_${PN} += "module-init-tools-depmod"
+
+FILES_module-init-tools-depmod = "${sbindir}/depmod.26"
+FILES_module-init-tools-insmod-static = "${sbindir}/insmod.static"
+
+SRC_URI = "ftp://ftp.kernel.org/pub/linux/utils/kernel/module-init-tools/module-init-tools-3.3-pre1.tar.bz2 \
+	   file://ignore_arch_directory;patch=1 \
+	   file://modutils_extension;patch=1 \
+	   file://no_man_rebuild;patch=1 \
+	   file://manpagesopt;patch=1 "
+S = "${WORKDIR}/module-init-tools-3.3-pre1"
+
+EXTRA_OECONF = "--disable-manpages"
+
+bindir = "/bin"
+sbindir = "/sbin"
+
+inherit autotools
+
+do_install() {
+	autotools_do_install
+	for f in bin/lsmod sbin/insmod sbin/rmmod sbin/modprobe sbin/modinfo sbin/depmod; do
+		mv ${D}/$f ${D}/$f.26
+	done
+}
+
+pkg_postinst_module-init-tools() {
+#!/bin/sh
+for f in sbin/insmod sbin/modprobe sbin/rmmod sbin/modinfo; do
+bn=`basename $f`
+   update-alternatives --install /$f $bn /$f.26 60
+done
+update-alternatives --install /bin/lsmod bin-lsmod /bin/lsmod.26 60
+update-alternatives --install /sbin/lsmod lsmod /bin/lsmod.26 60
+}
+
+pkg_prerm_module-init-tools() {
+#!/bin/sh
+for f in sbin/insmod sbin/modprobe sbin/rmmod sbin/modinfo; do
+bn=`basename $f`
+   update-alternatives --remove $bn /$f.26
+done
+update-alternatives --remove bin-lsmod /bin/lsmod.26
+update-alternatives --remove lsmod /bin/lsmod.26
+}
+
+pkg_postinst_module-init-tools-depmod() {
+#!/bin/sh
+update-alternatives --install /sbin/depmod depmod /sbin/depmod.26 60
+}
+
+pkg_prerm_module-init-tools-depmod() {
+#!/bin/sh
+update-alternatives --remove depmod /sbin/depmod.26
+}