SUMMARY = "A TCP/IP Daemon simplifying the communication with GPS devices"
SECTION = "console/network"
LICENSE = "BSD-2-Clause"
LIC_FILES_CHKSUM = "file://COPYING;md5=7a5d174db44ec45f9638b2c747806821"
DEPENDS = "dbus ncurses python3 pps-tools"
PROVIDES = "virtual/gpsd"

SRC_URI = "${SAVANNAH_GNU_MIRROR}/${BPN}/${BP}.tar.gz \
    file://0006-ubxtimelps.patch \
    file://0007-add-gll-vtg.patch \
    file://gpsd-default \
    file://gpsd \
    file://gpsd_ubx_fixed.sh \
    file://gpsd_ubx_settime.sh \
    file://gpsd_fixed.sh \
    file://gpsd_settime.sh \
    file://gpsd.rules \
    file://gpsd.service \
"

SRC_URI[sha256sum] = "522c2362a7eb2d7ac37eaa1504f12aded1c373479a87ba06cc6795974b567bbc"

inherit scons update-rc.d python3-dir python3native systemd update-alternatives pkgconfig

INITSCRIPT_PACKAGES = "gpsd-conf"
INITSCRIPT_NAME = "gpsd"
INITSCRIPT_PARAMS = "defaults 35"

SYSTEMD_OESCONS = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false',d)}"

export STAGING_INCDIR
export STAGING_LIBDIR

CLEANBROKEN = "1"

PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} usb"
PACKAGECONFIG[bluez] = "bluez='true',bluez='false',bluez5"
PACKAGECONFIG[qt] = "qt='yes' qt_versioned=5,qt='no',qtbase"
PACKAGECONFIG[usb] = "usb='true',usb='false',libusb1"

# Remove unneeded features.  netfeed is needed by gpsmon
EXTRA_OESCONS = " \
    sysroot=${STAGING_DIR_TARGET} \
    libQgpsmm='false' \
    nostrip='true' \
    systemd='${SYSTEMD_OESCONS}' \
    libdir='${libdir}' \
    sbindir='${sbindir}' \
    udevdir='${nonarch_base_libdir}/udev' \
    unitdir='${systemd_system_unitdir}' \
    manbuild='false' \
    debug='true' \
    strip='false' \
    chrpath='yes' \
    ublox='yes' \
    ubloxtimels='yes' \
    pps='yes' \
    gpsd_group='gps' \
    ntpshm='yes' \
    prefix='usr' \
    control_socket='false' \
    nofloats='yes' \
    ashtech='false' \
    earthmate='false' \
    evermore='false' \
    fury='false' \
    fv18='false' \
    garmin='false' \
    garmintxt='false' \
    geostar='false' \
    greis='false' \
    itrax='false' \
    mtk3301='false' \
    navcom='false' \
    nmea0183='true' \
    nmea2000='false' \
    oncore='false' \
    sirf='false' \
    skytraq='false' \
    superstar2='false' \
    tnt='false' \
    tripmate='false' \
    tsip='false' \
    ublox='true' \
    aivdm='false' \
    gpsclock='false' \
    isync='false' \
    ntrip='false' \
    oceanserver='false' \
    passthrough='false' \
    rtcm104v2='false' \
    rtcm104v3='false' \
    bluez='false' \
    ipv6='false' \
    netfeed='true' \
    usb='false' \
    LINK='${CC}' \
    ${PACKAGECONFIG_CONFARGS} \
"

# This cannot be used, because then chrpath is not found and only static lib is built
# target=${HOST_SYS}

do_compile_prepend() {
    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
    export CC="${CC}"
    export LD="${CC}"
    export LINKFLAGS="${LDFLAGS}"
}

do_install() {
    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
    export LD="${CC}"
    export LINKFLAGS="${LDFLAGS}"

    export DESTDIR="${D}"
    # prefix is used for RPATH and DESTDIR/prefix for installation
    ${STAGING_BINDIR_NATIVE}/scons prefix=${prefix} python_libdir=${libdir} install ${EXTRA_OESCONS} || \
      bbfatal "scons install execution failed."
}

