SUMMARY = "A TCP/IP Daemon simplifying the communication with GPS devices"
SECTION = "console/network"
LICENSE = "BSD"
LIC_FILES_CHKSUM = "file://COPYING;md5=d217a23f408e91c94359447735bc1800"
DEPENDS = "dbus dbus-glib ncurses python libusb1 chrpath-replacement-native pps-tools"
PROVIDES = "virtual/gpsd"
PR="m13"

EXTRANATIVEPATH += "chrpath-native"

#    file://0002-SConstruct-remove-rpath.patch
SRC_URI = "${SAVANNAH_GNU_MIRROR}/${BPN}/${BP}.tar.gz \
    file://0001-SConstruct-prefix-includepy-with-sysroot-and-drop-sy.patch \
    file://0004-SConstruct-disable-html-and-man-docs-building-becaus.patch \
    file://0001-include-sys-ttydefaults.h.patch \
    file://0005-suppress-text-in-binary.patch \
    file://0006-ubxtimelps.patch \
    file://0006-itu_r_tf_460_6.patch \
    file://0006-sysclockcrash.patch \
    file://gpsd-default \
    file://gpsd \
    file://gpsd_ubx_fixed.sh \
    file://gpsd_ubx_settime.sh \
    file://gpsd.rules \
    file://gpsd.service \
"
# Fixed
#    file://0001-Check-for-__STDC_NO_ATOMICS__-before-using-stdatomic.patch
#    file://0002-Add-a-test-for-C11-and-check-we-have-C11-before-usin.patch
#    file://0003-Whoops-check-for-C11-not-for-not-C11-in-stdatomic.h-.patch
#    file://0001-Include-stdatomic.h-only-in-C-mode.patch
#    file://0001-libgpsd-core-Fix-issue-with-ACTIVATE-hook-not-being-.patch

SRC_URI[md5sum] = "68691b5de4c94f82ec4062b042b5eb63"
SRC_URI[sha256sum] = "03579af13a4d3fe0c5b79fa44b5f75c9f3cac6749357f1d99ce5d38c09bc2029"


inherit scons update-rc.d python-dir pythonnative systemd

INITSCRIPT_NAME = "gpsd"
INITSCRIPT_PARAMS = "defaults 10"

SYSTEMD_OESCONS = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false',d)}"

export STAGING_INCDIR
export STAGING_LIBDIR

# Necessary for python
export BUILD_SYS
export HOST_SYS

PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)}"
PACKAGECONFIG[bluez] = "bluez='false',${BLUEZ}"
PACKAGECONFIG[qt] = "qt='yes',qt='no',qt4-x11-free"
EXTRA_OESCONS = " \
    sysroot=${STAGING_DIR_TARGET} \
    libQgpsmm='false' \
    debug='true' \
    strip='false' \
    chrpath='yes' \
    systemd='${SYSTEMD_OESCONS}' \
    libdir='${libdir}' \
    ashtech='no' \
    earthmate='no' \
    evermore='no' \
    fury='no' \
    fv18='no' \
    garmin='no' \
    garmintxt='no' \
    geostar='no' \
    greis='no' \
    itrax='no' \
    mtk3301='no' \
    navcom='no' \
    nmea0183='yes' \
    nmea2000='no' \
    oncore='no' \
    sirf='no' \
    skytraq='yes' \
    superstar2='no' \
    tnt='no' \
    tripmate='no' \
    tsip='no' \
    ublox='yes' \
    ubloxtimels='yes' \
    aivdm='no' \
    gpsclock='no' \
    oceanserver='no' \
    fixed_stop_bits='1' \
    pps='yes' \
    gpsd_group='gps' \
    ntpshm='yes' \
    ${PACKAGECONFIG_CONFARGS} \
"
# this cannot be used, because then chrpath is not found and only static lib is built
# target=${HOST_SYS}

do_compile_prepend() {
    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
    export LINKFLAGS="${LDFLAGS}"
}

do_install() {
    export PKG_CONFIG_PATH="${PKG_CONFIG_PATH}"
    export PKG_CONFIG="PKG_CONFIG_SYSROOT_DIR=\"${PKG_CONFIG_SYSROOT_DIR}\" pkg-config"
    export STAGING_PREFIX="${STAGING_DIR_HOST}/${prefix}"
    export LINKFLAGS="${LDFLAGS}"

    export DESTDIR="${D}"
    # prefix is used for RPATH and DESTDIR/prefix for instalation
    ${STAGING_BINDIR_NATIVE}/scons prefix=${prefix} install ${EXTRA_OESCONS}|| \
      bbfatal "scons install execution failed."
}

