DESCRIPTION = "MultiTech LoRa Network Server"
PRIORITY = "optional"
SECTION = "console/utils"
LICENSE = "Proprietary"
LIC_FILES_CHKSUM = "file://LICENSE;md5=2b9a30a3082ddccd2c695a4dbeeab80d"
DEPENDS = "jsoncpp libmts mosquitto sqlite3 curl gnutls"
RDEPENDS_${PN} += "logrotate bash lora-logging jsoncpp"
PR = "r0"
CONFFILES_${PN} += "${sysconfdir}/default/lora-network-server ${sysconfdir}/init.d/lora-network-server"

SRC_URI = "https://multitech.net/downloads/lora-network-server_${PV}.tar.gz \
           file://lora-network-server.init \
           file://lora-network-server.default \
          "

SRC_URI[md5sum] = "bd5ba59bb40bb39fb65eefeb237c3fe4"
SRC_URI[sha256sum] = "e2580fc5407029d870f2971f9c28239d66e443ce371b5909dfdea20a2fec9203"

# binaries are already stripped, so suppress warning
INSANE_SKIP_${PN} = "already-stripped"

S = "${WORKDIR}"

LORA_DIR = "/opt/lora"

do_compile() {
}

inherit update-rc.d

INITSCRIPT_NAME = "lora-network-server"
INITSCRIPT_PARAMS = "defaults 80 30"

do_install() {
    install -d ${D}${LORA_DIR}
    install -m 0755 lora-network-server-arm926ejste-mlinux-6 ${D}${LORA_DIR}/lora-network-server
    install -m 0755 lora-v21-keygen-arm926ejste-mlinux-6 ${D}${LORA_DIR}/lora-v21-keygen
    install -m 0644 config/lora-network-server.conf.sample ${D}${LORA_DIR}/lora-network-server.conf.sample
    install -m 0644 config/lora-network-server.conf.full ${D}${LORA_DIR}/lora-network-server.conf.full

    install -d ${D}${sysconfdir}/default
    install -m 0644 ${WORKDIR}/lora-network-server.default ${D}${sysconfdir}/default/lora-network-server
    install -d ${D}${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/lora-network-server.init ${D}${sysconfdir}/init.d/lora-network-server
}

FILES_${PN} += "${LORA_DIR}"
FILES_${PN}-dbg += "${LORA_DIR}/.debug"