require u-boot.inc

DEPENDS += "dtc-native"
FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}-2016.09.01:"

CONFIG_PATCH = "${@oe.utils.conditional('SDMFG', '', 'file://config-n.patch', 'file://config-sd.patch', d)}"
MTCDT_PATCH = "${@oe.utils.conditional('SDMFG', '', 'file://mtcdt-n.patch', 'file://mtcdt-sd.patch', d)}"

PASSWD_PATCH = "${@oe.utils.conditional('SDMFG', '', 'file://mtpwd.patch', '', d)}"

SRC_URI = "ftp://ftp.denx.de/pub/u-boot/u-boot-${PV}.tar.bz2 \
           file://kconfig_common.patch \
           ${CONFIG_PATCH} \
           file://i2c.patch \
           file://printeepromcrc.patch \
           file://tftpput.patch \
           file://hide_uboot_version.patch \
           file://fix_2_6.patch \
           file://fix_net.patch \
           ${PASSWD_PATCH} \
"

SRC_URI_append_mtcdt = " \
           ${MTCDT_PATCH} \
           file://mtcdt_flush_console_autoboot.patch"

SRC_URI_append_mtcap = " \
           file://mtcdt-n.patch"

SRC_URI_append_mtr = "\
           file://mtr.patch \
"
SRC_URI_append_mtrv1 = "\
           file://mtrv1.patch \
"
# Make U-Boot Console access optional for factory test builds
MTRE_DISABLE_ACCESS ?= "file://mtre_disable_access.patch"
SRC_URI_append_mtre = "\
           ${MTRE_DISABLE_ACCESS} \
           file://mtre.patch \
"

SRC_URI[md5sum] = "61c628f8034477c946e173ed174efeb4"
SRC_URI[sha256sum] = "95728e89dd476d17428f94080752ab48884be477b6a678941582aeef618b70bb"

S = "${WORKDIR}/${PN}-${PV}"