DESCRIPTION = "LoRa Basic Station"
HOMEPAGE = "https://github.com/lorabasics/basicstation"
PRIORITY = "optional"
SECTION = "console/utils"
# Semtech license is a modified BSD-style license
LICENSE = "Proprietary"
LIC_FILES_CHKSUM = "file://LICENSE;md5=7706b51ea6d730e45568141c660072d5"
DEPENDS = "lora-gateway logrotate lora-logging mbedtls"
RDEPENDS_${PN} += "bash"
PR = "r3"

SRCREV = "${PV}"

SRC_URI = "git://github.com/MultiTechSystems/basicstation.git;protocol=https;branch=master \
           file://setup.gmk \
           file://lora-basic-station.init \
           file://lora-basic-station.default \
           file://tc.uri \
           file://mtcap-station.conf \
           file://mtcdt-station.conf \
"

S = "${WORKDIR}/git"
B = "${S}"

LORA_DIR = "/opt/lora"

export LGW_PATH = "${STAGING_LIBDIR}/lora"
export LGW_INC = "${STAGING_INCDIR}/lora"

CFLAGS += "-I${STAGING_INCDIR} -I${STAGING_INCDIR}/lora -I${WORKDIR}/git/deps -Iinc -I. -std=gnu11 -L${STAGING_LIBDIR}/lora"

do_compile() {
  rm -fr ${S}/deps/lgw
  ln -s ${STAGING_INCDIR}/lora ${S}/deps/lgw
  cp ${WORKDIR}/setup.gmk ${S}/setup.gmk
  oe_runmake
}

do_install() {
  install -d ${D}${LORA_DIR}
  install -m 755 ${S}/build-mlinux-std/bin/station ${D}${LORA_DIR}/
  install -m 755 ${WORKDIR}/tc.uri ${D}${LORA_DIR}/

  install -d ${D}${sysconfdir}/default
  install -m 0644 ${WORKDIR}/lora-basic-station.default ${D}${sysconfdir}/default/lora-basic-station
  install -d ${D}${sysconfdir}/init.d
  install -m 0755 ${WORKDIR}/lora-basic-station.init ${D}${sysconfdir}/init.d/lora-basic-station
}

do_install_append_mtcap() {
  install -d ${D}${LORA_DIR}
  install -m 755 ${WORKDIR}/mtcap-station.conf ${D}${LORA_DIR}/station.conf
}

do_install_append_mtcdt() {
  install -d ${D}${LORA_DIR}
  install -m 755 ${WORKDIR}/mtcdt-station.conf ${D}${LORA_DIR}/station.conf
}



FILES_${PN} += "${LORA_DIR}"

# disable this on purpose for dev purposes
do_rm_work() {
  echo "skipping"
}