DESCRIPTION = "mtac drivers"
HOMEPAGE = "http://www.multitech.net/"
SECTION = "base"
PRIORITY = "optional"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
do_fetch[depends]+="virtual/kernel:do_shared_workdir"
DEPENDS = "virtual/kernel mts-io"
INC_PR = "r0"
COMPATIBLE_MACHINE = "(mtcdt|mtcpmhs)"

SRCREV = "${PV}"

# Some packages depend on mtac
RPROVIDES_kernel-module-${PN} = "mtac"

PR = "${INC_PR}.2"

PKGR = "${PR}${KERNEL_MODULE_PACKAGE_SUFFIX}${EXTENDPRAUTO}"

SRC_URI = " \
    git://git.multitech.net/cgit/mtac.git;protocol=https;branch=master \
"
S = "${WORKDIR}/git"

inherit module

MTS_EXTRA_SYMBOLS="${STAGING_INCDIR}/mts-io/Module.symvers"

COMMON_OEMAKE = " -C ${STAGING_KERNEL_DIR} \
                KBUILD_VERBOSE=1 \
                KBUILD_EXTRA_SYMBOLS="${MTS_EXTRA_SYMBOLS}" \
                M=${S} \
                modules \
                "

EXTRA_OEMAKE_mtcdt = "${COMMON_OEMAKE} EXTRA_CFLAGS='-I${STAGING_INCDIR}/mts-kernel-headers \
                                    -D ${MACHINE}'"
EXTRA_OEMAKE_mtcpmhs = "${COMMON_OEMAKE} EXTRA_CFLAGS='-I${STAGING_INCDIR}/mts-kernel-headers \
                                    -D ${MACHINE} -D CONFIG_MTS_NUM_ACCESSORY_PORTS=2'"

do_compile () {
    bbnote make   "$@"
    make   "$@"
    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
    oe_runmake
}

PACKAGES = "kernel-module-${PN} ${PN}-dev"

FILES_kernel-module-${PN} = "${base_libdir}/modules/${KERNEL_VERSION}/extra/mtac.ko"

PARALLEL_MAKE = ""

fakeroot do_install () {
    install -m 0755 -d ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra
    # use cp instead of install so the driver doesn't get stripped
    cp ${S}/mtac.ko ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra

    install -Dm0644 ${S}/Module.symvers ${D}${includedir}/${BPN}/Module.symvers

    install -d ${D}${includedir}/mts-kernel-headers/linux
    install -m 0644 ${S}/mtac.h ${D}${includedir}/mts-kernel-headers/linux
    chmod -R 0644 ${D}${includedir}/mts-kernel-headers/linux
}