DESCRIPTION = "mts-io controller and sysfs wrapper"
HOMEPAGE = "http://www.multitech.net/"
SECTION = "base"
PRIORITY = "optional"
LICENSE = "GPL"
DEPENDS = "virtual/kernel"
RDEPENDS = "kernel (${KERNEL_VERSION})"
INC_PR = "r3"

SRC_URI = " \
    file://mts-io.init \
    git://git.multitech.net/cdp-io-controller.git;protocol=git;tag=v${PV} \
    file://radio-reset-h5 \
"
S = "${WORKDIR}/git/io-module"

inherit module-base
inherit update-rc.d

EXTRA_OEMAKE = " -C ${STAGING_KERNEL_DIR} \
                M=${S} \
                modules \
                "

do_configure () {
   echo "Nothing to configure for mts-io"
}

CFLAGS = ""
CPPFLAGS = ""
CXXFLAGS = ""
LDFLAGS = ""

DAUGHTER_CARD_mtocgd2 = "-DMTOCGD2"
export DAUGHTER_CARD

do_compile () {
    oe_runmake
}

PACKAGES = "${PN}"

FILES_${PN} = "${base_libdir}/modules/${KERNEL_VERSION}/extra/mts_io.ko"
FILES_${PN} += "${sysconfdir}/init.d/mts-io"
FILES_${PN} += "${libdir}/mts-io-sysfs*"
FILES_${PN} += "${sbindir}/mts-io-sysfs ${sbindir}/radio-reset-h5"

INITSCRIPT_NAME = "mts-io"
INITSCRIPT_PARAMS = "start 39 S ."

PARALLEL_MAKE = ""

fakeroot do_install () {
    install -m 0755 -d ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra
    # use cp instead of install so the driver doesn't get stripped
    cp ${S}/mts_io.ko ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra
    cp ${S}/mts_io.h ${STAGING_KERNEL_DIR}/include/linux/
    cp ${S}/mts_io.h ${STAGING_INCDIR}/linux/

    install -d ${D}${sysconfdir}/init.d
    install -m 0755 ${WORKDIR}/mts-io.init ${D}${sysconfdir}/init.d/mts-io

    install -m 0755 -d ${D}${sbindir}
    install -d ${D}${libdir}/mts-io-sysfs
    install -m 0755 ${WORKDIR}/git/io-tool/mts-io-sysfs-inc.sh ${D}${libdir}/mts-io-sysfs
    install -m 0755 ${WORKDIR}/git/io-tool/mts-io-sysfs ${D}${sbindir}/mts-io-sysfs
    install -m 0755 ${WORKDIR}/radio-reset-h5 ${D}${sbindir}/radio-reset-h5
}