Added Gateway 4.1.0 with patch to support fpga v28. Added pkt fwder 3.1.0

3 files changed, 156 insertions, 0 deletions

diff --git a/recipes-connectivity/lora/lora-gateway/lora-gateway-add-fpga-version-28-31-33.patch b/recipes-connectivity/lora/lora-gateway/lora-gateway-add-fpga-version-28-31-33.patch
new file mode 100644
index 0000000..1950573
--- /dev/null
+++ b/recipes-connectivity/lora/lora-gateway/lora-gateway-add-fpga-version-28-31-33.patch
@@ -0,0 +1,12 @@
+diff --git a/libloragw/src/loragw_reg.c b/libloragw/src/loragw_reg.c
+index 7e396bc..e71e695 100644
+--- a/libloragw/src/loragw_reg.c
++++ b/libloragw/src/loragw_reg.c
+@@ -48,7 +48,7 @@ Maintainer: Sylvain Miermont
+ #define PAGE_ADDR        0x00
+ #define PAGE_MASK        0x03
+ 
+-const uint8_t FPGA_VERSION[] = { 31, 33 }; /* several versions could be supported */
++const uint8_t FPGA_VERSION[] = { 28, 31, 33 }; /* several versions could be supported */
+ 
+ /*
\ No newline at end of file
diff --git a/recipes-connectivity/lora/lora-gateway_4.1.0.bb b/recipes-connectivity/lora/lora-gateway_4.1.0.bb
new file mode 100644
index 0000000..186479d
--- /dev/null
+++ b/recipes-connectivity/lora/lora-gateway_4.1.0.bb
@@ -0,0 +1,72 @@
+DESCRIPTION = "LoRa Gateway library"
+HOMEPAGE = "https://github.com/Lora-net/lora_gateway"
+PRIORITY = "optional"
+SECTION = "console/utils"
+# Semtech license is a modified BSD-style license
+LICENSE = "SEMTECH"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a2bdef95625509f821ba00460e3ae0eb"
+DEPENDS = ""
+PR = "r9"
+SRCREV = "v${PV}"
+
+SRC_URI = "git://github.com/Lora-net/lora_gateway.git;protocol=git \
+           file://lora-gateway-add-fpga-version-28-31-33.patch \
+           file://library_4.0.cfg \
+           file://lora-gateway-add-spi-path-function.patch \
+           file://ln-lora-spi-dev.sh \
+           file://lora-gateway-change-util-tx-continuous-clksrc.patch \
+          "
+
+SRC_URI[md5sum] = "9e06a3733a9fea39a3d61f77b412badf"
+SRC_URI[sha256sum] = "28fbfe098013908794b32e51d1fed4427f20dd6c8adbbca78df2e1800f5c84dc"
+
+S = "${WORKDIR}/git"
+
+CFLAGS += "-Iinc -I."
+
+do_configure_append() {
+    # copy over custom library_4.0.cfg
+    cp ${WORKDIR}/library_4.0.cfg ${S}/libloragw/library.cfg
+}
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+	install -d ${D}${includedir}/lora
+	install -d ${D}${libdir}/lora
+	install -m 0644 libloragw/libloragw.a ${D}${libdir}/lora
+	install -m 0644 libloragw/library.cfg ${D}${libdir}/lora
+	install -m 0644 libloragw/inc/* ${D}${includedir}/lora
+	install -m 0644 libloragw/readme.md ${D}${libdir}/lora/lora-gw-readme.md
+
+	install -d ${D}/opt/lora/
+
+	install -d ${D}/opt/lora/gateway-utils
+	install -m 0755 libloragw/test_* ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_pkt_logger/util_pkt_logger ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_spectral_scan/util_spectral_scan ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_spi_stress/util_spi_stress ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_tx_test/util_tx_test ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_tx_continuous/util_tx_continuous ${D}/opt/lora/gateway-utils/
+	install -m 0755 util_lbt_test/util_lbt_test ${D}/opt/lora/gateway-utils/
+}
+
+do_install_append_mtcdt() {
+	install -m 0755 ${WORKDIR}/ln-lora-spi-dev.sh ${D}/opt/lora/
+}
+
+PACKAGES += "${PN}-utils ${PN}-utils-dbg"
+
+FILES_${PN} = "${libdir}/lora/lora-gw-readme.md"
+FILES_${PN}-utils = "/opt/lora/gateway-utils/* /opt/lora/ln-lora-spi-dev.sh"
+FILES_${PN}-utils-dbg = "/opt/lora/gateway-utils/.debug /opt/lora/ln-lora-spi-dev.sh"
+FILES_${PN}-dev = "${includedir}/lora ${libdir}/lora/library.cfg"
+FILES_${PN}-staticdev = "${libdir}/lora/libloragw.a"
+
+# disable this on purpose for dev purposes
+do_rm_work() {
+	echo "skipping"
+}
+
diff --git a/recipes-connectivity/lora/lora-packet-forwarder_3.1.0.bb b/recipes-connectivity/lora/lora-packet-forwarder_3.1.0.bb
new file mode 100644
index 0000000..85fb8e3
--- /dev/null
+++ b/recipes-connectivity/lora/lora-packet-forwarder_3.1.0.bb
@@ -0,0 +1,72 @@
+DESCRIPTION = "LoRa Packet Forwarder"
+HOMEPAGE = "https://github.com/Lora-net/packet_forwarder"
+PRIORITY = "optional"
+SECTION = "console/utils"
+# Semtech license is a modified BSD-style license
+LICENSE = "SEMTECH"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=22af7693d7b76ef0fc76161c4be76c45"
+DEPENDS = "lora-gateway"
+PR = "r7"
+
+SRCREV = "v${PV}"
+
+SRC_URI = "git://github.com/Lora-net/packet_forwarder.git;protocol=git \
+           file://README.md \
+           file://lora-packet-forwarder.init \
+           file://lora-packet-forwarder.default \
+           file://global_conf.json.3.0.0.PCB_E336.EU868.basic.clksrc0 \
+           file://global_conf.json.3.0.0.MTAC_LORA_1_0.EU868.basic.clksrc0 \
+           file://global_conf.json.3.0.0.MTAC_LORA_1_5.EU868.basic.clksrc0 \
+           file://global_conf.json.3.0.0.MTCAP-LORA-1-5.EU868.basic \
+           file://local_conf.json \
+           file://lora-packet-forwarder-add-spi-dev-path.patch \
+           file://lora-packet-forwarder-remove-jit-power-check.patch \
+"
+
+S = "${WORKDIR}/git"
+
+LORA_DIR = "/opt/lora"
+
+export LGW_PATH = "${STAGING_LIBDIR}/lora"
+export LGW_INC = "${STAGING_INCDIR}/lora"
+
+CFLAGS += "-I${LGW_INC} -Iinc -I."
+
+do_compile() {
+  oe_runmake
+}
+
+do_install() {
+  install -d ${D}${LORA_DIR}
+  install -m 755 lora_pkt_fwd/lora_pkt_fwd ${D}${LORA_DIR}/
+  install -m 755 ${WORKDIR}/local_conf.json ${D}${LORA_DIR}/
+
+  install -d ${D}${LORA_DIR}/forwarder-utils
+  install -m 755 util_sink/util_sink ${D}${LORA_DIR}/forwarder-utils/
+  install -m 755 util_ack/util_ack ${D}${LORA_DIR}/forwarder-utils/
+  install -m 755 util_tx_test/util_tx_test ${D}${LORA_DIR}/forwarder-utils/
+  install -m 755 ${WORKDIR}/README.md  ${D}${LORA_DIR}/
+}
+
+do_install_append_mtcdt() {
+  install -m 755 ${WORKDIR}/global_conf.json.3.0.0.MTAC_LORA_1_5.EU868.basic.clksrc0 ${D}${LORA_DIR}/global_conf.json
+  install -m 755 ${WORKDIR}/global_conf.json.3.0.0.MTAC_LORA_1_0.EU868.basic.clksrc0 ${D}${LORA_DIR}/global_conf.json.MTAC_LORA_1_0
+  install -m 755 ${WORKDIR}/global_conf.json.3.0.0.MTAC_LORA_1_5.EU868.basic.clksrc0 ${D}${LORA_DIR}/global_conf.json.MTAC_LORA_1_5
+}
+
+do_install_append_mtcap() {
+  install -m 755 ${WORKDIR}/global_conf.json.3.0.0.MTCAP-LORA-1-5.EU868.basic ${D}${LORA_DIR}/global_conf.json
+
+  install -d ${D}${sysconfdir}/default
+  install -m 0644 ${WORKDIR}/lora-packet-forwarder.default ${D}${sysconfdir}/default/lora-packet-forwarder
+  install -d ${D}${sysconfdir}/init.d
+  install -m 0755 ${WORKDIR}/lora-packet-forwarder.init ${D}${sysconfdir}/init.d/lora-packet-forwarder
+}
+
+FILES_${PN} += "${LORA_DIR}"
+FILES_${PN}-dbg += "${LORA_DIR}/.debug ${LORA_DIR}/forwarder-utils/.debug"
+
+# disable this on purpose for dev purposes
+do_rm_work() {
+  echo "skipping"
+}