DESCRIPTION = "LoRa Packet Forwarder"
HOMEPAGE = "https://github.com/Lora-net/packet_forwarder"
PRIORITY = "optional"
SECTION = "console/utils"
# Semtech license is a modified BSD-style license
LICENSE = "SEMTECH"
LIC_FILES_CHKSUM = "file://LICENSE;md5=22af7693d7b76ef0fc76161c4be76c45"
DEPENDS = "lora-gateway"
PR = "r3"

SRCREV = "v${PV}"

SRC_URI = "git://github.com/Lora-net/packet_forwarder.git;protocol=git \
           file://README.md \
           file://lora-packet-forwarder.init \
           file://lora-packet-forwarder.default \
           file://global_conf.json.3.0.0.PCB_E286.EU868.basic.clksrc0 \
           file://global_conf.json.3.0.0.PCB_E286.EU868.basic.clksrc1 \
           file://local_conf.json \
"

S = "${WORKDIR}/git"

LORA_DIR = "/opt/lora"

export LGW_PATH = "${STAGING_LIBDIR}/lora"
export LGW_INC = "${STAGING_INCDIR}/lora"

CFLAGS += "-I${LGW_INC} -Iinc -I."

do_compile() {
	oe_runmake
}

do_install() {
	install -d ${D}${LORA_DIR}
	install -m 755 lora_pkt_fwd/lora_pkt_fwd ${D}${LORA_DIR}/
# This file may be overwritten with a do_install_append_<MACHINE> function
	install -m 755 ${WORKDIR}/global_conf.json.3.0.0.PCB_E286.EU868.basic.clksrc1 ${D}${LORA_DIR}/global_conf.json
	install -m 755 ${WORKDIR}/local_conf.json ${D}${LORA_DIR}/

    install -d ${D}${sysconfdir}/default
    install -m 0644 ${WORKDIR}/lora-packet-forwarder.default ${D}${sysconfdir}/default/lora-packet-forwarder
    install -d ${D}${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/lora-packet-forwarder.init ${D}${sysconfdir}/init.d/lora-packet-forwarder

	install -m 755 util_sink/util_sink ${D}${LORA_DIR}/
	install -m 755 util_ack/util_ack ${D}${LORA_DIR}/
	install -m 755 util_tx_test/util_tx_test ${D}${LORA_DIR}/
	install -m 755 ${WORKDIR}/README.md  ${D}${LORA_DIR}/
}

do_install_append_mtp() {
	install -m 755 ${WORKDIR}/global_conf.json.3.0.0.PCB_E286.EU868.basic.clksrc0 ${D}${LORA_DIR}/global_conf.json
}

FILES_${PN} += "${LORA_DIR}"
FILES_${PN}-dbg += "${LORA_DIR}/.debug"

# disable this on purpose for dev purposes
do_rm_work() {
	echo "skipping"
}