require recipes/linux/linux.inc

# PR is set by MACHINE_KERNEL_PR in machine config

# Linux 2.6.39 for AT91
# commit Dec 4, 2013 - tty/serial: atmel_serial: remove dev_dbg in atmel_set_termios
SRCREV="5f90e2645cc8bacb958e1f56ac5ce78ee2db0083"

# Add 2.6.39.4 patch customized to patch against at91 branch
SRC_URI = "git://github.com/linux4sam/linux-at91.git;protocol=https;tag=${SRCREV} \
           file://linux-2.6.39.4-at91.patch \
           file://linux-2.6.39-at91-atmel-nand-debug-bit-flips.patch"

S = "${WORKDIR}/git"

COMMON_PATCHES = " \
                    file://linux-2.6.39.4-ledtrig-netdev.patch \
                    file://linux-2.6.39.4-at91sam9x5-extreset.patch \
                    file://linux-2.6.39.4-atmel-mci-force-detect.patch \
                    file://linux-2.6.39.4-wl12xx-sdio-irq.patch \
                    file://linux-2.6.35.14-at91-gpio-pullup.patch \
                    file://linux-2.6.32.3-atmel_spi.patch \
                    file://linux-2.6.32.3-at25.patch \
                    file://linux-2.6.39.4-atmel_serial_disable_hwhs.patch \
                    file://linux-2.6.39.4-at91sam9_wdt-10second-timeout.patch \
                    file://linux-2.6.35.14-option-zte.patch \
                    file://linux-2.6.39.4-option-telit-20140120.patch \
                    file://linux-2.6.38-sierra-1.7.40.patch \
                    file://linux-2.6.39.4-cdc-acm-ignore-exar-devices.patch \
                    "

SRC_URI_append_mtocgd2 = " \
                    file://defconfig \
                    file://linux-2.6.39.4-mach-at91-mtocgd2.patch \
                    file://linux-2.6.39.4-macb-force-link.patch \
					${COMMON_PATCHES} \
					"

SRC_URI_append_mtocgd = " \
                    file://defconfig \
                    file://linux-2.6.39.4-mach-at91-mtocgd.patch \
					${COMMON_PATCHES} \
					"

# prevent setlocalversion from changing kernel version
do_configure_prepend() {
    touch ${S}/.scmversion
}

# add missing crypto headers
sysroot_stage_all_append() {
    kerneldir=${SYSROOT_DESTDIR}${STAGING_KERNEL_DIR}
    cp -fR include/crypto* $kerneldir/include/
}