1 files changed, 56 insertions, 0 deletions
diff --git a/recipes-devtools/nodejs/nodejs_0.8.27.bb b/recipes-devtools/nodejs/nodejs_0.8.27.bb
new file mode 100644
index 0000000..7a2b1d7
--- /dev/null
+++ b/recipes-devtools/nodejs/nodejs_0.8.27.bb
@@ -0,0 +1,56 @@
+DESCRIPTION = "nodeJS Evented I/O for V8 JavaScript"
+HOMEPAGE = "http://nodejs.org"
+LICENSE = "MIT & BSD"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=95a589a3257ab7dfe37d8a8379e3c72d"
+
+DEPENDS = "openssl"
+
+# use newer npm version that supports caret (^) versions
+# https://github.com/npm/npm/issues/4849
+SRCREV_npm = "v1.4.23"
+
+SRC_URI = "http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz \
+           file://0001-gcc-has-a-builtin-define-to-denote-hard-abi-when-in-.patch \
+           git://github.com/npm/npm.git;destsuffix=npm;name=npm \
+"
+SRC_URI[md5sum] = "afb113584498d2248825650b94e590a9"
+SRC_URI[sha256sum] = "30608f9dcd9ad122f7e8e6212f95969979e3dc35309d0c422a56486334a9369e"
+
+S = "${WORKDIR}/node-v${PV}"
+
+# v8 errors out if you have set CCACHE
+CCACHE = ""
+
+ARCHFLAGS_arm = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--with-arm-float-abi=hard', '--with-arm-float-abi=softfp', d)}"
+ARCHFLAGS ?= ""
+
+# Node is way too cool to use proper autotools, so we install two wrappers to forcefully inject proper arch cflags to workaround gypi
+do_configure () {
+    export LD="${CXX}"
+
+    ./configure --prefix=${prefix} --without-snapshot ${ARCHFLAGS}
+}
+
+do_compile () {
+    export LD="${CXX}"
+    make BUILDTYPE=Release
+}
+
+do_install () {
+    # backup original bundled npm
+    if [ ! -d deps/npm.orig ]; then
+        mv deps/npm deps/npm.orig
+    else
+        rm -rf deps/npm
+    fi
+    # install updated npm from git repo
+    cp -r ${WORKDIR}/npm deps/npm
+
+    oe_runmake install DESTDIR=${D}
+}
+
+RDEPENDS_${PN} = "curl python-shell python-datetime python-subprocess python-crypt python-textutils python-netclient "
+RDEPENDS_${PN}_class-native = ""
+
+FILES_${PN} += "${libdir}/node/wafadmin ${libdir}/node_modules ${libdir}/dtrace"
+BBCLASSEXTEND = "native"