1 files changed, 100 insertions, 0 deletions
diff --git a/recipes-core/lighttpd/lighttpd_1.4.48.bb b/recipes-core/lighttpd/lighttpd_1.4.48.bb
new file mode 100644
index 0000000..0b9897a
--- /dev/null
+++ b/recipes-core/lighttpd/lighttpd_1.4.48.bb
@@ -0,0 +1,100 @@
+SUMMARY = "Lightweight high-performance web server"
+HOMEPAGE = "http://www.lighttpd.net/"
+BUGTRACKER = "http://redmine.lighttpd.net/projects/lighttpd/issues"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4dac5c6ab169aa212feb5028853a579"
+
+PR .= ".mts21"
+
+SECTION = "net"
+DEPENDS = "zlib libpcre openssl"
+RDEPENDS_${PN} += " \
+               lighttpd-module-access \
+               lighttpd-module-accesslog \
+               lighttpd-module-fastcgi \
+               lighttpd-module-rewrite \
+               lighttpd-module-redirect \
+               lighttpd-module-alias \
+               lighttpd-module-setenv \
+               lighttpd-module-expire \
+               lighttpd-module-openssl \
+"
+RDEPENDS_${PN} += " openssl"
+# for lighttpd_custom_images_setup script
+RDEPENDS_${PN} += "bash file file-magic-db-images"
+
+
+SRC_URI = "http://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${PV}.tar.gz \
+        file://lighttpd.conf \
+        file://lighttpd_nrs.conf \
+        file://lighttpd.init \
+        file://lighttpd_custom_images_setup \
+        file://0001-lighttpd-pcre-use-pkg-config.patch;apply=true \
+        file://0004_fastcgi_env_with_unixsocket.patch;apply=true \
+"
+
+
+SRC_URI[md5sum] = "fe9ea4dccacd9738be03245c364bc055"
+SRC_URI[sha256sum] = "fc36f82877284eb506356aa80f483f133a9e17ec7cb79acd7e5b7733768538ef"
+
+EXTRA_OECONF = " \
+             --without-bzip2 \
+             --without-ldap \
+             --without-lua \
+             --without-memcached \
+             --with-pcre \
+             --without-webdav-props \
+             --without-webdav-locks \
+             --with-openssl \
+             --with-openssl-libs=${STAGING_LIBDIR} \
+             --with-zlib \
+             --disable-static \
+"
+
+inherit useradd autotools pkgconfig update-rc.d gettext systemd
+
+INITSCRIPT_NAME = "lighttpd"
+INITSCRIPT_PARAMS = "defaults 60 40"
+
+USERADD_PACKAGES = "${PN}"
+GROUPADD_PARAM_${PN} = "--system --gid 667 www"
+USERADD_PARAM_${PN} = "--system --gid 667 --uid 667 --groups 667 --no-create-home --home-dir /var/www --shell /bin/false --no-user-group www"
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/init.d ${D}${sysconfdir}/lighttpd.d ${D}/www/pages/dav
+    install -d 0644 ${D}${sysconfdir}/ssl
+    install -m 0755 --group www -d ${D}${localstatedir}/www
+    install -m 0755 ${WORKDIR}/lighttpd.init ${D}${sysconfdir}/init.d/lighttpd
+    install -m 0644 --group www ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
+    install -m 0644 --group www ${WORKDIR}/lighttpd_nrs.conf ${D}${sysconfdir}
+
+    #For FHS compliance, create symbolic links to /var/log and /var/tmp for logs and temporary data
+    ln -sf ${localstatedir}/log ${D}/www/logs
+    ln -sf ${localstatedir}/tmp ${D}/www/var
+    ln -snf ../volatile/www/tmp ${D}${localstatedir}/www/tmp
+
+    install -d ${D}/${base_sbindir}
+    install -m 755 ${WORKDIR}/lighttpd_custom_images_setup ${D}/${base_sbindir}/lighttpd_custom_images_setup
+}
+
+do_install_append_mtr() {
+    sed -i 's/^server.max-request-size.*/server.max-request-size  = 60000/g' ${D}${sysconfdir}/lighttpd.conf
+}
+
+do_install_append_mtrv1() {
+    sed -i 's/^server.max-request-size.*/server.max-request-size  = 60000/g' ${D}${sysconfdir}/lighttpd.conf
+}
+
+FILES_${PN} += "${sysconfdir} /www"
+
+CONFFILES_${PN} = "${sysconfdir}/lighttpd.conf \
+                   ${sysconfdir}/lighttpd_nrs.conf \
+                  "
+
+PACKAGES_DYNAMIC += "^lighttpd-module-.*"
+
+python populate_packages_prepend () {
+    lighttpd_libdir = d.expand('${libdir}')
+    do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
+}