SUMMARY = "Lightweight high-performance web server"
HOMEPAGE = "http://www.lighttpd.net/"
BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues"

LICENSE = "BSD"
LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579"


SECTION = "net"
DEPENDS = "zlib libpcre openssl"
RDEPENDS_${PN} += " \
               lighttpd-module-access \
               lighttpd-module-accesslog \
               lighttpd-module-fastcgi \
               lighttpd-module-rewrite \
               lighttpd-module-redirect \
               lighttpd-module-alias \
               lighttpd-module-setenv \
               lighttpd-module-expire \
               lighttpd-module-openssl \
"
RDEPENDS_${PN} += " openssl"
# for lighttpd_custom_images_setup script


SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.gz \
        file://lighttpd.conf \
	file://lighttpd.init \
	file://lighttpd.service \
        file://0001-lighttpd-pcre-use-pkg-config.patch;apply=true \
        file://0004_fastcgi_env_with_unixsocket.patch;apply=true \
"


SRC_URI[md5sum] = "fe9ea4dccacd9738be03245c364bc055"
SRC_URI[sha256sum] = "fc36f82877284eb506356aa80f483f133a9e17ec7cb79acd7e5b7733768538ef"

EXTRA_OECONF = " \
             --without-bzip2 \
             --without-ldap \
             --without-lua \
             --without-memcached \
             --with-pcre \
             --without-webdav-props \
             --without-webdav-locks \
             --with-openssl \
             --with-openssl-libs=${STAGING_LIBDIR} \
             --with-zlib \
             --disable-static \
"

inherit useradd update-rc.d autotools pkgconfig gettext systemd

INITSCRIPT_NAME = "lighttpd"
INITSCRIPT_PARAMS = "defaults 70"

USERADD_PACKAGES = "${PN}"
GROUPADD_PARAM_${PN} = "--system --gid 667 www"
USERADD_PARAM_${PN} = "--system --gid 667 --uid 667 --groups 667 --no-create-home --home-dir /var/www --shell /bin/false --no-user-group www"

do_install_append() {
    install -d ${D}${sysconfdir}/init.d ${D}${sysconfdir}/lighttpd.d ${D}/www/pages/dav
    install -d 0644 ${D}${sysconfdir}/ssl
    install -m 0755 --group www -d ${D}${localstatedir}/www
    install -m 0755 ${WORKDIR}/lighttpd.init ${D}${sysconfdir}/init.d/lighttpd
    install -m 0644 --group www ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
    
    	install -d ${D}${systemd_unitdir}/system
	install -m 0644 ${WORKDIR}/lighttpd.service ${D}${systemd_unitdir}/system
	sed -i -e 's,@SBINDIR@,${sbindir},g' \
		-e 's,@SYSCONFDIR@,${sysconfdir},g' \
		-e 's,@BASE_BINDIR@,${base_bindir},g' \
		${D}${systemd_unitdir}/system/lighttpd.service
    #For FHS compliance, create symbolic links to /var/log and /var/tmp for logs and temporary data
    ln -sf ${localstatedir}/log ${D}/www/logs
    ln -sf ${localstatedir}/tmp ${D}/www/var
    ln -snf ../volatile/www/tmp ${D}${localstatedir}/www/tmp}
}

do_install_append_mtr() {
    sed -i 's/^server.max-request-size.*/server.max-request-size  = 60000/g' ${D}${sysconfdir}/lighttpd.conf
}

do_install_append_mtrv1() {
    sed -i 's/^server.max-request-size.*/server.max-request-size  = 60000/g' ${D}${sysconfdir}/lighttpd.conf
}

FILES_${PN} += "${sysconfdir} /www"

CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf \
                  "

PACKAGES_DYNAMIC += "^lighttpd-module-.*"

python populate_packages_prepend () {
    lighttpd_libdir = d.expand('${libdir}')
    do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
}