DESCRIPTION = "LoRa Gateway library"
HOMEPAGE = "https://github.com/Lora-net/lora_gateway"
PRIORITY = "optional"
SECTION = "console/utils"
# Semtech license is a modified BSD-style license
LICENSE = "Proprietary"
LIC_FILES_CHKSUM = "file://LICENSE;md5=a2bdef95625509f821ba00460e3ae0eb"
DEPENDS = "gpsd"
RDEPENDS_${PN} = "libgps"

PR = "r34"
SRCREV = "${PV}"

SRC_URI = "git://git.multitech.net/cgit/lora_gateway_mtac_full.git;branch=master;protocol=https \
           file://library_4.0.cfg \
           file://ln-lora-spi-dev.sh \
          "


S = "${WORKDIR}/git"

CFLAGS += "-Iinc -I. -idirafter ${STAGING_DIR_TARGET}/usr/include/gps"

do_configure_append() {
    # copy over custom library_4.0.cfg
    cp ${WORKDIR}/library_4.0.cfg ${S}/libloragw/library.cfg
}

do_compile() {
    oe_runmake
}

do_install() {
	install -d ${D}${includedir}/lora
	install -d ${D}${libdir}/lora
	install -m 0644 libloragw/libloragw.a ${D}${libdir}/lora
	install -m 0644 libloragw/library.cfg ${D}${libdir}/lora
	install -m 0644 libloragw/inc/* ${D}${includedir}/lora
	install -m 0644 libloragw/readme.md ${D}${libdir}/lora/lora-gw-readme.md

	install -d ${D}/opt/lora/

	install -d ${D}/opt/lora/gateway-utils
	install -m 0755 libloragw/test_* ${D}/opt/lora/gateway-utils/
	install -m 0755 util_pkt_logger/util_pkt_logger ${D}/opt/lora/gateway-utils/
	install -m 0755 util_spectral_scan/util_spectral_scan ${D}/opt/lora/gateway-utils/
	install -m 0755 util_spi_stress/util_spi_stress ${D}/opt/lora/gateway-utils/
	install -m 0755 util_tx_test/util_tx_test ${D}/opt/lora/gateway-utils/
	install -m 0755 util_tx_continuous/util_tx_continuous ${D}/opt/lora/gateway-utils/
	install -m 0755 util_lbt_test/util_lbt_test ${D}/opt/lora/gateway-utils/
}

do_install_append_mtcdt() {
	install -m 0755 ${WORKDIR}/ln-lora-spi-dev.sh ${D}/opt/lora/
}

PACKAGES += "${PN}-utils ${PN}-utils-dbg"

FILES_${PN} = "${libdir}/lora/lora-gw-readme.md"
FILES_${PN}-utils = "/opt/lora/gateway-utils/* /opt/lora/ln-lora-spi-dev.sh"
FILES_${PN}-utils-dbg = "/opt/lora/gateway-utils/.debug /opt/lora/ln-lora-spi-dev.sh"
FILES_${PN}-dev = "${includedir}/lora ${libdir}/lora/library.cfg"
FILES_${PN}-staticdev = "${libdir}/lora/libloragw.a"

# disable this on purpose for dev purposes
do_rm_work() {
	echo "skipping"
}