do_install_append() {
    install -d ${D}/${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/gpsd ${D}/${sysconfdir}/init.d/
    install -d ${D}/${sysconfdir}/default
    install -m 0644 ${WORKDIR}/gpsd-default ${D}/${sysconfdir}/default/gpsd.default
    install -d ${D}${sbindir}
    install -m 0755 ${WORKDIR}/gpsd_ubx_fixed.sh ${D}${sbindir}/gpsd_ubx_fixed
    install -m 0755 ${WORKDIR}/gpsd_ubx_settime.sh ${D}${sbindir}/gpsd_ubx_settime
    install -m 0755 ${WORKDIR}/gpsd_fixed.sh ${D}${sbindir}/gpsd_fixed
    install -m 0755 ${WORKDIR}/gpsd_settime.sh ${D}${sbindir}/gpsd_settime

    #support for udev
    install -d ${D}/${sysconfdir}/udev/rules.d
    install -m 0644 ${S}/gpsd.rules.in ${D}/${sysconfdir}/udev/rules.d/
    install -d ${D}${base_libdir}/udev/
    install -m 0755 ${S}/gpsd.hotplug ${D}${base_libdir}/udev/

    # Support for python
    install -d ${D}${PYTHON_SITEPACKAGES_DIR}/gps
    install -m 755 ${S}/gps/*.py ${D}${PYTHON_SITEPACKAGES_DIR}/gps

    # support for dev (development)
    mkdir -p -m 0644 ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/gpsd.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/compiler.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/os_compat.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/ppsthread.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/timespec.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/gpsdclient.h ${D}/${includedir}/gps
    install -m 0644 ${S}/buildtmp/include/gpsd_config.h ${D}/${includedir}/gps
}


PACKAGES =+ "libgps python3-pygps gpsd-udev gpsd-conf gpsd-gpsctl gpspipe gps-utils"

RPROVIDES_${PN}-dbg += "python-pygps-dbg"

FILES_${PN}-dev += "${libdir}/libQgpsmm.prl"

FILES_${PN}-doc += "${datadir}/${BPN}/doc"

RDEPENDS_${PN} = "bash gpsd-gpsctl"
RRECOMMENDS_${PN} = "gpsd-conf gpsd-udev gpsd-machine-conf"

SUMMARY_gpsd-udev = "udev relevant files to use gpsd hotplugging"
FILES_gpsd-udev = "${nonarch_base_libdir}/udev"
RDEPENDS_gpsd-udev += "udev gpsd-conf"

SUMMARY_libgps = "C service library used for communicating with gpsd"
FILES_libgps = "${libdir}/libgps.so.*"

SUMMARY_gpsd-conf = "gpsd configuration files and init scripts"
FILES_gpsd-conf = "${sysconfdir}"
CONFFILES_gpsd-conf = "${sysconfdir}/default/gpsd.default"
RDEPENDS_gpsd-conf = "bash"

SUMMARY_gpsd-gpsctl = "Tool for tweaking GPS modes"
FILES_gpsd-gpsctl = "${bindir}/gpsctl"

SUMMARY_gpspipe = "Tool for connecting to gpsd and retrieve sentences"
FILES_gpspipe = "${bindir}/gpspipe"

SUMMARY_gps-utils = "Utils used for simulating, monitoring,... a GPS"
# Python files are required for gps/fake, required for gpsfake.
FILES_gps-utils = "\
    ${bindir}/cgps         \
    ${bindir}/gegps        \
    ${bindir}/gps2udp      \
    ${bindir}/gpscat       \
    ${bindir}/gpscsv       \
    ${bindir}/gpsctl       \
    ${bindir}/gpsdebuginfo \
    ${bindir}/gpsdecode    \
    ${bindir}/gpsfake      \
    ${bindir}/gpsmon       \
    ${bindir}/gpsplot      \
    ${bindir}/gpsprof      \
    ${bindir}/gpsrinex     \
    ${bindir}/gpssnmp      \
    ${bindir}/gpssubframe  \
    ${bindir}/gpxlogger    \
    ${bindir}/lcdgps       \
    ${bindir}/ntpshmmon    \
    ${bindir}/ppscheck     \
    ${bindir}/ubxtool      \
    ${bindir}/xgps         \
    ${bindir}/xgpsspeed    \
    ${bindir}/zerk         \
"
RDEPENDS_gps-utils = "python3-pygps"

SUMMARY_python3-pygps = "Python bindings to gpsd"
FILES_python3-pygps = "${PYTHON_SITEPACKAGES_DIR}/* ${libdir}/gps/*.py ${libdir}/*.egg-info"
RDEPENDS_python3-pygps = " \
    python3-core \
    python3-io \
    python3-threading \
    python3-terminal \
    gpsd \
    python3-json"

RPROVIDES_${PN} += "${PN}-systemd"
RREPLACES_${PN} += "${PN}-systemd"
RCONFLICTS_${PN} += "${PN}-systemd"
SYSTEMD_SERVICE_${PN} = "${BPN}.socket ${BPN}ctl@.service"

ALTERNATIVE_${PN} = "gpsd-defaults"
ALTERNATIVE_LINK_NAME[gpsd-defaults] = "${sysconfdir}/default/gpsd"
ALTERNATIVE_TARGET[gpsd-defaults] = "${sysconfdir}/default/gpsd.default"