Merge bk://oe-devel.bkbits.net/openembedded

into bkbits.net:/repos/n/nslu2-linux/openembedded

2005/02/21 17:35:27-06:00 ti.com!kergoth
Kill the ipkg paths patch, since its busted.

2005/02/21 17:33:13-06:00 ti.com!kergoth
Fix sbindir in native.bbclass and cross.bbclass.  Thanks to Jordan Crouse for reporting.

2005/02/21 17:13:19-06:00 ti.com!kergoth
Add the paths patch to ipkg which fixes it to no longer hardcode the '/usr/lib/ipkg' path, which I forgot to check in from the previous commit.

2005/02/21 17:09:46-06:00 ti.com!kergoth
Merge oe-devel@oe-devel.bkbits.net:openembedded
into odin.sc.ti.com:/home/kergoth/code/user/oe/openembedded

2005/02/21 17:09:03-06:00 ti.com!kergoth
Run a sed script against our packages to fix some hardcoded target path
references.  As always when I do things like this, if packages you maintain
were touched by this, please do a sanity check to ensure the sed script didn't
run wild.

2005/02/21 15:49:47-06:00 ti.com!kergoth
Use a HOTPLUG variable to manage which hotplug you prefer, to ensure that hotplug is still included in task-bootstrap even if you dont set DISTRO.

BKrev: 421b2b63X5eoMcSrC7pVcptXK-iFKg

2 files changed, 323 insertions, 0 deletions

