picocell:feat: add recipe for semtech lora-gateway 4.0.1

1 files changed, 59 insertions, 0 deletions

diff --git a/recipes-connectivity/lora/lora-gateway_4.0.1.bb b/recipes-connectivity/lora/lora-gateway_4.0.1.bb
new file mode 100644
index 0000000..098aa30
--- /dev/null
+++ b/recipes-connectivity/lora/lora-gateway_4.0.1.bb
@@ -0,0 +1,59 @@
+DESCRIPTION = "LoRa Gateway library"
+HOMEPAGE = "https://github.com/Lora-net/lora_gateway"
+PRIORITY = "optional"
+SECTION = "console/utils"
+# Semtech license is a modified BSD-style license
+LICENSE = "SEMTECH"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a2bdef95625509f821ba00460e3ae0eb"
+DEPENDS = "libftdi libmpsse libusb1"
+PR = "r0"
+SRCREV = "v${PV}"
+
+SRC_URI = "git://github.com/Lora-net/lora_gateway.git;protocol=git \
+           file://library_4.0.cfg \
+          "
+
+SRC_URI[md5sum] = "9e06a3733a9fea39a3d61f77b412badf"
+SRC_URI[sha256sum] = "28fbfe098013908794b32e51d1fed4427f20dd6c8adbbca78df2e1800f5c84dc"
+
+S = "${WORKDIR}/git"
+
+CFLAGS += "-Iinc -I. -DLIBFTDI1=1"
+
+do_configure_append() {
+    # copy over custom library_4.0.cfg
+    cp ${WORKDIR}/library_4.0.cfg ${S}/libloragw/library.cfg
+}
+
+do_compile() {
+    oe_runmake
+}
+
+do_install() {
+	install -d ${D}${includedir}/lora
+	install -d ${D}${libdir}/lora
+	install -m 0644 libloragw/libloragw.a ${D}${libdir}/lora
+	install -m 0644 libloragw/library.cfg ${D}${libdir}/lora
+	install -m 0644 libloragw/inc/* ${D}${includedir}/lora
+	install -m 0644 libloragw/readme.md ${D}${libdir}/lora
+
+	install -d ${D}/opt/lora
+	install -m 0755 libloragw/test_* ${D}/opt/lora/
+	install -m 0755 util_pkt_logger/util_pkt_logger ${D}/opt/lora/
+	install -m 0755 util_spectral_scan/util_spectral_scan ${D}/opt/lora/
+	install -m 0755 util_spi_stress/util_spi_stress ${D}/opt/lora/
+	install -m 0755 util_tx_test/util_tx_test ${D}/opt/lora/
+}
+
+PACKAGES += "${PN}-utils ${PN}-utils-dbg"
+
+FILES_${PN}-utils = "/opt/lora/*"
+FILES_${PN}-utils-dbg = "/opt/lora/.debug"
+FILES_${PN}-dev = "${includedir}/lora ${libdir}/lora/library.cfg"
+FILES_${PN}-staticdev = "${libdir}/lora/libloragw.a"
+
+# disable this on purpose for dev purposes
+do_rm_work() {
+	echo "skipping"
+}
+