merge of '0c29b5c42b77169131d341373bedf1d5faf4af83'

     and 'b6e208df4ac3f681a9a18f6b4cdaac3850de571c'

1 files changed, 61 insertions, 0 deletions

diff --git a/packages/exmap-console/exmap-console.inc b/packages/exmap-console/exmap-console.inc
new file mode 100644
index 0000000000..4c107d5f07
--- /dev/null
+++ b/packages/exmap-console/exmap-console.inc
@@ -0,0 +1,61 @@
+DESCRIPTION = "Console based version of exmap, a memory usage analysis tool"
+HOMEPAGE = "http://projects.o-hand.com/exmap-console"
+SECTION = "devel"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel"
+
+SRC_URI = "http://projects.o-hand.com/sources/exmap-console/exmap-console-${PV}.tgz"
+
+inherit module-base
+inherit autotools
+
+MYPV := "${PV}"
+
+PACKAGES += "exmap-server kernel-module-exmap"
+
+FILES_exmap-console = "${bindir}/exmap ${bindir}/exmapd"
+PACKAGE_ARCH_exmap-console = "${TARGET_ARCH}"
+RDEPENDS_exmap-console += "kernel-module-exmap"
+
+FILES_exmap-server = "${bindir}/exmapserver"
+PACKAGE_ARCH_exmap-server = "${TARGET_ARCH}"
+RDEPENDS_exmap-server += "kernel-module-exmap"
+
+FILES_kernel-module-exmap = "${base_libdir}"
+PACKAGE_ARCH_kernel-module-exmap = "${MACHINE_ARCH}"
+PV_kernel-module-exmap = "${MYPV}-${KERNEL_VERSION}"
+RDEPENDS_kernel-module-exmap += "kernel (${KERNEL_VERSION})"
+
+S = "${WORKDIR}/exmap-console-${PV}"
+
+export MODULE_PATH="${D}${base_libdir}/modules/${KERNEL_VERSION}"
+
+do_compile() {
+    cd ${S}/src
+    make
+
+    cd ${S}/kernel
+    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+    oe_runmake KERNEL_PATH=${STAGING_KERNEL_DIR}   \
+        KERNEL_SRC=${STAGING_KERNEL_DIR}    \
+        KERNEL_VERSION=${KERNEL_VERSION}    \
+        CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
+        ${MAKE_TARGETS}
+}
+
+do_install() {
+    oe_runmake 'DESTDIR=${D}' 'DEPMOD=/bin/true' install
+}
+
+pkg_postinst_append_kernel-module-exmap () {
+    if [ -n "$D" ]; then
+        exit 1
+    fi
+    depmod -a
+    update-modules || true
+}
+
+pkg_postrm_append_kernel-module-exmap () {
+    update-modules || true
+}
+