diff --git a/packages/gcc-csl/gcc-csl-cross_2004-q1a.bb b/packages/gcc-csl/gcc-csl-cross_2004-q1a.bb
index e69de29bb2..d74fb4fa3d 100644
--- a/packages/gcc-csl/gcc-csl-cross_2004-q1a.bb
+++ b/packages/gcc-csl/gcc-csl-cross_2004-q1a.bb
@@ -0,0 +1,93 @@
+SECTION = "devel"
+include gcc-csl_${PV}.bb
+inherit cross
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/gcc-csl-${PV}"
+
+DEPENDS = "virtual/${TARGET_PREFIX}binutils virtual/${TARGET_PREFIX}libc-for-gcc"
+PROVIDES = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
+
+# Files for these are defined in the main gcc.oe
+PACKAGES = "libgcc libstdc++ libg2c"
+INHIBIT_PACKAGE_STRIP = "1"
+
+EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
+		      --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
+
+export CPPFLAGS = ""
+export CXXFLAGS = ""
+export CFLAGS = ""
+export LDFLAGS = ""
+
+do_configure () {
+	rm -f ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/3.4.0/libgcc_eh.a
+	(cd ${S} && gnu-configize) || die "failure running gnu-configize"
+	oe_runconf
+}
+
+do_compile_prepend () {
+	export CC="${BUILD_CC}"
+	export AR_FOR_TARGET="${TARGET_SYS}-ar"
+	export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
+	export LD_FOR_TARGET="${TARGET_SYS}-ld"
+	export NM_FOR_TARGET="${TARGET_SYS}-nm"
+	export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
+}
+
+do_stage_append () {
+	for d in info man share/doc share/locale ; do
+		rm -rf ${CROSS_DIR}/$d
+	done
+
+	# These aren't useful on the cross toolchain
+	rm -f ${CROSS_DIR}/bin/*gcov
+	rm -f ${CROSS_DIR}/bin/*gccbug
+
+	# Fix a few include links so cross builds are happier
+	if [ ! -e ${STAGING_INCDIR}/c++ ]; then
+		mkdir -p ${STAGING_INCDIR}
+		ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
+			${STAGING_INCDIR}/
+	fi
+
+	# We use libiberty from binutils
+	rm -f ${CROSS_DIR}/lib/libiberty.a
+
+	# We probably don't need these
+	rmdir ${CROSS_DIR}/include || :
+
+	# We don't really need to keep this around
+	rm -rf ${CROSS_DIR}/share
+}
+
+python do_package() {
+	if bb.data.getVar('DEBIAN_NAMES', d, 1):
+		bb.data.setVar('PKG_libgcc', 'libgcc1', d)
+	bb.build.exec_func('package_do_package', d)
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/${base_libdir}
+	if [ -f ${D}/${base_libdir}/libgcc_s.so.? ]; then
+		# Already in the right location
+		:
+	elif [ -f ${D}/${prefix}/lib/libgcc_s.so.? ]; then
+		mv -f ${D}/${prefix}/lib/libgcc_s.so.* ${D}/${base_libdir}
+	else
+		mv -f ${D}/${prefix}/*/lib/libgcc_s.so.* ${D}/${base_libdir}
+	fi
+
+	# Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
+	TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
+	mkdir -p ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libstdc++.so.* ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libg2c.so.* ${D}/${TGT_LIBDIR}
+
+	# Manually run the target stripper since we won't get it run by
+	# the packaging.
+	${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libstdc++.so.*
+	${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libg2c.so.*
+	${TARGET_PREFIX}strip ${D}/${base_libdir}gcc_s.so.*
+}
diff --git a/packages/gcc-csl/gcc-csl_2004-q1a.bb b/packages/gcc-csl/gcc-csl_2004-q1a.bb
index e69de29bb2..c4839792c0 100644
--- a/packages/gcc-csl/gcc-csl_2004-q1a.bb
+++ b/packages/gcc-csl/gcc-csl_2004-q1a.bb
@@ -0,0 +1,230 @@
+SECTION = "devel"
+inherit autotools gettext
+
+DESCRIPTION = "The GNU cc and gcc C compilers."
+LICENSE = "GPL"
+MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
+BROKEN = "1"
+
+# libgcc libstdc++ libg2c are listed in our FILES_*, but are actually
+# packaged in the respective cross packages.
+PACKAGES = "${PN} ${PN}-symlinks \
+            ${PN}-c++ ${PN}-c++-symlinks \
+            ${PN}-f77 ${PN}-f77-symlinks \
+            libstdc++-dev libg2c-dev \
+            ${PN}-doc"
+
+FILES_${PN} = "${bindir}/${TARGET_PREFIX}gcc \
+	       ${bindir}/${TARGET_PREFIX}cpp \
+	       ${bindir}/${TARGET_PREFIX}gcov \
+	       ${bindir}/${TARGET_PREFIX}gccbug \
+	       ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1 \
+	       ${libexecdir}/gcc/${TARGET_SYS}/${PV}/collect2 \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/*.o \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/specs \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/lib* \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/include"
+
+FILES_${PN}-symlinks = "${bindir}/cc \
+			${bindir}/gcc \
+			${bindir}/cpp \
+			${bindir}/gcov \
+			${bindir}/gccbug"
+
+FILES_${PN}-f77 = "${bindir}/${TARGET_PREFIX}g77 \
+		   ${libexecdir}/gcc/${TARGET_SYS}/${PV}/f771"
+
+FILES_${PN}-f77-symlinks = "${bindir}/g77 \
+			    ${bindir}/f77"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libg2c = "${libdir}/libg2c.so.*"
+FILES_libg2c = "${libdir}/libg2c.so.*"
+
+FILES_libg2c-dev = "${libdir}/libg2c.so \
+			  ${libdir}/libg2c.a \
+			  ${libdir}/libfrtbegin.a"
+
+FILES_${PN}-c++ = "${bindir}/${TARGET_PREFIX}g++ \
+		   ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1plus"
+
+FILES_${PN}-c++-symlinks = "${bindir}/c++ \
+			    ${bindir}/g++"
+
+FILES_libgcc = "/lib/libgcc_s.so.*"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libstdc++ = "${libdir}/libstdc++.so.*"
+FILES_libstdc++ = "${libdir}/libstdc++.so.*"
+
+FILES_libstdc++-dev = "${includedir}/c++/${PV} \
+		       ${libdir}/libstdc++.so \
+		       ${libdir}/libstdc++.la \
+		       ${libdir}/libstdc++.a \
+		       ${libdir}/libsupc++.la \
+		       ${libdir}/libsupc++.a"
+
+FILES_${PN}-doc = "${infodir} \
+		   ${mandir} \
+		   ${libdir}/gcc/${TARGET_SYS}/${PV}/include/README"
+
+#	   file://gcc34-pre-modify.patch;patch=1
+SRC_URI = "http://www.codesourcery.com/public/gnu_toolchain/arm/2004-Q1A/gcc-${PV}.tar.gz \
+	   file://gcc34-reverse-compare.patch;patch=1 \
+	   file://gcc34-arm-ldm.patch;patch=1 \
+	   file://gcc34-arm-ldm-peephole.patch;patch=1 \
+	   file://gcc34-arm-tune.patch;patch=1 \
+	   file://gcc34-15089.patch;patch=1 \
+	   file://gcc34-15666.patch;patch=1 \
+	   file://gcc-uclibc-3.4.0-100-conf.patch;patch=1 \
+	   file://gcc-uclibc-3.4.0-200-code.patch;patch=1 \
+	   file://gcc-3.4.0-arm-lib1asm.patch;patch=1 \
+	   file://gcc-3.4.0-arm-nolibfloat.patch;patch=1"
+
+python do_unpack () {
+	bb.build.exec_func('base_do_unpack', d)
+	bb.build.exec_func('fix_perms', d)
+}
+
+fix_perms () {
+	chmod -R u+w ${S}
+}
+
+gccbuild_uclibc_do_patch () {
+	#
+	# Hack things to use the correct shared lib loader
+	#
+	#LIST=`grep -lr -- "-dynamic-linker.*\.so[\.0-9]*" .`
+	#if [ -n "$LIST" ] ; then
+	#	perl -i -p -e "s,-dynamic-linker.*\.so[\.0-9]*},-dynamic-linker /lib/ld-uClibc.so.0},;" $LIST
+	#fi
+
+	#
+	# Prevent system glibc start files from leaking in uninvited...
+	#
+	perl -i -p -e "s,standard_startfile_prefix_1 = \".*,standard_startfile_prefix_1 = \"${CROSS_DIR}/${TARGET_SYS}/lib/\";,;" gcc/gcc.c
+	perl -i -p -e "s,standard_startfile_prefix_2 = \".*,standard_startfile_prefix_2 = \"${CROSS_DIR}/${TARGET_SYS}/usr/lib/\";,;" gcc/gcc.c
+
+	#
+	# Prevent system glibc include files from leaking in uninvited...
+	#
+	perl -i -p -e "s,^NATIVE_SYSTEM_HEADER_DIR.*,NATIVE_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
+	perl -i -p -e "s,^CROSS_SYSTEM_HEADER_DIR.*,CROSS_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
+	perl -i -p -e "s,^#define.*STANDARD_INCLUDE_DIR.*,#define STANDARD_INCLUDE_DIR \"${CROSS_DIR}/${TARGET_SYS}/include\",;" gcc/cppdefault.h
+
+	#
+	# Prevent system glibc libraries from being found by collect2 
+	# when it calls locatelib() and rummages about the system looking 
+	# for libraries with the correct name...
+	#
+	perl -i -p -e "s,\"/lib,\"${CROSS_DIR}/${TARGET_SYS}/lib,g;" \
+		gcc/collect2.c
+	perl -i -p -e "s,\"/usr/,\"${CROSS_DIR}/${TARGET_SYS}/usr/,g;" \
+		gcc/collect2.c
+
+	#
+	# Prevent gcc from using the unwind-dw2-fde-glibc code
+	#
+	perl -i -p -e "s,^#ifndef inhibit_libc,#define inhibit_libc
+#ifndef inhibit_libc,g;" gcc/unwind-dw2-fde-glibc.c
+}
+
+python do_patch () {
+    import bb, re
+    bb.build.exec_func('base_do_patch', d)
+    if (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None):
+        bb.build.exec_func('gccbuild_uclibc_do_patch', d)
+}
+
+S = "${WORKDIR}/gcc-${PV}"
+B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
+
+EXTRA_OECONF = "--with-gnu-ld \
+                --enable-shared \
+                --enable-multilib \
+                --enable-target-optspace \
+                --enable-languages=c,c++,f77 \
+                --enable-threads=posix \
+                --enable-c99 \
+                --enable-long-long \
+                --enable-symvers=gnu \
+                --program-prefix=${TARGET_PREFIX} \
+                ${EXTRA_OECONF_PATHS} \
+                ${EXTRA_OECONF_DEP}"
+
+EXTRA_OECONF_PATHS = "--with-local-prefix=${prefix}/local \
+                      --with-gxx-include-dir=${includedir}/c++/${PV}"
+
+EXTRA_OECONF_DEP = ""
+EXTRA_OECONF_uclibc = "--disable-__cxa_atexit"
+EXTRA_OECONF_glibc = "--enable-__cxa_atexit"
+EXTRA_OECONF_append_ramses = " --with-float=soft "
+
+python __anonymous () {
+    import bb, re
+    if (re.match('linux-uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None):
+        bb.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_uclibc}', d)
+    elif (re.match('linux$', bb.data.getVar('TARGET_OS', d, 1)) != None):
+        bb.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_glibc}', d)
+}
+
+do_configure () {
+	# Setup these vars for cross building only
+	if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
+		export CC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+		export GCC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+		export CXX_FOR_TARGET="${CCACHE} ${HOST_PREFIX}g++"
+		export AS_FOR_TARGET="${HOST_PREFIX}as"
+		export LD_FOR_TARGET="${HOST_PREFIX}ld"
+		export NM_FOR_TARGET="${HOST_PREFIX}nm"
+		export AR_FOR_TARGET="${HOST_PREFIX}ar"
+		export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
+	fi
+	(cd ${S} && gnu-configize) || die "failure running gnu-configize"
+	oe_runconf
+}
+
+do_install () {
+	autotools_do_install
+
+	# Cleanup some of the ${libdir}{,exec}/gcc stuff ...
+	rm -r ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+	rm -r ${D}/${libexecdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/${base_libdir}
+	mv ${D}/${libdir}/libgcc_s.so.* ${D}/${base_libdir}
+	rm ${D}/${libdir}/libgcc_s.so
+	ln -sf `echo ${libdir}/gcc/${TARGET_SYS}/${PV} \
+		| tr -s / \
+		| sed -e 's,^/,,' -e 's,[^/]*,..,g'`/lib/libgcc_s.so.? \
+		      ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/libgcc_s.so
+
+	# We don't need libtool libraries
+	rm ${D}/${libdir}/libg2c.la
+
+	# Cleanup manpages..
+	rm -r ${D}/${mandir}/man7
+
+	# We use libiberty from binutils
+	rm ${D}/${libdir}/libiberty.a
+
+	cd ${D}/${bindir}
+
+	# We care about g++ not c++
+	rm *c++
+
+	# We don't care about the gcc-<version> ones for this
+	rm *gcc-?.?*
+
+	# These sometimes show up, they are strange, we remove them
+	rm -f ${TARGET_ARCH}-*${TARGET_ARCH}-*
+
+	# Symlinks so we can use these trivially on the target
+	ln -sf ${TARGET_SYS}-g77 g77
+	ln -sf ${TARGET_SYS}-g++ g++
+	ln -sf ${TARGET_SYS}-gcc gcc
+	ln -sf g77 f77
+	ln -sf g++ c++
+	ln -sf gcc cc
+}