do_install_append() {
    install -d ${D}/${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/gpsd ${D}/${sysconfdir}/init.d/
    install -d ${D}/${sysconfdir}/default
    install -m 0644 ${WORKDIR}/gpsd-default ${D}/${sysconfdir}/default/gpsd.default
    install -d ${D}${sbindir}
    install -m 0755 ${WORKDIR}/gpsd_ubx_fixed.sh ${D}${sbindir}/gpsd_ubx_fixed
    install -m 0755 ${WORKDIR}/gpsd_ubx_settime.sh ${D}${sbindir}/gpsd_ubx_settime

    #support for udev
    install -d ${D}/${sysconfdir}/udev/rules.d
    install -m 0644 ${WORKDIR}/gpsd.rules ${D}/${sysconfdir}/udev/rules.d
    install -d ${D}${base_libdir}/udev/
    install -m 0755 ${S}/gpsd.hotplug ${D}${base_libdir}/udev/

    #support for python
    install -d ${D}/${PYTHON_SITEPACKAGES_DIR}/gps
    install -m 755 ${S}/gps/*.py ${D}/${PYTHON_SITEPACKAGES_DIR}/gps

    #support for systemd
    install -d ${D}${systemd_unitdir}/system/
    install -m 0644 ${WORKDIR}/${BPN}.service ${D}${systemd_unitdir}/system/${BPN}.service
    install -m 0644 ${S}/systemd/${BPN}.socket ${D}${systemd_unitdir}/system/${BPN}.socket
    
    # support for dev (development)
    mkdir -p -m 0644 ${D}/${includedir}/gps
    install -m 0644 ${S}/gpsd.h ${D}/${includedir}/gps
    install -m 0644 ${S}/revision.h ${D}/${includedir}/gps
    install -m 0644 ${S}/gpsdclient.h ${D}/${includedir}/gps
    install -m 0644 ${S}/gpsd_config.h ${D}/${includedir}/gps
    install -m 0644 ${S}/compiler.h ${D}/${includedir}/gps
    install -m 0644 ${S}/ppsthread.h ${D}/${includedir}/gps
}

# Use libgps recipe for sysroot.
do_populate_sysroot() {
}

RDEPENDS_${PN}-conf += "bash"

pkg_postinst_${PN}-conf() {
    update-alternatives --install ${sysconfdir}/default/gpsd gpsd-defaults ${sysconfdir}/default/gpsd.default 10
}

pkg_postrm_${PN}-conf() {
    update-alternatives --remove gpsd-defaults ${sysconfdir}/default/gpsd.default
}

PACKAGES =+ "libgps libgpsd python-pygps-dbg python-pygps gpsd-udev gpsd-conf gpsd-gpsctl gpspipe gps-utils"

# File does not exist: ${libdir}/libQgpsmm.prl 
# FILES_${PN}-dev += "${libdir}/pkgconfdir/libgpsd.pc ${libdir}/pkgconfdir/libgps.pc \
#                     ${includedir}/gps.h ${includedir}/libgpsmm.h ${includedir}/gps"

FILES_${PN} += "${sbindir}/gpsd_ubx_fixed ${sbindir}/gpsd_ubx_settime"

FILES_python-pygps-dbg += " ${libdir}/python*/site-packages/gps/.debug"

RDEPENDS_${PN} = "gpsd-gpsctl bash"
RRECOMMENDS_${PN} = "gpsd-conf gpsd-machine-conf"

SUMMARY_${PN}-udev = "udev relevant files to use gpsd hotplugging"
FILES_${PN}-udev = "${base_libdir}/udev ${sysconfdir}/udev/*"
RDEPENDS_${PN}-udev += "udev gpsd-conf"

SUMMARY_libgpsd = "C service library used for communicating with gpsd"
FILES_libgpsd = "${libdir}/libgpsd.so.*"

SUMMARY_libgps = "C service library used for communicating with gpsd"
FILES_libgps = "${libdir}/libgps.so.*"

SUMMARY_${PN}-conf = "gpsd configuration files and init scripts"
FILES_${PN}-conf = "${sysconfdir}" 
CONFFILES_${PN}-conf = "${sysconfdir}/default/gpsd.default"

SUMMARY_${PN}-gpsctl = "Tool for tweaking GPS modes"
FILES_${PN}-gpsctl = "${bindir}/gpsctl"

SUMMARY_gpspipe = "Tool to connectg to gpsd and retrieve sentences"
FILES_gpspipe = "${bindir}/gpspipe"

SUMMARY_gps-utils = "Utils used for simulating, monitoring,... a GPS"
FILES_gps-utils = "${bindir}/*"
RDEPENDS_gps-utils = "python-pygps"

SUMMARY_python-pygps = "Python bindings to gpsd"
FILES_python-pygps = "${PYTHON_SITEPACKAGES_DIR}/*"
RDEPENDS_python-pygps = " \
    python-core \
    python-io \
    python-threading \
    python-terminal \
    python-curses \
    gpsd \
    python-json"

RPROVIDES_${PN} += "${PN}-systemd"
RREPLACES_${PN} += "${PN}-systemd"
RCONFLICTS_${PN} += "${PN}-systemd"
SYSTEMD_SERVICE_${PN} = "${PN}.socket"