From 592e3edf6abf0556b872c9748717bd6e2d29126b Mon Sep 17 00:00:00 2001
From: John Klug <john.klug@multitech.com>
Date: Tue, 24 Apr 2018 18:07:06 -0500
Subject: Original libpwquality recipes

---
 recipes-support/libpwquality/libpwquality_1.3.0.bb | 58 ++++++++++++++++++++++
 .../libpwquality/libpwquality_1.4.0.bb.new         | 45 +++++++++++++++++
 2 files changed, 103 insertions(+)
 create mode 100644 recipes-support/libpwquality/libpwquality_1.3.0.bb
 create mode 100644 recipes-support/libpwquality/libpwquality_1.4.0.bb.new

(limited to 'recipes-support')

diff --git a/recipes-support/libpwquality/libpwquality_1.3.0.bb b/recipes-support/libpwquality/libpwquality_1.3.0.bb
new file mode 100644
index 0000000..90fd804
--- /dev/null
+++ b/recipes-support/libpwquality/libpwquality_1.3.0.bb
@@ -0,0 +1,58 @@
+SUMMARY = "Library for password quality checking and generating random passwords"
+HOMEPAGE = "https://launchpad.net/libpwquality"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bd2f1386df813a459a0c34fde676fc2"
+
+SRC_URI = "https://launchpad.net/${BPN}/trunk/${PV}/+download/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "2a3d4ba1d11b52b4f6a7f39622ebf736"
+SRC_URI[sha256sum] = "74d2ea90e103323c1f2d6a6cc9617cdae6877573eddb31aaf31a40f354cc2d2a"
+
+inherit autotools-brokensep pkgconfig gettext pythonnative
+
+DEPENDS = "zlib cracklib libpam"
+
+EXTRA_OECONF = " \
+    --with-python-binary=${PYTHON} \
+"
+
+do_compile() {
+    # make distustils part for python bindings happy
+    export STAGING_INCDIR=${STAGING_INCDIR}
+    export STAGING_LIBDIR=${STAGING_LIBDIR}
+    export BUILD_SYS=${BUILD_SYS}
+    export HOST_SYS=${HOST_SYS}
+    base_do_compile
+}
+
+do_install() {
+    # make distustils part for python bindings happy
+    export STAGING_INCDIR=${STAGING_INCDIR}
+    export STAGING_LIBDIR=${STAGING_LIBDIR}
+    export BUILD_SYS=${BUILD_SYS}
+    export HOST_SYS=${HOST_SYS}
+    autotools_do_install
+}
+
+FILES_${PN} += " \
+    ${libdir}/security/*.so \
+"
+
+PACKAGE_BEFORE_PN += "${PN}-python"
+
+FILES_${PN}-python = " \
+    ${PYTHON_SITEPACKAGES_DIR} \
+"
+
+FILES_${PN}-staticdev += " \
+    ${PYTHON_SITEPACKAGES_DIR}/*.a \
+    ${libdir}/security/*.a \
+"
+FILES_${PN}-dev += " \
+    ${PYTHON_SITEPACKAGES_DIR}/*.la \
+    ${libdir}/security/*.la \
+"
+
+FILES_${PN}-dbg += "\
+    ${PYTHON_SITEPACKAGES_DIR}/.debug \
+    ${libdir}/security/.debug \
+"
diff --git a/recipes-support/libpwquality/libpwquality_1.4.0.bb.new b/recipes-support/libpwquality/libpwquality_1.4.0.bb.new
new file mode 100644
index 0000000..2c96063
--- /dev/null
+++ b/recipes-support/libpwquality/libpwquality_1.4.0.bb.new
@@ -0,0 +1,45 @@
+DESCRIPTION = "Library for password quality checking and generating random passwords"
+HOMEPAGE = "https://github.com/libpwquality/libpwquality"
+SECTION = "devel/lib"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bd2f1386df813a459a0c34fde676fc2"
+
+SRCNAME = "libpwquality"
+SRC_URI = "https://github.com/${SRCNAME}/${SRCNAME}/releases/download/${SRCNAME}-${PV}/${SRCNAME}-${PV}.tar.bz2 \
+           file://add-missing-python-include-dir-for-cross.patch \
+"
+
+SRC_URI[md5sum] = "b8defcc7280a90e9400d6689c93a279c"
+SRC_URI[sha256sum] = "1de6ff046cf2172d265a2cb6f8da439d894f3e4e8157b056c515515232fade6b"
+
+S = "${WORKDIR}/${SRCNAME}-${PV}"
+
+DEPENDS = "cracklib virtual/gettext python3"
+RDEPENDS_python3-libpwquality = "${PN}"
+
+inherit autotools python3native gettext
+
+B = "${S}"
+
+export PYTHON_DIR
+export BUILD_SYS
+export HOST_SYS
+export STAGING_LIBDIR
+export STAGING_INCDIR
+
+EXTRA_OECONF += "--with-python-rev=${PYTHON_BASEVERSION} \
+                 --with-python-binary=${STAGING_BINDIR_NATIVE}/${PYTHON_PN}-native/${PYTHON_PN} \
+                 --with-pythonsitedir=${PYTHON_SITEPACKAGES_DIR} \
+                 --libdir=${libdir} \
+"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}"
+PACKAGECONFIG[pam] = "--enable-pam, --disable-pam, libpam"
+
+PACKAGES += "python3-libpwquality python3-libpwquality-dbg"
+FILES_${PN} += "${libdir}/security/pam_pwquality.so"
+FILES_${PN}-dbg += "${libdir}/security/.debug"
+FILES_${PN}-staticdev += "${libdir}/security/pam_pwquality.a"
+FILES_${PN}-dev += "${libdir}/security/pam_pwquality.la"
+FILES_python3-${PN} = "${PYTHON_SITEPACKAGES_DIR}/*"
+FILES_python3-${PN}-dbg = "${PYTHON_SITEPACKAGES_DIR}/.debug"
-- 
cgit v1.2.3