merge of '603b2d0c7e4ad80e5779bd3bbdb822331cc0ea2b'

     and '6ab53da82d157971966f5a17d0c29d54df22cac9'

1 files changed, 50 insertions, 0 deletions

diff --git a/packages/libpng/libpng_1.2.20.bb b/packages/libpng/libpng_1.2.20.bb
new file mode 100644
index 0000000000..c6c296cae4
--- /dev/null
+++ b/packages/libpng/libpng_1.2.20.bb
@@ -0,0 +1,50 @@
+DESCRIPTION = "PNG Library"
+HOMEPAGE = "http://www.libpng.org/"
+LICENSE = "libpng"
+SECTION = "libs"
+DEPENDS = "zlib"
+PRIORITY = "required"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/libpng/libpng-${PV}.tar.bz2"
+S = "${WORKDIR}/libpng-${PV}"
+
+inherit autotools binconfig pkgconfig
+
+do_stage() {
+	cp libpng.pc libpng12.pc
+	install -m 644 png.h ${STAGING_INCDIR}/png.h
+	install -m 644 pngconf.h ${STAGING_INCDIR}/pngconf.h
+	oe_libinstall -so libpng ${STAGING_LIBDIR}/
+	oe_libinstall -so libpng12 ${STAGING_LIBDIR}/
+	ln -sf libpng12.so ${STAGING_LIBDIR}/libpng.so
+}
+
+do_install() {
+	install -d ${D}${bindir}
+	install -d ${D}${mandir}
+	install -d ${D}${libdir}
+	install -d ${D}${includedir}
+	unset LDFLAGS
+	oe_runmake 'prefix=${prefix}' 'DESTDIR=${D}' \
+		   'DB=${D}${bindir}' 'DI=${D}${includedir}' \
+		   'DL=${D}${libdir}' 'DM=${D}${mandir}' \
+		   install
+}
+
+python do_package() {
+        if bb.data.getVar('DEBIAN_NAMES', d, 1):
+            bb.data.setVar('PKG_${PN}', 'libpng12', d)
+        bb.build.exec_func('package_do_package', d)
+}
+
+PACKAGES =+ "${PN}12-dbg ${PN}12 ${PN}12-dev"
+
+FILES_${PN}12-dbg = "${libdir}/libpng12*.dbg"
+FILES_${PN}12 = "${libdir}/libpng12.so.*"
+FILES_${PN}12-dev = "${libdir}/libpng12.* ${includedir}/libpng12 ${libdir}/pkgconfig/libpng12.pc"
+FILES_${PN} = "${libdir}/lib*.so.*"
+FILES_${PN}-dev = "${includedir} ${libdir}/lib*.so ${libdir}/*.la \
+        ${libdir}/*.a ${libdir}/pkgconfig \
+        ${datadir}/aclocal ${bindir} ${sbindir}"
+